SQL 中实现两个字段合并

[candy_yuxi]

麻烦各位

我现在又一张表，表中数据有重复的
现在要查出表中
Name,MobilePhone,Venues字段都相同的话就只保留一条数据
Name,MobilePhone字段相同，Venues字段不同的也是只保留一条数据，但是有把表中的LoveSports(爱好的运动)这个字段的值相加

-------------------------------------------------
假设表中数据：

aa 1234567 球场 羽毛球，篮球 YS001
bb 1234567 游泳馆 游泳 81204
cc 7654321 冰场 滑冰 95623
aa 1234567 球场 足球 B12125
aa 1234567 球场 羽毛球 Y12121
cc 7654321 球场 羽毛球，篮球 YS121


需要得到的结果：

aa 1234567 球场 羽毛球，篮球，足球 YS001
bb 1234567 游泳馆 游泳 81204
cc 7654321 球场 羽毛球，篮球,滑冰 YS121


------------------------------------------------------------
合并LoveSports的值是，有一样的只要一个


现实表不只这几个字段，得到的结果要能复制到别的表


谢谢各位，帮帮忙

急！！！！！！！！！！

描述不清楚的可以加我QQ540255090

[dawugui]

参考下面这个.

[code=SQL]/*
标题：按某字段合并字符串之一(简单合并)
作者：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)
时间：2008-11-06
地点：广东深圳

描述：将如下形式的数据按id字段合并value字段。
id    value
----- ------
1     aa
1     bb
2     aaa
2     bbb
2     ccc
需要得到结果：
id     value
------ -----------
1      aa,bb
2      aaa,bbb,ccc
即：group by id, 求 value 的和（字符串相加）
*/
--1、sql2000中只能用自定义的函数解决
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go

create function dbo.f_str(@id int) returns varchar(100)
as
begin
    declare @str varchar(1000)
    set @str = ''
    select @str = @str + ',' + cast(value as varchar) from tb where id = @id
    set @str = right(@str , len(@str) - 1)
    return @str
end
go

--调用函数
select id , value = dbo.f_str(id) from tb group by id

drop function dbo.f_str
drop table tb


--2、sql2005中的方法
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go

select id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')
from tb
group by id

drop table tb


--3、使用游标合并数据
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
declare @t table(id int,value varchar(100))--定义结果集表变量
--定义游标并进行合并处理
declare my_cursor cursor local for
select id , value from tb
declare @id_old int , @id int , @value varchar(10) , @s varchar(100)
open my_cursor
fetch my_cursor into @id , @value
select @id_old = @id , @s=''
while @@FETCH_STATUS = 0
begin
    if @id = @id_old
       select @s = @s + ',' + cast(@value as varchar)
    else
      begin
        insert @t values(@id_old , stuff(@s,1,1,''))
        select @s = ',' + cast(@value as varchar) , @id_old = @id
      end
    fetch my_cursor into @id , @value
END
insert @t values(@id_old , stuff(@s,1,1,''))
close my_cursor
deallocate my_cursor

select * from @t
drop table tb

[/code]

[dawugui]

以上为单独一个字段(ID)的,自己改为两个或多个字段匹配即可,如果还需要Venues,加max(Venues),或min(Venues)即可.

[--小F--]

SQL code问题描述：
无论是在sql 2000，还是在 sql 2005 中,都没有提供字符串的聚合函数，
  所以，当我们在处理下列要求时，会比较麻烦：
有表tb, 如下：
id    value
----- ------
1     aa
1     bb
2     aaa
2     bbb
2     ccc
需要得到结果：
id     values
------ -----------
1      aa,bb
2      aaa,bbb,ccc
即， group by id, 求 value 的和（字符串相加）

1. 旧的解决方法

-- 1. 创建处理函数
CREATE FUNCTION dbo.f_str(@id int)
RETURNS varchar(8000)
AS
BEGIN
    DECLARE @r varchar(8000)
    SET @r = ''
    SELECT @r = @r + ',' + value
    FROM tb
    WHERE id=@id
    RETURN STUFF(@r, 1, 1, '')
END
GO
-- 调用函数

SELECt id, values=dbo.f_str(id) 
FROM tb 
GROUP BY id

-- 2. 新的解决方法 
-- 示例数据
DECLARE @t TABLE(id int, value varchar(10))
INSERT @t SELECT 1, 'aa'
UNION ALL SELECT 1, 'bb'
UNION ALL SELECT 2, 'aaa'
UNION ALL SELECT 2, 'bbb'
UNION ALL SELECT 2, 'ccc'

-- 查询处理
SELECT *
FROM(
    SELECT DISTINCT 
        id
    FROM @t
)A
OUTER APPLY(
    SELECT 
        [values]= STUFF(REPLACE(REPLACE(
            (
                SELECT value FROM @t N
                WHERE id = A.id
                FOR XML AUTO
            ), '<N value="', ','), '"/>', ''), 1, 1, '')
)N

/*--结果
id          values
----------- ----------------
1           aa,bb
2           aaa,bbb,ccc
(2 行受影响)
--*/

--各种字符串分函数

--3.3.1 使用游标法进行字符串合并处理的示例。
--处理的数据
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'b',3

--合并处理
--定义结果集表变量
DECLARE @t TABLE(col1 varchar(10),col2 varchar(100))

--定义游标并进行合并处理
DECLARE tb CURSOR LOCAL
FOR
SELECT col1,col2 FROM tb ORDER BY  col1,col2
DECLARE @col1_old varchar(10),@col1 varchar(10),@col2 int,@s varchar(100)
OPEN tb
FETCH tb INTO @col1,@col2
SELECT @col1_old=@col1,@s=''
WHILE @@FETCH_STATUS=0
BEGIN
    IF @col1=@col1_old
        SELECT @s=@s+','+CAST(@col2 as varchar)
    ELSE
    BEGIN
        INSERT @t VALUES(@col1_old,STUFF(@s,1,1,''))
        SELECT @s=','+CAST(@col2 as varchar),@col1_old=@col1
    END
    FETCH tb INTO @col1,@col2
END
INSERT @t VALUES(@col1_old,STUFF(@s,1,1,''))
CLOSE tb
DEALLOCATE tb
--显示结果并删除测试数据
SELECT * FROM @t
DROP TABLE tb
/*--结果
col1       col2
---------- -----------
a          1,2
b          1,2,3
--*/
GO


/*==============================================*/


--3.3.2 使用用户定义函数，配合SELECT处理完成字符串合并处理的示例
--处理的数据
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'b',3
GO

--合并处理函数
CREATE FUNCTION dbo.f_str(@col1 varchar(10))
RETURNS varchar(100)
AS
BEGIN
    DECLARE @re varchar(100)
    SET @re=''
    SELECT @re=@re+','+CAST(col2 as varchar)
    FROM tb
    WHERE col1=@col1
    RETURN(STUFF(@re,1,1,''))
END
GO

--调用函数
SELECT col1,col2=dbo.f_str(col1) FROM tb GROUP BY col1
--删除测试
DROP TABLE tb
DROP FUNCTION f_str
/*--结果
col1       col2
---------- -----------
a          1,2
b          1,2,3
--*/
GO

/*==============================================*/


--3.3.3 使用临时表实现字符串合并处理的示例
--处理的数据
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'b',3

--合并处理
SELECT col1,col2=CAST(col2 as varchar(100)) 
INTO #t FROM tb
ORDER BY col1,col2
DECLARE @col1 varchar(10),@col2 varchar(100)
UPDATE #t SET 
    @col2=CASE WHEN @col1=col1 THEN @col2+','+col2 ELSE col2 END,
    @col1=col1,
    col2=@col2
SELECT * FROM #t
/*--更新处理后的临时表
col1       col2
---------- -------------
a          1
a          1,2
b          1
b          1,2
b          1,2,3
--*/
--得到最终结果
SELECT col1,col2=MAX(col2) FROM #t GROUP BY col1
/*--结果
col1       col2
---------- -----------
a          1,2
b          1,2,3
--*/
--删除测试
DROP TABLE tb,#t
GO


/*==============================================*/

--3.3.4.1 每组 <=2 条记录的合并
--处理的数据
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'c',3

--合并处理
SELECT col1,
    col2=CAST(MIN(col2) as varchar)
        +CASE 
            WHEN COUNT(*)=1 THEN ''
            ELSE ','+CAST(MAX(col2) as varchar)
        END
FROM tb
GROUP BY col1
DROP TABLE tb
/*--结果
col1       col2      
---------- ----------
a          1,2
b          1,2
c          3
--*/

--3.3.4.2 每组 <=3 条记录的合并
--处理的数据
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'b',3
UNION ALL SELECT 'c',3

--合并处理
SELECT col1,
    col2=CAST(MIN(col2) as varchar)
        +CASE 
            WHEN COUNT(*)=3 THEN ','
                +CAST((SELECT col2 FROM tb WHERE col1=a.col1 AND col2 NOT IN(MAX(a.col2),MIN(a.col2))) as varchar)
            ELSE ''
        END
        +CASE 
            WHEN COUNT(*)>=2 THEN ','+CAST(MAX(col2) as varchar)
            ELSE ''
        END
FROM tb a
GROUP BY col1
DROP TABLE tb
/*--结果
col1       col2
---------- ------------
a          1,2
b          1,2,3
c          3
--*/
GO
if not object_id('A') is null
    drop table A
Go
Create table A([id] int,[cname] nvarchar(2))
Insert A
select 1,N'张三' union all
select 2,N'李四' union all
select 3,N'王五' union all
select 4,N'蔡六'
Go
--> --> 
 
if not object_id('B') is null
    drop table B
Go
Create table B([id] int,[cname] nvarchar(5))
Insert B
select 1,N'1,2,3' union all
select 2,N'3,4'
Go
create function F_str(@cname nvarchar(100))
returns nvarchar(100)
as
begin 
select @cname=replace(@cname,ID,[cname]) from A where patindex('%,'+rtrim(ID)+',%',','+@cname+',')>0
return @cname
end
go
select [id],dbo.F_str([cname])[cname] from B

id          cname
----------- ----------------------------------------------------------------------------------------------------
1           张三,李四,王五
2           王五,蔡六

(2 個資料列受到影響)

[dawugui]

以下为2000中用函数的方法,2005的方法见一楼.

create table tb(Name varchar(20),MobilePhone varchar(20),position varchar(20),LoveSports varchar(20),Venues varchar(20))
insert into tb values('aa' , '1234567' , '球场' , '羽毛球,篮球' , 'YS001') 
insert into tb values('bb' , '1234567' , '游泳馆', '游泳' , '81204') 
insert into tb values('cc' , '7654321' , '冰场' , '滑冰' , '95623') 
insert into tb values('aa' , '1234567' , '球场' , '足球' , 'B12125') 
insert into tb values('aa' , '1234567' , '球场' , '羽毛球' , 'Y12121') 
insert into tb values('cc' , '7654321' , '球场' , '羽毛球,篮球' , 'YS121') 
go

create function dbo.f_str(@Name varchar(20),@MobilePhone varchar(20)) returns varchar(100)
as
begin
    declare @str varchar(1000)
    set @str = ''
    select @str = @str + ',' + cast(LoveSports as varchar) from tb where name = @name and MobilePhone = @MobilePhone
    set @str = right(@str , len(@str) - 1)
    return @str
end
go

--调用函数
select name,MobilePhone ,min(position) position, LoveSports = dbo.f_str(name,MobilePhone) , min(Venues) Venues from tb group by name,MobilePhone

drop function dbo.f_str

drop table tb

/*
name                 MobilePhone          position             LoveSports                                                                                           Venues               
-------------------- -------------------- -------------------- ---------------------------------------------------------------------------------------------------- -------------------- 
aa                   1234567              球场                   羽毛球,篮球,足球,羽毛球                                                                                        B12125
bb                   1234567              游泳馆                  游泳                                                                                                   81204
cc                   7654321              冰场                   滑冰,羽毛球,篮球                                                                                            95623

（所影响的行数为 3 行）

*/

[candy_yuxi]

select id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')
from tb
group by id


这里面的XML PATH 是什么？

后面的 group by id 那我其他字段还能查吗，我还有很多字段都要查出来的？

还有，我合并的值有重复的要怎么处理

问一下SQL中有没有判断字段中是否包含值的

谢谢

[--小F--]

[Quote=引用 5 楼 candy_yuxi 的回复:]
select id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')
from tb
group by id


这里面的XML PATH 是什么？

后面的 group by id 那我其他字段还能查吗，我还有很多字段都要查出来的？

还有，我合并的值有重复的要怎么处理

问一下SQL中有没有判断字段中是否包含值的

谢谢
[/Quote]
XML PATH SQL 2005中的 XML
有没有判断字段中是否包含值的 有 可以用like或者 charindex函数

[--小F--]

我合并的值有重复的要怎么处理

distinct去掉重复列

如果是下面的类型就这样做:

--处理表重复记录(查询和删除)
/******************************************************************************************************************************************************
1、Num、Name相同的重复值记录,没有大小关系只保留一条
2、Name相同,ID有大小关系时,保留大或小其中一个记录
整理人：中国风(Roy)

日期:2008.06.06
******************************************************************************************************************************************************/

--1、用于查询重复处理记录(如果列没有大小关系时2000用生成自增列和临时表处理,SQL2005用row_number函数处理)

--> --> (Roy)生成測試數據
 
if not object_id('Tempdb..#T') is null
    drop table #T
Go
Create table #T([ID] int,[Name] nvarchar(1),[Memo] nvarchar(2))
Insert #T
select 1,N'A',N'A1' union all
select 2,N'A',N'A2' union all
select 3,N'A',N'A3' union all
select 4,N'B',N'B1' union all
select 5,N'B',N'B2'
Go


--I、Name相同ID最小的记录(推荐用1,2,3),方法3在SQl05时，效率高于1、2
方法1:
Select * from #T a where not exists(select 1 from #T where Name=a.Name and ID<a.ID)

方法2:
select a.* from #T a join (select min(ID)ID,Name from #T group by Name) b on a.Name=b.Name and a.ID=b.ID

方法3:
select * from #T a where ID=(select min(ID) from #T where Name=a.Name)

方法4:
select a.* from #T a join #T b on a.Name=b.Name and a.ID>=b.ID group by a.ID,a.Name,a.Memo having count(1)=1 

方法5:
select * from #T a group by ID,Name,Memo having ID=(select min(ID)from #T where Name=a.Name)

方法6:
select * from #T a where (select count(1) from #T where Name=a.Name and ID<a.ID)=0

方法7:
select * from #T a where ID=(select top 1 ID from #T where Name=a.name order by ID)

方法8:
select * from #T a where ID!>all(select ID from #T where Name=a.Name)

方法9(注:ID为唯一时可用):
select * from #T a where ID in(select min(ID) from #T group by Name)

--SQL2005:

方法10:
select ID,Name,Memo from (select *,min(ID)over(partition by Name) as MinID from #T a)T where ID=MinID

方法11:

select ID,Name,Memo from (select *,row_number()over(partition by Name order by ID) as MinID from #T a)T where MinID=1

生成结果:
/*
ID          Name Memo
----------- ---- ----
1           A    A1
4           B    B1

(2 行受影响)
*/


--II、Name相同ID最大的记录,与min相反:
方法1:
Select * from #T a where not exists(select 1 from #T where Name=a.Name and ID>a.ID)

方法2:
select a.* from #T a join (select max(ID)ID,Name from #T group by Name) b on a.Name=b.Name and a.ID=b.ID order by ID

方法3:
select * from #T a where ID=(select max(ID) from #T where Name=a.Name) order by ID

方法4:
select a.* from #T a join #T b on a.Name=b.Name and a.ID<=b.ID group by a.ID,a.Name,a.Memo having count(1)=1 

方法5:
select * from #T a group by ID,Name,Memo having ID=(select max(ID)from #T where Name=a.Name)

方法6:
select * from #T a where (select count(1) from #T where Name=a.Name and ID>a.ID)=0

方法7:
select * from #T a where ID=(select top 1 ID from #T where Name=a.name order by ID desc)

方法8:
select * from #T a where ID!<all(select ID from #T where Name=a.Name)

方法9(注:ID为唯一时可用):
select * from #T a where ID in(select max(ID) from #T group by Name)

--SQL2005:

方法10:
select ID,Name,Memo from (select *,max(ID)over(partition by Name) as MinID from #T a)T where ID=MinID

方法11:
select ID,Name,Memo from (select *,row_number()over(partition by Name order by ID desc) as MinID from #T a)T where MinID=1

生成结果2:
/*
ID          Name Memo
----------- ---- ----
3           A    A3
5           B    B2

(2 行受影响)
*/



--2、删除重复记录有大小关系时,保留大或小其中一个记录


--> --> (Roy)生成測試數據

if not object_id('Tempdb..#T') is null
    drop table #T
Go
Create table #T([ID] int,[Name] nvarchar(1),[Memo] nvarchar(2))
Insert #T
select 1,N'A',N'A1' union all
select 2,N'A',N'A2' union all
select 3,N'A',N'A3' union all
select 4,N'B',N'B1' union all
select 5,N'B',N'B2'
Go

--I、Name相同ID最小的记录(推荐用1,2,3),保留最小一条
方法1:
delete a from #T a where  exists(select 1 from #T where Name=a.Name and ID<a.ID)

方法2:
delete a  from #T a left join (select min(ID)ID,Name from #T group by Name) b on a.Name=b.Name and a.ID=b.ID where b.Id is null

方法3:
delete a from #T a where ID not in (select min(ID) from #T where Name=a.Name)

方法4(注:ID为唯一时可用):
delete a from #T a where ID not in(select min(ID)from #T group by Name)

方法5:
delete a from #T a where (select count(1) from #T where Name=a.Name and ID<a.ID)>0

方法6:
delete a from #T a where ID<>(select top 1 ID from #T where Name=a.name order by ID)

方法7:
delete a from #T a where ID>any(select ID from #T where Name=a.Name)



select * from #T

生成结果:
/*
ID          Name Memo
----------- ---- ----
1           A    A1
4           B    B1

(2 行受影响)
*/


--II、Name相同ID保留最大的一条记录:

方法1:
delete a from #T a where  exists(select 1 from #T where Name=a.Name and ID>a.ID)

方法2:
delete a  from #T a left join (select max(ID)ID,Name from #T group by Name) b on a.Name=b.Name and a.ID=b.ID where b.Id is null

方法3:
delete a from #T a where ID not in (select max(ID) from #T where Name=a.Name)

方法4(注:ID为唯一时可用):
delete a from #T a where ID not in(select max(ID)from #T group by Name)

方法5:
delete a from #T a where (select count(1) from #T where Name=a.Name and ID>a.ID)>0

方法6:
delete a from #T a where ID<>(select top 1 ID from #T where Name=a.name order by ID desc)

方法7:
delete a from #T a where ID<any(select ID from #T where Name=a.Name)


select * from #T
/*
ID          Name Memo
----------- ---- ----
3           A    A3
5           B    B2

(2 行受影响)
*/





--3、删除重复记录没有大小关系时，处理重复值


--> --> (Roy)生成測試數據
 
if not object_id('Tempdb..#T') is null
    drop table #T
Go
Create table #T([Num] int,[Name] nvarchar(1))
Insert #T
select 1,N'A' union all
select 1,N'A' union all
select 1,N'A' union all
select 2,N'B' union all
select 2,N'B'
Go

方法1:
if object_id('Tempdb..#') is not null
    drop table #
Select distinct * into # from #T--排除重复记录结果集生成临时表#

truncate table #T--清空表

insert #T select * from #    --把临时表#插入到表#T中

--查看结果
select * from #T

/*
Num         Name
----------- ----
1           A
2           B

(2 行受影响)
*/

--重新执行测试数据后用方法2
方法2:

alter table #T add ID int identity--新增标识列
go
delete a from  #T a where  exists(select 1 from #T where Num=a.Num and Name=a.Name and ID>a.ID)--只保留一条记录
go
alter table #T drop column ID--删除标识列

--查看结果
select * from #T

/*
Num         Name
----------- ----
1           A
2           B

(2 行受影响)

*/

--重新执行测试数据后用方法3
方法3:
declare Roy_Cursor cursor local for
select count(1)-1,Num,Name from #T group by Num,Name having count(1)>1
declare @con int,@Num int,@Name nvarchar(1)
open Roy_Cursor
fetch next from Roy_Cursor into @con,@Num,@Name
while @@Fetch_status=0
begin 
    set rowcount @con;
    delete #T where Num=@Num and Name=@Name
    set rowcount 0;
    fetch next from Roy_Cursor into @con,@Num,@Name
end
close Roy_Cursor
deallocate Roy_Cursor

--查看结果
select * from #T
/*
Num         Name
----------- ----
1           A
2           B

(2 行受影响)
*/

[candy_yuxi]

谢谢各位

我的是SQL2005

晚了

明天来结贴

各位有好方法烦请解答

有程序更好

-----------------------------

貌似都是夜猫子

还是早早睡吧

(⊙o⊙)不熬了，能比熊猫了

[子陌红尘]

create table test(Name varchar(10),MobilePhone varchar(10),Place varchar(10),LoveSports varchar(40),Venues varchar(10))
insert into test select 'aa','1234567','球场'  ,'羽毛球,篮球','YS001 '
insert into test select 'bb','1234567','游泳馆','游泳'       ,'81204 '
insert into test select 'cc','7654321','冰场'  ,'滑冰'       ,'95623 '
insert into test select 'aa','1234567','球场'  ,'足球'       ,'B12125'
insert into test select 'aa','1234567','球场'  ,'羽毛球'     ,'Y12121'
insert into test select 'cc','7654321','球场'  ,'羽毛球,篮球','YS121 '
go

create function f_str(@Name varchar(10),@MobilePhone varchar(10),@Place varchar(10))
returns varchar(100)
as
begin
    declare @ret varchar(8000),@LSs varchar(40)
    
    declare tc cursor for 
    select distinct LoveSports from test where Name=@Name and MobilePhone=@MobilePhone and Place=@Place
    
    open tc
    
    fetch next from tc into @ret
    
    fetch next from tc into @LSs
    
    while @@fetch_status=0
    begin
        set @LSs=@LSs+','
        
        while charindex(',',@LSs)>0
        begin
            select 
                @ret=@ret+case when charindex(','+left(@LSs,charindex(',',@LSs)), ','+@ret+',')>0 
                                 then '' else ','+left(@LSs,charindex(',',@LSs)-1) end,
                @LSs=stuff(@LSs,1,charindex(',',@LSs),'')
        end
        
        fetch next from tc into @LSs
    end
    return @ret
end
go

select Name,MobilePhone,Place,dbo.f_str(Name,MobilePhone,Place) as LoveSports from test group by Name,MobilePhone,Place
/*
Name       MobilePhone Place      LoveSports                                                                                           
---------- ----------- ---------- ---------------------------------------------------------------------------------------------------- 
aa         1234567     球场         羽毛球,篮球,足球
bb         1234567     游泳馆       游泳
cc         7654321     冰场         滑冰
cc         7654321     球场         羽毛球,篮球
*/
go


drop function f_str
drop table test
go

[candy_yuxi]

[Quote=引用 15 楼 fredrickhu 的回复:]
SQL code*/createtable tb(Namevarchar(20),MobilePhonevarchar(20),positionvarchar(20),LoveSportsvarchar(20),Venuesvarchar(20))insertinto tbvalues('aa' ,'1234567' ,'球场' ,'羽毛球,篮球' ,'YS001')insertinto tbva¡­
[/Quote]

这个查出来的数据条数对了

也加进去了，

只是如果爱好的运动字段有重复的它还是一样加
还有一些爱好运动字段里有<N/>这个是啥?

如

韩霞令	13361927237	isports	滑冰，篮球，足球，羽毛球，游泳,滑冰，篮球，足球，羽毛球，游泳
张杰	13361929360	源深	篮球，羽毛球,篮球，羽毛球,篮球，羽毛球<N/>,羽毛球，篮球,羽毛球，篮球,游泳,滑冰,滑冰，篮球，足球，羽毛球，游泳,滑冰，篮球，足球，羽毛球，游泳
王斐	13361935010	球场	足球，篮球,羽毛球，篮球
王晨	13361952265	球场	篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球
李家明	13361967596	isports	篮球，羽毛球,滑冰，篮球，足球，羽毛球，游泳
王飞	13361973289	球场	篮球，羽毛球,羽毛球，篮球,游泳
王威	13361990590	球场	足球，篮球,羽毛球，篮球
张志铭	13361992716	源深	篮球，羽毛球,滑冰，篮球，足球，羽毛球，游泳

这个能否在后期进行处理，就是我这个已经加进去之后在进行处理

只要结果对都没关系

[candy_yuxi]

谢谢各位

对于这个后续问题又开了一贴

如果各位想到答案的话

也烦请告诉我一下

谢谢

可以加我QQ540255090

[candy_yuxi]

9楼的结果出来是这样

WAVID ELIASON	13585740767	松江游泳馆	NULL
WAVID ELIASON	137658421	松江游泳馆	NULL
阿尔卡特	13764549386	球场	NULL
阿尔卡特	13816976878	源深	NULL
白波	13911605700	上海游泳馆	NULL
白波	13916605700	万体冰场	NULL
白友为	13166401040	上海游泳馆	NULL
白云	13679242435	源深	NULL
白云	13918453325	爱动卡	NULL
鲍铁军	13901696099	上海游泳馆	NULL
鲍伟	13818790593	源深	NULL
鲍伟	13916803850	isports	NULL
贝美根	13651931890	万体冰场	NULL
贝美根	13651937890	万体冰场	NULL
毕燕飞	13571760388	上海游泳馆	NULL
毕燕飞	13671760388	上海游泳馆	NULL
卞广泓	13601832825	上海游泳馆	NULL

分组后只能查询这三个字段，LoveSport字段大部分成了null，有一小部分还有是原先的，并没有加


12楼

陈伟	13817848967	松江游泳馆	游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟	13901650425	上海游泳馆	游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟	13917283833	源深	游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟	13918766440	源深	游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟	15800331609	球场	游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟	51702701	上海游泳馆	游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟明	13901845998	上海游泳馆	游泳,游泳
陈伟明	13901845998/64872589	上海游泳馆	游泳,游泳
陈玮	13364232533	松江游泳馆	游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮	13501813882	上海游泳馆	游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮	13564232533	松江游泳馆	游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮	13817236067	上海游泳馆	游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮	1390198249	源深	游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮	13916011333	源深	游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳

查的是*from 为什么只出现了三个字段

LoveSports字段有增加但是重复了，而且加了很多


---------------------------------------------------------------------
可以加我QQ540255090吗

可以远程操作一下，字段比较多，可能我真实的数据和虚伪的数据查出来有所不同

谢谢各位

[--小F--]

[Quote=引用 13 楼 candy_yuxi 的回复:]
9楼的结果出来是这样

SQL code
WAVID ELIASON13585740767 松江游泳馆NULL
WAVID ELIASON137658421 松江游泳馆NULL
阿尔卡特13764549386 球场NULL
阿尔卡特13816976878 源深NULL
白波13911605700 上海游泳馆NULL
白波13916605700 万体冰场NULL
白友为13166401040 上海游泳馆NULL
白云13679242435 源深NULL
白云13918453325 爱动卡NULL
鲍铁军13901696099 上海游泳馆NULL
鲍伟13818790593 源深NULL
鲍伟13916803850 isportsNULL
贝美根13651931890 万体冰场NULL
贝美根13651937890 万体冰场NULL
毕燕飞13571760388 上海游泳馆NULL
毕燕飞13671760388 上海游泳馆NULL
卞广泓13601832825 上海游泳馆NULL

分组后只能查询这三个字段，LoveSport字段大部分成了null，有一小部分还有是原先的，并没有加


12楼
SQL code
陈伟13817848967 松江游泳馆 游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟13901650425 上海游泳馆 游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟13917283833 源深 游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟13918766440 源深 游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟15800331609 球场 游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟51702701 上海游泳馆 游泳,游泳,游泳,篮球，羽毛球,篮球，羽毛球,篮球，羽毛球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,足球，篮球,羽毛球，篮球,游泳,游泳,游泳
陈伟明13901845998 上海游泳馆 游泳,游泳
陈伟明13901845998/64872589 上海游泳馆 游泳,游泳
陈玮13364232533 松江游泳馆 游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮13501813882 上海游泳馆 游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮13564232533 松江游泳馆 游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮13817236067 上海游泳馆 游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮1390198249 源深 游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳
陈玮13916011333 源深 游泳,篮球，羽毛球,篮球，羽毛球,羽毛球，篮球,游泳,游泳,游泳


查的是*from 为什么只出现了三个字段

LoveSports字段有增加但是重复了，而且加了很多


---------------------------------------------------------------------
可以加我QQ540255090吗

可以远程操作一下，字段比较多，可能我真实的数据和虚伪的数据查出来有所不同

谢谢各位


[/Quote]

*/

create table tb(Name varchar(20),MobilePhone varchar(20),position varchar(20),LoveSports varchar(20),Venues varchar(20))
insert into tb values('aa' , '1234567' , '球场' , '羽毛球,篮球' , 'YS001')
insert into tb values('bb' , '1234567' , '游泳馆', '游泳' , '81204')
insert into tb values('cc' , '7654321' , '冰场' , '滑冰' , '95623')
insert into tb values('aa' , '1234567' , '球场' , '足球' , 'B12125')
insert into tb values('aa' , '1234567' , '球场' , '羽毛球' , 'Y12121')
insert into tb values('cc' , '7654321' , '球场' , '羽毛球,篮球' , 'YS121')
go


-- 查询处理
SELECT *
FROM(
SELECT DISTINCT
Name,MobilePhone,max(position) as position
FROM tb group by name,MobilePhone
)A
OUTER APPLY(
SELECT
[LoveSports]= STUFF(REPLACE(REPLACE(
(
SELECT LoveSports FROM tb N
WHERE name = A.name
FOR XML AUTO
), '<N LoveSports="', ','), '"/>', ''), 1, 1, '')
)N
drop table tb

[--小F--]

*/

create table tb(Name varchar(20),MobilePhone varchar(20),position varchar(20),LoveSports varchar(20),Venues varchar(20))
insert into tb values('aa' , '1234567' , '球场' , '羽毛球,篮球' , 'YS001') 
insert into tb values('bb' , '1234567' , '游泳馆', '游泳' , '81204') 
insert into tb values('cc' , '7654321' , '冰场' , '滑冰' , '95623') 
insert into tb values('aa' , '1234567' , '球场' , '足球' , 'B12125') 
insert into tb values('aa' , '1234567' , '球场' , '羽毛球' , 'Y12121') 
insert into tb values('cc' , '7654321' , '球场' , '羽毛球,篮球' , 'YS121') 
go


-- 查询处理
SELECT *
FROM(
    SELECT DISTINCT 
        Name,MobilePhone,max(position) as position
    FROM tb group by name,MobilePhone
)A
OUTER APPLY(
    SELECT 
        [LoveSports]= STUFF(REPLACE(REPLACE(
            (
                SELECT LoveSports FROM tb N
                WHERE name = A.name
                FOR XML AUTO
            ), '<N LoveSports="', ','), '"/>', ''), 1, 1, '')
)N
drop table tb

/*
Name       MobilePhone Place      LoveSports                                                                                           
---------- ----------- ---------- ---------------------------------------------------------------------------------------------------- 
aa         1234567     球场         羽毛球,篮球,足球
bb         1234567     游泳馆       游泳
cc         7654321     球场         羽毛球,篮球
*/
 

[--小F--]

create table tb(Name varchar(20),MobilePhone varchar(20),position varchar(20),LoveSports varchar(20),Venues varchar(20))
insert into tb values('aa' , '1234567' , '球场' , '羽毛球,篮球' , 'YS001') 
insert into tb values('bb' , '1234567' , '游泳馆', '游泳' , '81204') 
insert into tb values('cc' , '7654321' , '冰场' , '滑冰' , '95623') 
insert into tb values('aa' , '1234567' , '球场' , '足球' , 'B12125') 
insert into tb values('aa' , '1234567' , '球场' , '羽毛球' , 'Y12121') 
insert into tb values('cc' , '7654321' , '球场' , '羽毛球,篮球' , 'YS121') 
go


-- 查询处理
SELECT *
FROM(
    SELECT DISTINCT 
        Name
    FROM tb
)A
OUTER APPLY(
    SELECT 
        [LoveSports]= STUFF(REPLACE(REPLACE(
            (
                SELECT LoveSports FROM tb N
                WHERE name = A.name
                FOR XML AUTO
            ), '<N LoveSports="', ','), '"/>', ''), 1, 1, '')
)N
drop table tb
/*
Name       MobilePhone Place      LoveSports                                                                                           
---------- ----------- ---------- ---------------------------------------------------------------------------------------------------- 
aa         1234567     球场         羽毛球,篮球,足球
bb         1234567     游泳馆       游泳
cc         7654321     冰场         滑冰
cc         7654321     球场         羽毛球,篮球
*/

[--小F--]

2005的

[--小F--]

10楼的贴错了

create table tb(Name varchar(20),MobilePhone varchar(20),position varchar(20),LoveSports varchar(20),Venues varchar(20))
insert into tb values('aa' , '1234567' , '球场' , '羽毛球,篮球' , 'YS001') 
insert into tb values('bb' , '1234567' , '游泳馆', '游泳' , '81204') 
insert into tb values('cc' , '7654321' , '冰场' , '滑冰' , '95623') 
insert into tb values('aa' , '1234567' , '球场' , '足球' , 'B12125') 
insert into tb values('aa' , '1234567' , '球场' , '羽毛球' , 'Y12121') 
insert into tb values('cc' , '7654321' , '球场' , '羽毛球,篮球' , 'YS121') 
go


-- 查询处理
SELECT *
FROM(
    SELECT DISTINCT 
        Name,MobilePhone,position
    FROM tb
)A
OUTER APPLY(
    SELECT 
        [LoveSports]= STUFF(REPLACE(REPLACE(
            (
                SELECT LoveSports FROM tb N
                WHERE name = A.name
                FOR XML AUTO
            ), '<N LoveSports="', ','), '"/>', ''), 1, 1, '')
)N
drop table tb
/*
Name       MobilePhone Place      LoveSports                                                                                           
---------- ----------- ---------- ---------------------------------------------------------------------------------------------------- 
aa         1234567     球场         羽毛球,篮球,足球
bb         1234567     游泳馆       游泳
cc         7654321     冰场         滑冰
cc         7654321     球场         羽毛球,篮球
*/