问个VB.netCombobox 联动问题！

2009-07-08 10:13:50 101 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

llkj0768 墨衍会员 · AI 创作全网分发关注 + 加入社区

esp32s3 spi camera gc6133调试 gc6133 spi只有master模式，同时需要esp32提供主时钟，需要有主时钟然后才能通过i2c进行初始化.测试了几种方式，记录如下。阅读详情

用的是VB.net
想做这样的效果
Combobox1为省份选择
Combobox2为城市选择
在选择省份后Combobox2自动出现与省份对应的城市
这个代码不怎么写啊？
不用数据库！直接代码！
有谁愿意给个参考！

...全文

PTA 编程题（C语言）-- 然后是几点 PTA 编程题（C语言）-- 然后是几点阅读详情

llkj0768

VB 16,718 成员 110,520 内容

+ 关注 + 加入社区

切换为时间正序

rickylee917 2011-12-11

打赏
举报

Public Class Form1
Private gRegion As New Region

Private Sub FormMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
Me.ComboBoxProvince.DropDownStyle = ComboBoxStyle.DropDownList
Me.ComboBoxCity.DropDownStyle = ComboBoxStyle.DropDownList
Me.ComboBoxTown.DropDownStyle = ComboBoxStyle.DropDownList

With Me.ComboBoxProvince
.DataSource = gRegion.ProvinceTable
.DisplayMember = "Name"
.ValueMember = "ID"
End With
End Sub

Private Sub ComboBoxProvince_SelectedValueChanged(ByVal sender As Object, ByVal e As System.EventArgs) _
Handles comboboxprovince.SelectedValueChanged
If Me.ComboBoxProvince.SelectedValue Is Nothing Then Return

With Me.ComboBoxCity
.DataSource = gRegion.GetCities(Me.ComboBoxProvince.SelectedValue.ToString)
.DisplayMember = "Name"
.ValueMember = "ID"
End With
End Sub

Private Sub ComboBoxCity_SelectedValueChanged(ByVal sender As Object, ByVal e As System.EventArgs) _
Handles ComboBoxCity.SelectedValueChanged
If Me.ComboBoxCity.SelectedValue Is Nothing Then Return

With Me.ComboBoxTown
.DataSource = gRegion.GetTowns(Me.ComboBoxCity.SelectedValue.ToString)
.DisplayMember = "Name"
.ValueMember = "ID"
End With
End Sub
End Class

Public Class Region
Private gProvinceTable As DataTable
Private gCityTable As DataTable
Private gTownTable As DataTable

Sub New()
gProvinceTable = New DataTable("Provice")
With gProvinceTable
.Columns.Add("ID")
.Columns.Add("Name")
.PrimaryKey = New DataColumn() {.Columns("ID")}
End With

gCityTable = New DataTable("City")
With gCityTable
.Columns.Add("ID")
.Columns.Add("Name")
.Columns.Add("ProvinceID")
.PrimaryKey = New DataColumn() {.Columns("ID")}
End With

gTownTable = New DataTable("Town")
With gTownTable
.Columns.Add("ID")
.Columns.Add("Name")
.Columns.Add("CityID")
.PrimaryKey = New DataColumn() {.Columns("ID")}
End With

With gProvinceTable.Rows
.Add(New Object() {"01", "河北省"})
.Add(New Object() {"02", "山西省"})
End With

With gCityTable.Rows
.Add(New Object() {"001", "石家庄市", "01"})
.Add(New Object() {"002", "唐山市", "01"})
.Add(New Object() {"003", "太原市", "02"})
.Add(New Object() {"004", "大同市", "02"})
End With

With gTownTable.Rows
.Add(New Object() {"00001", "井陉县", "001"})
.Add(New Object() {"00002", "正定县", "001"})
.Add(New Object() {"00003", "滦　县", "002"})
.Add(New Object() {"00004", "滦南县", "002"})
.Add(New Object() {"00005", "清徐县", "003"})
.Add(New Object() {"00006", "阳曲县", "003"})
.Add(New Object() {"00007", "阳高县", "004"})
.Add(New Object() {"00008", "天镇县", "004"})
End With

gProvinceTable.AcceptChanges()
gCityTable.AcceptChanges()
gTownTable.AcceptChanges()
End Sub

Public ReadOnly Property ProvinceTable() As DataTable
Get
Return gProvinceTable
End Get
End Property

Public ReadOnly Property CityTable() As DataTable
Get
Return gCityTable
End Get
End Property

Public ReadOnly Property TownTable() As DataTable
Get
Return gTownTable
End Get
End Property

Public Function GetCities(ByVal provinceID As String) As DataView
Return New DataView(Me.CityTable, String.Format("ProvinceID = '{0}'", provinceID), "ID", DataViewRowState.CurrentRows)
End Function

Public Function GetTowns(ByVal CityID As String) As DataView
Return New DataView(Me.TownTable, String.Format("CityID = '{0}'", CityID), "ID", DataViewRowState.CurrentRows)
End Function

End Class

问个VB.netCombobox 联动问题！

相关推荐