求一个查询方法！！

[dream__life]

一个无限极部门表，其中有2个字段DepID和FatherDepID，DepID是自动增长的。

现在需要查询出给定部门的所有子部门，即给出一个DepID，查处他所有的子部门的DepID。

哪位大虾帮帮忙，我对SQLSERVER不怎么熟。

[--小F--]

--bom结构，查找节点下所有子节点：

create table os(id int,parentid int,desn varchar(10))
insert into os select 1,0,'体育用品'
insert into os select 2,0,'户外运动'
insert into os select 3,1,'篮球'
insert into os select 4,1,'足球'
insert into os select 5,2,'帐篷'
insert into os select 6,2,'登山鞋'
insert into os select 7,0,'男士用品'
insert into os select 8,7,'刮胡刀'
insert into os select 9,3,'大号篮球'

--求个节点下所有子节点：
create function f_cid(@id int)
returns varchar(500)
as
begin
     declare @t table(id int,parentid int,desn varchar(10),lev int)
     declare @lev int
     set @lev=1
     insert into @t select *,@lev from  os where id=@id
     while(@@rowcount>0)
     begin
          set @lev=@lev+1
          insert into @t select a.*,@lev from os a,@t b
          where a.parentid=b.id and b.lev=@lev-1
     end
     declare @cids varchar(500)
     select @cids=isnull(@cids+',','')+ltrim(id) from @t order by lev
     return @cids
end
go

--调用函数
select *,ids=dbo.f_cid(id) from os


--得到每个节点路径：
create proc wsp2
@id int
as
select *,cast(' ' as varchar(10)) fullpath  into #os from os
DECLARE @i int,@j int
set @i=0
set @j=1
select @i=max(parentid) from #os
update #os set fullpath=id 
while @j<=@i
begin
       update #os set fullpath=a.fullpath+','+ltrim(#os.id) 
            from #os inner join #os a on #os.parentid=a.id 
       where #os.parentid=@j 
       set @j=@j+1
end
select * from #os
go
--调用存储过程
exec wsp2 1


----------------------------------------------------------------------------------------------------------------
create table tb(id varchar(3) , pid varchar(3) , name varchar(10)) 
insert into tb values('001' , null  , '广东省') 
insert into tb values('002' , '001' , '广州市') 
insert into tb values('003' , '001' , '深圳市') 
insert into tb values('004' , '002' , '天河区') 
insert into tb values('005' , '003' , '罗湖区') 
insert into tb values('006' , '003' , '福田区') 
insert into tb values('007' , '003' , '宝安区') 
insert into tb values('008' , '007' , '西乡镇') 
insert into tb values('009' , '007' , '龙华镇') 
insert into tb values('010' , '007' , '松岗镇') 
go 

--查询指定节点及其所有子节点的函数 
create function f_cid(@ID varchar(3)) returns @t_level table(id varchar(3) , level int) 
as 
begin 
  declare @level int 
  set @level = 1 
  insert into @t_level select @id , @level 
  while @@ROWCOUNT > 0 
  begin 
    set @level = @level + 1 
    insert into @t_level select a.id , @level 
    from tb a , @t_Level b 
    where a.pid = b.id and b.level = @level - 1 
  end 
  return 
end 
go 

--调用函数查询001(广东省)及其所有子节点 
select a.* from tb a , f_cid('001') b where a.id = b.id order by a.id 
/* 
id  pid  name      
---- ---- ---------- 
001  NULL 广东省 
002  001  广州市 
003  001  深圳市 
004  002  天河区 
005  003  罗湖区 
006  003  福田区 
007  003  宝安区 
008  007  西乡镇 
009  007  龙华镇 
010  007  松岗镇 

（所影响的行数为 10 行） 
*/ 

--调用函数查询002(广州市)及其所有子节点 
select a.* from tb a , f_cid('002') b where a.id = b.id order by a.id 
/* 
id  pid  name      
---- ---- ---------- 
002  001  广州市 
004  002  天河区 

（所影响的行数为 2 行） 
*/ 

--调用函数查询003(深圳市)及其所有子节点 
select a.* from tb a , f_cid('003') b where a.id = b.id order by a.id 
/* 
id  pid  name      
---- ---- ---------- 
003  001  深圳市 
005  003  罗湖区 
006  003  福田区 
007  003  宝安区 
008  007  西乡镇 
009  007  龙华镇 
010  007  松岗镇 

（所影响的行数为 7 行） 
*/ 

drop table tb 
drop function f_cid


----------------------------------------------------------------------------------------------------------------
set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
go


ALTER trigger [tri_updatesalary_Mem_Type]
 on [dbo].[SalaryIncrease]
after  insert
as
 declare @i int
 set @i=@@identity
 
 update m
 set m.Mem_Type=case when s.SMark>500000 then '退休会员'--500000
                   when s.SMark>400000 then '钻石五级'--400000
                   when s.SMark>300000 then '钻石四级'--300000
                   when s.SMark>200000 then '钻石三级'--200000
                   when s.SMark>100000 then '钻石二级'--100000
                   when s.SMark>50000 then '钻石一级'--50000
                   when s.SMark>40000 then '五星级'--40000
                   when s.SMark>30000 then '四星级'--30000
                   when s.SMark>20000 then '三星级'--20000
                   when s.SMark>10000 then '二星级'--10000
                   when s.SMark>5000 then '一星级'--5000
                   else '一般VIP会员'
               end
from MemberInfo m
  join (select s.SCardName,sum(s.SMark) as SMark 
          from SalaryIncrease s join inserted i on s.SCardName=i.SCardName group by s.SCardName) s
    on m.Mem_Num=s.SCardName 
 
 --if exists(select * from MemberInfo m join inserted i on m.Mem_Num=i.SCardName and m.Mem_Mark>100 )
 if exists (select  m.SCardName,sum(m.ShopMark)as mark from(select m.SCardName,m.ShopMark  from ShoppingMark m join inserted i on m.SCardName=i.SCardName
where year(m.SDate)=year(getdate()) and month(m.SDate)=month(getdate())) m
 group by m.SCardName  having sum(m.ShopMark)>100)
 /**/
/* --最新的(我写的,上面是整合魅影的)select * from ShoppingMark SM join (select m.SCardName,sum(m.ShopMark) as Mark from ShoppingMark m join inserted i on m.SCardName=i.SCardName group by m.SCardName) s
 on SM.SCardName=s.ScardName where month(SDate)=month(getdate()) and year(SDate)=year(getdate()) and s.Mark>100*/
begin
 update s
   set s.SIncease=case
                      --积分大于1000就是星级.所以不用判断是否是星级
                   when m.Mem_Type<>'一般VIP会员' then s.SMark*0.3
                   else case 
                          when s.SMark>4000 then 
                               s.SMark*0.3
                        --  when s.SMark>4000 then 
                             --  200*0.2+200*0.23+200*0.25+200*0.28+(s.SMark-800)*0.3
                          when s.SMark>3000 then 
                               1000*0.2+1000*0.23+1000*0.25+(s.SMark-600)*0.28
                          when s.SMark>2000 then 
                               1000*0.2+100*0.23+(s.SMark-400)*0.25  
                          when s.SMark>1000 then
                               (s.SMark-200)*.023+1000*0.2
                          else  s.SMark*0.2
                       end
                  end
 from SalaryIncrease as s
 join inserted i
    on s.SCardName=i.SCardName
  join MemberInfo m
    on (i.SCardName=m.Mem_Num and s.SID=@i) or (i.SCardName=m.Mem_Num and s.SIncease=0)
    end
--go

[feixianxxx]

--测试数据
CREATE TABLE tb(ID char(3),PID char(3),Name nvarchar(10))
INSERT tb SELECT '001',NULL ,'山东省'
UNION ALL SELECT '002','001','烟台市'
UNION ALL SELECT '004','002','招远市'
UNION ALL SELECT '003','001','青岛市'
UNION ALL SELECT '005',NULL ,'四会市'
UNION ALL SELECT '006','005','清远市'
UNION ALL SELECT '007','006','小分市'
GO

--查询指定节点及其所有子节点的函数
CREATE FUNCTION f_Cid(@ID char(3))
RETURNS @t_Level TABLE(ID char(3),Level int)
AS
BEGIN
	DECLARE @Level int
	SET @Level=1
	INSERT @t_Level SELECT @ID,@Level
	WHILE @@ROWCOUNT>0
	BEGIN
		SET @Level=@Level+1
		INSERT @t_Level SELECT a.ID,@Level
		FROM tb a,@t_Level b
		WHERE a.PID=b.ID
			AND b.Level=@Level-1
	END
	RETURN
END
GO

--调用函数查询002及其所有子节点
SELECT a.*
FROM tb a,f_Cid('002') b
WHERE a.ID=b.ID
/*--结果
ID   PID  Name       
------ ------- ---------- 
002  001  烟台市
004  002  招远市
--*/

[feixianxxx]

--这个是找出父节点的方法 上面 是找出子节点的

CREATE FUNCTION f_Pid(@ID char(3))
RETURNS @t_Level TABLE(ID char(3),Level int)
AS
BEGIN
	DECLARE @Level int
	SET @Level=1
	INSERT @t_Level SELECT @ID,@Level
	WHILE @@ROWCOUNT>0
	BEGIN
		SET @Level=@Level+1
		INSERT @t_Level SELECT a.PID,@Level
		FROM tb a,@t_Level b
		WHERE a.ID=b.ID
			AND b.Level=@Level-1
	END
	RETURN
END
GO


--上面的用户定义函数可以处理一个节点有多个父节点的情况，对于标准的树形数据而言，由于每个节点仅有一个父节点，所以也可以通过下面的用户定义函数实现查找标准树形数据的父节点。
CREATE FUNCTION f_Pid(@ID char(3))
RETURNS @t_Level TABLE(ID char(3))
AS
BEGIN
	INSERT @t_Level SELECT @ID
	SELECT @ID=PID FROM tb
	WHERE ID=@ID
		AND PID IS NOT NULL
	WHILE @@ROWCOUNT>0
	BEGIN
		INSERT @t_Level SELECT @ID
		SELECT @ID=PID FROM tb
		WHERE ID=@ID
			AND PID IS NOT NULL
	END
	RETURN
END

[guguda2008]

真长啊

[sdhdy]

楼上说的很详细了。

[JonasFeng]

[Quote=引用 3 楼 feixianxxx 的回复:]
SQL code--这个是找出父节点的方法 上面 是找出子节点的CREATEFUNCTION f_Pid(@IDchar(3))RETURNS@t_LevelTABLE(IDchar(3),Levelint)ASBEGINDECLARE@LevelintSET@Level=1INSERT@t_LevelSELECT@ID,@LevelWHILE@@ROWCOUNT>0BEGINSET@Level=¡­
[/Quote]

MARK

[dream__life]

感谢各位！！！搞定！

[jimwoo]

mark