求超级郁闷的SQL语句

[csbinchina]

现有一个如下表:

id parentid name
1 0 aaa
2 1 bbbb
3 2 cccc
4 2 bbbb
5 4 eeee

parentid 表示此记录属于id与他相等记录的子记录.

能不能写一个sql语句,当id=4时能查出最后2条,id=1时,能查出所有记录.

谢谢各位了....

[guguda2008]

循环可以实现你的愿望

[feixianxxx]

--测试数据
if OBJECT_ID('tb') is not null 
drop table tb 
go
CREATE TABLE tb(ID char(3),PID char(3),Name nvarchar(10))
INSERT tb SELECT '001',NULL ,'山东省'
UNION ALL SELECT '002','001','烟台市'
UNION ALL SELECT '004','002','招远市'
UNION ALL SELECT '003','001','青岛市'
UNION ALL SELECT '005',NULL ,'四会市'
UNION ALL SELECT '006','005','清远市'
UNION ALL SELECT '007','006','小分市'
GO
--2000的方法

--查询指定节点及其所有子节点的函数
CREATE FUNCTION f_Cid(@ID char(3))
RETURNS @t_Level TABLE(ID char(3),Level int)
AS
BEGIN
declare @Level int
set @level=1
insert @t_level select @id,@level
while @@rowcount>0
begin 
    set @level=@level+1
    insert @t_Level select tb.id,@level
     from tb join @t_level t on tb.pid=t.id
     where t.level+1=@level
   end
   return
end

select tb.*
from tb join dbo.f_cid('002') b
on tb.ID=b.id
/*
ID   PID  Name
---- ---- ----------
002  001  烟台市
004  002  招远市

*/
go
--2005的方法（CTE）

declare @n varchar(10)
set @n='002'
;with 
jidian as
(
  select * from tb where ID=@n
  union all
  select t.* from jidian j join tb t on j.ID=t.PID
)
select * from jidian 
go
/*

[sdhdy]

楼主参考一下这个吧。

--bom结构，查找节点下所有子节点：
if object_id('bom') is not null 
drop table bom
go
create table bom(id int,parentid int,desn nvarchar(10))
insert into bom select 1,0,N'体育用品'
insert into bom select 2,0,N'户外运动'
insert into bom select 3,1,N'篮球'
insert into bom select 4,1,N'足球'
insert into bom select 5,2,N'帐篷'
insert into bom select 6,2,N'登山鞋'
insert into bom select 7,0,N'男士用品'
insert into bom select 8,7,N'刮胡刀'
insert into bom select 9,3,N'大号篮球'
go
--求一个节点下所有子节点：
create function GetChildNode(@id int)
returns @tb table(id int,parentid int,desn varchar(10),lev int)
as
begin
     declare @lev int
     set @lev=1
     insert into @tb select *,@lev from  bom where id=@id
     while(@@rowcount>0)
     begin
          set @lev=@lev+1
          insert into @tb select a.*,@lev from bom a,@tb b
          where a.parentid=b.id and b.lev=@lev-1
     end
     return
end
go

--调用函数
declare @id int
set @id=1
select * from dbo.GetChildNode(@id)
/*
id          parentid    desn          lev         
----------- ----------- ---------- ----------- 
1           0           体育用品       1
3           1           篮球           2
4           1           足球           2
9           3           大号篮球       3
*/

[SQL77]

BOM结构,不懂

[华夏小卒]

不是很明白

[--小F--]

CREATE TABLE BOM(PID INT,ID INT)
INSERT INTO BOM SELECT 801,101
INSERT INTO BOM SELECT 801,102
INSERT INTO BOM SELECT 801,103
INSERT INTO BOM SELECT 801,601
INSERT INTO BOM SELECT 601,101
INSERT INTO BOM SELECT 601,105
INSERT INTO BOM SELECT 601,501
INSERT INTO BOM SELECT 501,106
INSERT INTO BOM SELECT 501,121
GO

CREATE FUNCTION F_GETROOT(@PID INT)
RETURNS INT
AS
BEGIN
    DECLARE @ID INT
    WHILE EXISTS(SELECT 1 FROM BOM WHERE ID=@PID)
    BEGIN
        SET @ID=@PID
        SELECT @PID=PID FROM BOM WHERE ID=@ID
    END
    RETURN @PID
END
GO

SELECT PID=DBO.F_GETROOT(PID),ID FROM BOM
GO

/*
PID         ID
----------- ----------- 
801         101
801         102
801         103
801         601
801         101
801         105
801         501
801         106
801         121
*/


DROP FUNCTION F_GETROOT
DROP TABLE BOM
GO




--生成测试数据
create table BOM_1(Item int,bom_head varchar(20),bom_child varchar(20),number int,products_attribute  varchar(20))
insert into BOM_1 select 1 ,'A' ,'A1',1,'采购'
insert into BOM_1 select 2 ,'A' ,'A2',2,'生产'
insert into BOM_1 select 3 ,'A2','A3',3,'生产'
insert into BOM_1 select 4 ,'A2','A4',2,'采购'
insert into BOM_1 select 5 ,'A3','A5',2,'采购'
insert into BOM_1 select 6 ,'A3','A6',1,'采购'
insert into BOM_1 select 7 ,'B' ,'B1',1,'采购'
insert into BOM_1 select 8 ,'B' ,'B2',2,'生产'
insert into BOM_1 select 9 ,'B2','B3',3,'生产'
insert into BOM_1 select 10,'B2','B4',2,'采购'
insert into BOM_1 select 11,'B3','B5',2,'采购'
insert into BOM_1 select 12,'B3','B6',2,'采购'
go
   

--创建用户定义函数，用于取每个父节点下子节点的采购配置信息
create function f_stock(@bom_head varchar(20))
returns @t table(bom varchar(20),number int)
as
begin 
    declare @level int
    declare @a table(bom varchar(20),number int,products_attribute varchar(20),[level] int)
    set @level=1

    if exists(select 1 from BOM_1 where bom_head=@bom_head)    
    insert into @a 
    select bom_child,number,products_attribute,@level 
    from BOM_1 
    where bom_head=@bom_head
    
    while exists(select 1 from @a where [level]=@level and products_attribute='生产')
    begin
        set @level=@level+1
        insert into @a(bom,number,products_attribute,[level])
        select a.bom_child,a.number,a.products_attribute,@level 
        from BOM_1 a,@a b
        where a.bom_head=b.bom and b.[level]=@level-1
    end
    
    insert into @t(bom,number) select bom,number from @a where products_attribute='采购'
    return
end
go


--执行调用，取父节点'A'一个标准配置分解的采购信息及数量
select * from dbo.f_stock('A')






--生成测试数据
create table BOM(ID INT,PID INT,MSG VARCHAR(1000))
insert into BOM select 1,0,NULL
insert into BOM select 2,1,NULL
insert into BOM select 3,1,NULL
insert into BOM select 4,2,NULL
insert into BOM select 5,3,NULL
insert into BOM select 6,5,NULL
insert into BOM select 7,6,NULL
go

--创建用户定义函数用于取每个父节点下子节点的采购配置信息
create function f_getChild(@ID VARCHAR(10))
returns @t table(ID VARCHAR(10),PID VARCHAR(10),Level INT)
as
begin
    declare @i int
    set @i = 1
    insert into @t select ID,PID,@i from BOM where PID = @ID
    
    while @@rowcount<>0
    begin
        set @i = @i + 1
        
        insert into @t 
        select 
            a.ID,a.PID,@i 
        from 
            BOM a,@t b 
        where 
            a.PID=b.ID and b.Level = @i-1
    end
    return
end
go

--执行查询
select ID from dbo.f_getChild(3)
go

--输出结果
/*
ID
----
5
6
7
*/

--删除测试数据
drop function f_getChild
drop table BOM





创建用户定义函数,每个子节点de父节点的信息


--生成测试数据
create table BOM(ID int,parentID int,sClassName varchar(10))
insert into BOM values(1,0,'1111'      )
insert into BOM values(2,1,'1111_1'    )
insert into BOM values(3,2,'1111-1-1'  )
insert into BOM values(4,3,'1111-1-1-1') 
insert into BOM values(5,1,'1111-2'    )

go

--创建用户定义函数,每个子节点de父节点的信息
create function f_getParent(@ID int)
returns varchar(40)
as
begin
    declare @ret varchar(40)

    while exists(select 1 from BOM where ID=@ID and parentID<>0)
    begin
        select @ID=b.ID,@ret=','+rtrim(b.ID)+isnull(@ret,'')
        from
            BOM a,BOM b
        where
            a.ID=@ID and b.ID=a.parentID
    end
    
    set @ret=stuff(@ret,1,1,'')
    return @ret
end
go

--执行查询
select ID,isnull(dbo.f_getParent(ID),'') as parentID from BOM
go

--输出结果
/*
ID          parentID                                 
----------- ---------------------------------------- 
1           
2           1
3           1,2
4           1,2,3
5           1   
*/

--删除测试数据
drop function f_getParent
drop table BOM
go

[feixianxxx]

-- =========================================
-- -----------t_mac 小编-------------
   ---希望有天成为大虾---- 
-- =========================================

IF OBJECT_ID('tb') IS NOT NULL
  DROP TABLE tb
GO
CREATE TABLE tb(id  int, parentid int,   name  varchar(10))
go
insert tb SELECT 
1    ,        0       ,   'aaa' union all select 
2     ,       1      ,    'bbbb' union all select 
3     ,       2      ,    'cccc' union all select 
4     ,       2     ,     'bbbb' union all select 
5     ,       4     ,    'eeee' 
go
CREATE FUNCTION f_Cid(@ID int)
RETURNS @t_Level TABLE(ID int,Level int)
AS
BEGIN
declare @Level int
set @level=1
insert @t_level select @id,@level
while @@rowcount>0
begin 
    set @level=@level+1
    insert @t_Level select tb.id,@level
     from tb join @t_level t on tb. parentid=t.id
     where t.level+1=@level
   end
   return
end

select tb.*
from tb join dbo.f_cid(1) b
on tb.ID=b.id
/*

go
/*------------
id          parentid    name
----------- ----------- ----------
1           0           aaa
2           1           bbbb
3           2           cccc
4           2           bbbb
5           4           eeee
-------*/

[feixianxxx]

-- =========================================
-- -----------t_mac 小编-------------
   ---希望有天成为大虾---- 
-- =========================================

IF OBJECT_ID('tb') IS NOT NULL
  DROP TABLE tb
GO
CREATE TABLE tb(id  int, parentid int,   name  varchar(10))
go
insert tb SELECT 
1    ,        0       ,   'aaa' union all select 
2     ,       1      ,    'bbbb' union all select 
3     ,       2      ,    'cccc' union all select 
4     ,       2     ,     'bbbb' union all select 
5     ,       4     ,    'eeee' 
go
--2005的方法（CTE）
declare @n int
set @n=4
;with 
jidian as
(
  select * from tb where ID=@n
  union all
  select t.* from jidian j join tb t on j.ID=t. parentid
)
select * from jidian 
go
/*
id          parentid    name
----------- ----------- ----------
4           2           bbbb
5           4           eeee
-------*/

[guguda2008]

----------------------------------------------------------
--------我这个简单------------------------------------
----------------------------------------------------------
DECLARE @T TABLE(
ID INT,
PARENTID INT,
NAME VARCHAR(20)
)
INSERT INTO @T
SELECT 1,            0,          'aaa' UNION ALL
SELECT 2,            1,          'bbbb' UNION ALL
SELECT 3,            2,          'cccc' UNION ALL
SELECT 4,            2,          'bbbb' UNION ALL
SELECT 5,            4,          'eeee'

DECLARE @ID INT
SELECT @ID=4

DECLARE @TEMP TABLE(
ID INT
)
INSERT INTO @TEMP
SELECT ID FROM @T WHERE ID=@ID
WHILE EXISTS(
SELECT  1 FROM @T T
WHERE EXISTS (SELECT ID FROM @TEMP T2 WHERE T2.ID=T.PARENTID)
AND NOT EXISTS (SELECT ID FROM @TEMP T3 WHERE T3.ID=T.ID)
)
BEGIN
INSERT INTO @TEMP
SELECT  T.ID FROM @T T
WHERE EXISTS (SELECT ID FROM @TEMP T2 WHERE T2.ID=T.PARENTID)
AND NOT EXISTS (SELECT ID FROM @TEMP T3 WHERE T3.ID=T.ID)
END
SELECT * FROM @TEMP

[csbinchina]

能不能不用函数实现?

[csbinchina]

多谢大家.... 结贴去.

[feixianxxx]

[Quote=引用 10 楼 csbinchina 的回复:]
能不能不用函数实现?
[/Quote]
函数上面写了