关于表值函数的参数传递问题——为什么不能传递列名作为参数

[humorous2001]

我写了一个表值函数：

ALTER   function   [dbo].[split](@c   varchar(2000),@split   varchar(2))   
  returns   @t   table(col   varchar(20))   
  as   
    begin   
    
      while(charindex(@split,@c)<>0)   
        begin   
          insert   @t(col)   values   (substring(@c,1,charindex(@split,@c)-1))   
          set   @c   =   stuff(@c,1,charindex(@split,@c),'')   
        end   
      insert   @t(col)   values   (@c)   
      return   
    end   

然后使用下面的语句，这样报错，ParentStr是NewsBoard的字段，请问如何解决？：
"ParentStr" 不是可识别的表提示选项。如果它要作为表值函数的参数，请确保您的数据库兼容模式设置为 90。

ALTER PROCEDURE [dbo].[ShowCurrentBoardNavigation]
@BoardID int AS
begin
select BoardID,BoardName,ParentStr,ParentID from News_Board b
where BoardID =@Boardid and Convert(varchar(10),@BoardID) in (select * from split(ParentStr,','))
end

[jwdream2008]

顶！

[chuifengde]

select * from dbo.split(...)

[chuifengde]

1.用ParentStr作参数不行
2.去掉函数，改如下:
ALTER PROCEDURE [dbo].[ShowCurrentBoardNavigation]
@BoardID int AS
begin
select BoardID,BoardName,ParentStr,ParentID from News_Board b
where BoardID =@Boardid and charindex(','+ltrim(@BoardId)+',',','+ParentStr+',')>0
end

[lihan6415151528]

http://blog.csdn.net/lihan6415151528/archive/2009/08/10/4431237.aspx

[Yang_]

表值函数有这个限制,try:

ALTER PROCEDURE [dbo].[ShowCurrentBoardNavigation]
@BoardID int AS
begin
select BoardID,BoardName,ParentStr,ParentID from News_Board b
cross apply (select * from dbo.split(b.ParentStr,',')) as t
where b.BoardID =@Boardid and Convert(varchar(10),@BoardID) = t.col
end

[xiaoliaoyun]

--更改数据库的兼容级别
DECLARE @DBName VARCHAR(100)
SELECT @DBName = db_name()
EXEC sp_dbcmptlevel @DBName,90

--然后执行存储过程

EXEC [dbo].[ShowCurrentBoardNavigation] @BoardID = 1

[xiaoliaoyun]

--更改数据库的兼容级别
DECLARE @DBName VARCHAR(100)
SELECT @DBName = db_name()
EXEC sp_dbcmptlevel @DBName,90
GO
--然后执行存储过程

EXEC [dbo].[ShowCurrentBoardNavigation] @BoardID = 1

[magic_sgx99]

-- 一、更改数据库的兼容级别
DECLARE @DBName VARCHAR(100)
SELECT @DBName = 'dagl'
EXEC sp_dbcmptlevel @DBName,90

-- 二、查询数据
select r.* from table --该表中必须含有ParentStr字段
cross apply dbo.split(ParentStr) as r