如何用DOS命令的date命令获得当前日期（只要月日）的前一天？

[doudou321]

如题

[pecker]

无法实现

[百年树人]

http://topic.csdn.net/u/20090817/15/68cb96f8-da5b-45cf-bb91-c798a7380a8f.html

参考一下7楼的

[ljc007]

test.bat

[code=BatchFile]@echo off
rem 计算指定天数之前的日期
set DaysAgo=1
rem 假设系统日期的格式为yyyy-mm-dd
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
echo %DaysAgo%天的日期是%DstMonth%月%DstDay%日
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
[/code]

[huoyanming]

[Quote=引用 3 楼 ljc007 的回复:]
test.bat

BatchFile code@echooffrem 计算指定天数之前的日期set DaysAgo=1rem 假设系统日期的格式为yyyy-mm-ddcall:DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDaysset/a PassDays-=%DaysAgo%call:DaysToDate %PassDays% DstYear DstMonth DstDayecho %DaysAgo%天的日期是%DstMonth%月%DstDay%日pausegoto:eof:DateToDays %yy% %mm% %dd% dayssetlocal ENABLEEXTENSIONSset yy=%1&set mm=%2&set dd=%3if1%yy% LSS200if1%yy% LSS170(set yy=20%yy%)else(set yy=19%yy%)set/a dd=100%dd%%%100,mm=100%mm%%%100set/a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2set/a j=j/5+dd+y*365+y/4-y/100+y/400-2472633endlocal&set%4=%j%&goto:EOF:DaysToDate %days% yy mm ddsetlocal ENABLEEXTENSIONSset/a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=aset/a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5set/a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10(if %mm% LSS10set mm=0%mm%)&(if %dd% LSS10set dd=0%dd%)endlocal&set%2=%yy%&set%3=%mm%&set%4=%dd%&goto:EOF
[/Quote]

Cattle between A and C

[夜鹰]

C:\>test
1天的日期是09月17日
请按任意键继续. . .

C:\>

-------------------------
ljc007批处理没问题。

[hm2002519]

ljc007 厉害,又帮我们解决了一个小问题,哈哈哈!

[huyangg]

can kao can kao

[开心鹰子]

真的很厉害，我试过没问题的

[jeszj]

ccccccccccccc

[luokebin110]

不用那么复杂
@echo off
set DaysAgo=1
set Today=%date:~0,4%%date:~5,2%%date:~8,2%
set /a PassDays=%Today%-1
echo %PassDays%
pause

[xiaoxbb]

高手，绝对的高手，崇拜中

[shrekz]

[Quote=引用 10 楼 luokebin110 的回复:]
不用那么复杂
@echo off
set DaysAgo=1
set Today=%date:~0,4%%date:~5,2%%date:~8,2%
set /a PassDays=%Today%-1
echo %PassDays%
pause
[/Quote]
需要注意润年和日期小于差值时的月份变化等。