请教sql

rockswj 2009-09-19 10:43:59
学生 教师 教师评价
学生1 教师1 优
学生1 教师2 一般
学生2 教师1 一般
学生2 教师2 差
学生3 教师1 优

想得到的结果是每个学生的全部评价，用逗号隔开。


学生 教师评价

学生1 优，一般
学生2 一般，差
学生3 优

最好一条语句能搞定吗？
...全文
169 11 打赏 收藏 转发到动态 举报
写回复
用AI写文章
11 条回复
切换为时间正序
请发表友善的回复…
发表回复
ws_hgo 2009-09-19
  • 打赏
  • 举报
 回复 
if object_id('tb') is not null drop table tb

go 



create table tb([学生] varchar(5),[教师] varchar(5),[教师评价] varchar(4))

insert tb

select '学生1','教师1','优' union all

select '学生1','教师2','一般' union all

select '学生2','教师1','一般' union all

select '学生2','教师2','差' union all

select '学生3','教师1','优'

--------------开始查询--------------------------

CREATE FUNCTION dbo.f_strUnite(@学生 varchar(50)) 

RETURNS varchar(8000) 

AS 

BEGIN 

    DECLARE @str varchar(8000) 

    SET @str ='' 

    SELECT @str = @str + ',' + 教师评价 FROM tb WHERE 学生=@学生 

    RETURN STUFF(@str, 1, 1, '') 

END 

GO 



select distinct([学生]),dbo.f_strUnite([学生]) as 教师评价 from tb



学生    教师评价

----- ----------------

学生1   优,一般

学生2   一般,差

学生3   优
dawugui 2009-09-19
  • 打赏
  • 举报
 回复 
--sql 2000,使用函数解决.

create table [tb]([学生] varchar(5),[教师] varchar(5),[教师评价] varchar(4))

insert [tb]

select '学生1','教师1','优' union all

select '学生1','教师2','一般' union all

select '学生2','教师1','一般' union all

select '学生2','教师2','差' union all

select '学生3','教师1','优'

go



create function dbo.f_str(@学生 varchar(5)) returns varchar(100)

as

begin

    declare @str varchar(1000)

    set @str = ''

    select @str = @str + ',' + cast(教师评价 as varchar) from tb where 学生 = @学生

    set @str = right(@str , len(@str) - 1)

    return @str

end

go



--调用函数

select 学生 , 教师评价 = dbo.f_str(学生) from tb group by 学生



drop function dbo.f_str

drop table tb



/*

学生    教师评价       

----- ----------------

学生1   优,一般

学生2   一般,差

学生3   优



（所影响的行数为 3 行）

*/


--sql 2005

create table [tb]([学生] nvarchar(5),[教师] nvarchar(5),[教师评价] nvarchar(4))

insert [tb]

select N'学生1',N'教师1',N'优' union all

select N'学生1',N'教师2',N'一般' union all

select N'学生2',N'教师1',N'一般' union all

select N'学生2',N'教师2',N'差' union all

select N'学生3',N'教师1',N'优'

go



select 学生, [教师评价] = stuff((select ',' + [教师评价] from tb t where 学生 = tb.学生 for xml path('')) , 1 , 1 , '')

from tb

group by 学生



drop table tb



/*

学生    教师评价

----- ------------

学生1   优,一般

学生2   一般,差

学生3   优



(3 行受影响)

*/
xiequan2 2009-09-19
  • 打赏
  • 举报
 回复 


--> 测试数据：[tb]

if object_id('[tb]') is not null drop table [tb]

go

create table [tb]([学生] varchar(5),[教师] varchar(5),[教师评价] varchar(4))

insert [tb]

select '学生1','教师1','优' union all

select '学生1','教师2','一般' union all

select '学生2','教师1','一般' union all

select '学生2','教师2','差' union all

select '学生3','教师1','优'







 

create function f_join(@学生 as varchar(50))

returns varchar(200)

as 

begin

declare @s varchar(200)

 select @s=isnull(@s+',','')+[教师评价] from tb where [学生]=@学生 

return @s

end





select [学生],教师评价=dbo.f_join([学生]) from [tb] group by [学生]



/*

学生    教师评价

----- --------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

学生1   优,一般

学生2   一般,差

学生3   优



(3 行受影响)



*/
feixianxxx 2009-09-19
  • 打赏
  • 举报
 回复
╮(╯▽╰)╭

好久不写。。


速度慢了 。。。

继续潜水~
feixianxxx 2009-09-19
  • 打赏
  • 举报
 回复
2000的做法 函数 
-- =========================================

-- -----------t_mac 小编-------------------

   --------------------希望有天成为大虾---- 

-- =========================================



IF OBJECT_ID('tb') IS NOT NULL

DROP TABLE tb

GO

CREATE TABLE tb( a  varchar(10),b  varchar(10) , c varchar(10) )

go

insert tb SELECT 

'学生1',                      '教师1'   ,               '优' UNION ALL SELECT 

'学生1',                      '教师2'  ,               '一般' UNION ALL SELECT 

'学生2',                      '教师1'  ,                '一般' UNION ALL SELECT 

'学生2',                      '教师2'  ,                '差' UNION ALL SELECT 

'学生3',                      '教师1' ,                 '优' 

go

CREATE FUNCTION dbo.f_tb(@id varchar(10)) 

RETURNS varchar(8000) 

AS 

BEGIN 

    DECLARE @str varchar(8000) 

    SET @str = '' 

    SELECT @str = @str + ',' + c FROM tb WHERE a=@id 

    RETURN STUFF(@str, 1, 1, '') 

END 

GO 



SELECT a as 学生, 教师评价 = dbo.f_tb(a) FROM tb GROUP BY a 

drop table tb 

drop function dbo.f_tb 

学生         教师评价

---------- ----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

学生1        优,一般

学生2        一般,差

学生3        优
--小F-- 2009-09-19
  • 打赏
  • 举报
 回复 
---2000用函数

----------------------------------------------------------------

-- Author  :fredrickhu(小F，向高手学习)

-- Date    :2009-09-19 10:45:26

-- Version:

--      Microsoft SQL Server 2005 - 9.00.4035.00 (Intel X86) 

--	Nov 24 2008 13:01:59 

--	Copyright (c) 1988-2005 Microsoft Corporation

--	Developer Edition on Windows NT 5.1 (Build 2600: Service Pack 3)

--

----------------------------------------------------------------

--> 测试数据：[tb]

if object_id('[tb]') is not null drop table [tb]

go 

create table [tb]([学生] varchar(5),[教师] varchar(5),[教师评价] varchar(4))

insert [tb]

select '学生1','教师1','优' union all

select '学生1','教师2','一般' union all

select '学生2','教师1','一般' union all

select '学生2','教师2','差' union all

select '学生3','教师1','优'

--------------开始查询--------------------------

CREATE FUNCTION dbo.f_strUnite(@id varchar(50)) 

RETURNS varchar(8000) 

AS 

BEGIN 

    DECLARE @str varchar(8000) 

    SET @str = '' 

    SELECT @str = @str + ',' + 教师评价 FROM tb WHERE 学生=@id 

    RETURN STUFF(@str, 1, 1, '') 

END 

GO 

-- 调用函数 

SELECT 学生, 教师评价 = dbo.f_strUnite(学生) FROM tb GROUP BY 学生 

drop table tb 

drop function dbo.f_strUnite 

go 

----------------结果----------------------------

/* 学生    教师评价

----- ----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

学生1   优,一般

学生2   一般,差

学生3   优



(3 行受影响)

*/
feixianxxx 2009-09-19
  • 打赏
  • 举报
 回复 
-- =========================================

-- -----------t_mac 小编-------------------

   --------------------希望有天成为大虾---- 

-- =========================================



IF OBJECT_ID('tb') IS NOT NULL

DROP TABLE tb

GO

CREATE TABLE tb( a  varchar(10),b  varchar(10) , c varchar(10) )

go

insert tb SELECT 

'学生1',                      '教师1'   ,               '优' UNION ALL SELECT 

'学生1',                      '教师2'  ,               '一般' UNION ALL SELECT 

'学生2',                      '教师1'  ,                '一般' UNION ALL SELECT 

'学生2',                      '教师2'  ,                '差' UNION ALL SELECT 

'学生3',                      '教师1' ,                 '优' 

go

select distinct  a as 学生, 

教师评价=STUFF((select ','+c from tb t where tb.a=t.a for xml path('') ),1,1,'')

from tb 



学生         教师评价

---------- ----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

学生1        优,一般

学生2        一般,差

学生3        优
config_man 2009-09-19
  • 打赏
  • 举报
 回复
路过...
--小F-- 2009-09-19
  • 打赏
  • 举报
 回复 
----------------------------------------------------------------

-- Author  :fredrickhu(小F，向高手学习)

-- Date    :2009-09-19 10:45:26

-- Version:

--      Microsoft SQL Server 2005 - 9.00.4035.00 (Intel X86) 

--	Nov 24 2008 13:01:59 

--	Copyright (c) 1988-2005 Microsoft Corporation

--	Developer Edition on Windows NT 5.1 (Build 2600: Service Pack 3)

--

----------------------------------------------------------------

--> 测试数据：[tb]

if object_id('[tb]') is not null drop table [tb]

go 

create table [tb]([学生] varchar(5),[教师] varchar(5),[教师评价] varchar(4))

insert [tb]

select '学生1','教师1','优' union all

select '学生1','教师2','一般' union all

select '学生2','教师1','一般' union all

select '学生2','教师2','差' union all

select '学生3','教师1','优'

--------------开始查询--------------------------

select 学生, [教师评价]=stuff((select ','+[教师评价] from tb t where 学生=tb.学生 for xml path('')), 1, 1, '') 

from tb 

group by 学生 

----------------结果----------------------------

/* 学生    教师评价

----- ----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

学生1   优,一般

学生2   一般,差

学生3   优



(3 行受影响)

*/
feixianxxx 2009-09-19
  • 打赏
  • 举报
 回复 
if object_id('tb') is not null

drop table tb

create table tb(aa varchar(20),bb varchar(20))

insert into tb select '奥米茄',  '地板' union all

select '瓷砖' ,'地板' union all

select '蒙娜丽莎','厨房设备' union all 

select '实木复合地板' ,'涂料' 



select  [values]=stuff((select '|'+aa from tb t where bb=tb.bb for xml path('')), 1, 1, ''),bb

from tb 

group by bb 

/*bb                   values

-------------------- --------------------

厨房设备                 蒙娜丽莎

地板                   奥米茄|瓷砖

涂料                   实木复合地板



(3 行受影响)

*/
\
参考
fanzhouqi 2009-09-19
  • 打赏
  • 举报
 回复
要个函数
[MySQL]——SQL预编译、动态sql
一条sql语句的执行过程为语法检查与解析->sql优化->编译->执行。原始的sql存在弊端，每条语句编译生成不同的SQL语句，浪费性能和空间。 两种参数占位符的区别 动态SQL的使用
SQL 语言：嵌入式 SQL 和动态 SQL
嵌入式SQL和动态SQL是两种在应用程序中嵌入和使用SQL语句的方法。它们各自具有一定的优势和局限性，适用于不同的场景。
SQL解析利器General SQL Parser
最近发现一款很有意思的工具，名字叫GSP（全称General SQL Parser）。他是一款专业的SQL引擎，适用于各种数据库。
基于AI大模型实现自然语言转SQL、SQL解释、SQL优化和SQL转换
自定义AI可以是用户自己部署的任意AI模型，例如ChatGLM、ChatGPT、文心一言、通义千问等等，但是自定义的接口输入和输出需要符合自定义的协议规范才可快速使用，否则可能需要二次开发。代码中提供了两个DEMO，只需要配置自定义AI接口地址，以及接口是否流式输出即可查看。具体使用中可以参考DEMO接口来编写自定义接口，或者直接在DEMO接口中进行二次开发，封装自己的自定义接口自定义的流式输出接口配置DEMO自定义的非流式输出接口配置DEMO。
SQL 别名和sql连接
通过使用 SQL，可以为表名称或列名称指定别名。
MS-SQL Server

34,875

社区成员

254,639

社区内容

发帖
与我相关
我的任务
社区描述
MS-SQL Server相关内容讨论专区
社区管理员
  • 基础类社区
  • 二月十六
  • 卖水果的net
加入社区
  • 近7日
  • 近30日
  • 至今

加载中

查看更多榜单
社区公告
暂无公告

试试用AI创作助手写篇文章吧

+ 用AI写文章