关于窗口最大化问题！

[ArmStronger]

Private Sub Form_Resize()
    Dim d(4) As Double
    Dim i As Long
    Dim TempPos As Long
    Dim StartPos As Long
    Dim Ctl As Control
    Dim TempVisible As Boolean
    Dim ScaleX As Double
    Dim ScaleY As Double
    
    ScaleX = ScaleWidth / InitWidth
    ScaleY = ScaleHeight / InitHeight
    On Error Resume Next
    For Each Ctl In Me
        TempVisible = Ctl.Visible
        Ctl.Visible = False
        StartPos = 1
        ' 读取 Control 的原始位置、大小、字型大小
        For i = 0 To 4
            TempPos = InStr(StartPos, Ctl.Tag, " ", vbTextCompare)
            If TempPos > 0 Then
                d(i) = Mid(Ctl.Tag, StartPos, TempPos - StartPos)
                StartPos = TempPos + 1
            Else
                d(i) = 0
            End If
            ' 根据比例设定 Control 的位置、大小、字型大小
            Ctl.Move d(0) * ScaleX, d(1) * ScaleY, d(2) * ScaleX, d(3) * ScaleY
            'Ctl.Width = D(2) * ScaleX
            'Ctl.Height = D(3) * ScaleY
            If ScaleX < ScaleY Then
                Ctl.FontSize = d(4) * ScaleX
            Else
                Ctl.FontSize = d(4) * ScaleY
            End If
        Next i
        Ctl.Visible = TempVisible
    Next Ctl
    On Error GoTo 0

End Sub

使用上面的代码 可以使窗体最大化的时候一些控件位置随之成比例改变！
但是 comBobox类型 和line类型 的没变化，怎么让他们一起改变位置呢？
还有就是窗体上的 MsflexGrid 的 列宽 怎么也一起改变？
谢谢！

[getemail]

你走入歧途了
VB是做应用的,折腾这些意义不是很大

[getemail]

comBobox的高度与字体的大小有关系,当然你也可以让它变,但是费劲与你得到的不成比例的

[ArmStronger]

[Quote=引用 1 楼 getemail 的回复:]
你走入歧途了
VB是做应用的,折腾这些意义不是很大
[/Quote]
不是啊，做系统时要当然要满足客服需求啦

[jhone99]

有的控件有特殊，这儿有一个例子，参照一下

Option Explicit
Private FormOldWidth    As Long    '保存窗体的原始宽度
Private FormOldHeight    As Long    '保存窗体的原始高度
  '在调用ResizeForm前先调用本函数
  Public Sub ResizeInit(FormName As Form)
      Dim Obj    As Control
      FormOldWidth = FormName.ScaleWidth
      FormOldHeight = FormName.ScaleHeight
      On Error Resume Next
      For Each Obj In FormName
          If TypeOf Obj Is ComboBox Then
                Obj.Tag = Obj.Left & " " & Obj.Top & " " & Obj.Width & " " & Obj.FontSize & " "
          ElseIf TypeOf Obj Is CommandButton Then
                Obj.Tag = Obj.Left & " " & Obj.Top & " " & Obj.Width & " " & Obj.Height & " " & Obj.FontSize & " "
          ElseIf TypeOf Obj Is Line Then
                Obj.Tag = Obj.X1 & " " & Obj.X2 & " " & Obj.Y1 & " " & Obj.Y2 & " " & Obj.BorderWidth & " "
          Else
                Obj.Tag = Obj.Left & " " & Obj.Top & " " & Obj.Width & " " & Obj.Height & " "

          End If
      Next Obj
      On Error GoTo 0
  End Sub

  '按比例改变表单内各元件的大小，在调用ReSizeForm前先调用ReSizeInit函数
  Public Sub ResizeForm(FormName As Form)
      Dim Pos(4)    As Double
      Dim i    As Long, TempPos      As Long, StartPos      As Long
      Dim Obj    As Control
      Dim ScaleX    As Double, ScaleY      As Double
      ScaleX = FormName.ScaleWidth / FormOldWidth          '保存窗体宽度缩放比例
      ScaleY = FormName.ScaleHeight / FormOldHeight          '保存窗体高度缩放比例
      On Error Resume Next
      For Each Obj In FormName
          StartPos = 1
          For i = 0 To 5
          '读取控件的原始位置与大小
              TempPos = InStr(StartPos, Obj.Tag, " ", vbTextCompare)
              If TempPos > 0 Then
                  Pos(i) = Mid(Obj.Tag, StartPos, TempPos - StartPos)
                  StartPos = TempPos + 1
              Else
                  Pos(i) = 0
              End If
        '根据控件的原始位置及窗体改变大小的比例对控件重新定位与改变大小
          Next i

            If TypeOf Obj Is ComboBox Then
                Obj.FontSize = Pos(3) * ScaleY
                Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, Pos(2) * ScaleX
            ElseIf TypeOf Obj Is CommandButton Then
                Obj.FontSize = Pos(4) * ScaleY
                Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, Pos(2) * ScaleX, Pos(3) * ScaleY
            ElseIf TypeOf Obj Is Line Then
                Obj.X1 = Pos(0) * ScaleX
                Obj.X2 = (Pos(1) - Pos(0)) * ScaleX + Obj.X1
                Obj.Y1 = Pos(2) * ScaleY
                Obj.Y2 = (Pos(3) - Pos(2)) * ScaleY + Obj.Y1
                Obj.BorderWidth = Pos(4) * Sqr(ScaleX * ScaleX + ScaleY * ScaleY)
            Else
                Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, Pos(2) * ScaleX, Pos(3) * ScaleY
            End If
      Next Obj
      On Error GoTo 0
  End Sub

Private Sub Form_Initialize()
    Call ResizeInit(Me)
End Sub

Private Sub Form_Resize()
    Call ResizeForm(Me)
End Sub

[ArmStronger]

谢谢楼上的，我试下

[king06]

[Quote=引用 4 楼 jhone99 的回复:]
有的控件有特殊，这儿有一个例子，参照一下
……
[/Quote]
顶了~~

也记得以前有一帖,做过这样的讨论,有比较好的代码...

[ArmStronger]

非常感谢 jhone99！用你提供的代码成功啦!

不过还请教下 MsflexGrid控件 的 列宽 怎么也一起改变？

[ArmStronger]

问题解决啦！

[R_TRIG]

列宽的问题咋解决的？