如何枚举所有桌面上的程序窗口

2009-10-23 01:36:22 405 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

保姆级教程：用Python和PyTorch复现PTB-XL心电信号分类论文（附完整代码）本文提供了一份详细的PTB-XL心电信号分类教程，涵盖从数据预处理到模型优化的完整流程。通过PyTorch实现三种深度学习架构（Conv1D、SincNet和熵特征融合网络），并针对医疗AI特有的类别不平衡问题提供解决方案。教程包含可运行的代码示例，帮助开发者快速复现论文结果并应用于实际心电信号分析场景。阅读详情

如何枚举所有桌面上的程序窗口（看不见的窗口就不需要了），请给个实例。

...全文

【C++】详解 lower_bound 和 upper_bound 函数（看不懂来捶我！！！）这两个函数是我在 LeetCode 上做题见到，看到不熟悉的函数 lower_bound 和 upper_bound让我感觉很难受，于是在C++ 官网去学习，例子就一个是最基础的，我看明白了。虽然是两个函数的接口就两个，但是有时候看别人使用的时候，里面参数还可以放不同的仿函数，我懵逼了。就去网上搜，但是大家讲解的都是它的第一个接口。我只能再把文档一遍一遍过，代码一遍遍的尝试，调试。最终通过查阅资料将其总结如下。阅读详情

sssvip123

VB基础类 7,788 成员 197,583 内容

+ 关注 + 加入社区

切换为时间正序

futurepi 2010-09-01

打赏
举报

学习了

Flyingdragon168 2009-10-23

打赏
举报

API 函数，FindWindow与EnumWindows结合。

贝隆 2009-10-23

打赏
举报

'Example Name:EnumWindows and EnumChildWindows Callbacks  



'------------------------------------------------------------------------------

'

' BAS Moduel Code

'

'------------------------------------------------------------------------------

Option Explicit 



Private Const LVIF_INDENT As Long = &H10

Private Const LVIF_TEXT As Long = &H1

Private Const LVM_FIRST As Long = &H1000

Private Const LVM_SETITEM As Long = (LVM_FIRST + 6)



Private Type LVITEM

   mask As Long

   iItem As Long

   iSubItem As Long

   state As Long

   stateMask As Long

   pszText As String

   cchTextMax As Long

   iImage As Long

   lParam As Long

   iIndent As Long

End Type



Public Declare Function EnumWindows Lib "user32" _

  (ByVal lpEnumFunc As Long, _

   ByVal lParam As Long) As Long

   

Public Declare Function EnumChildWindows Lib "user32" _

  (ByVal hWndParent As Long, _

   ByVal lpEnumFunc As Long, _

   ByVal lParam As Long) As Long



Private Declare Function GetWindowTextLength Lib "user32" _

    Alias "GetWindowTextLengthA" _

   (ByVal hwnd As Long) As Long

    

Private Declare Function GetWindowText Lib "user32" _

    Alias "GetWindowTextA" _

   (ByVal hwnd As Long, _

    ByVal lpString As String, _

    ByVal cch As Long) As Long

    

Private Declare Function GetClassName Lib "user32" _

    Alias "GetClassNameA" _

   (ByVal hwnd As Long, _

    ByVal lpClassName As String, _

    ByVal nMaxCount As Long) As Long



Private Declare Function IsWindowVisible Lib "user32" _

   (ByVal hwnd As Long) As Long

   

Private Declare Function GetParent Lib "user32" _

   (ByVal hwnd As Long) As Long



Private Declare Function SendMessage Lib "user32" _

   Alias "SendMessageA" _

  (ByVal hwnd As Long, _

   ByVal wMsg As Long, _

   ByVal wParam As Long, _

   lParam As Any) As Long





Public Function EnumWindowProc(ByVal hwnd As Long, _

                               ByVal lParam As Long) As Long

   

  'working vars

   Dim nSize As Long

   Dim sTitle As String

   Dim sClass As String

   

   Dim sIDType As String

   Dim itmX As ListItem

   Dim nodX As Node

   

  'eliminate windows that are not top-level.

   If GetParent(hwnd) = 0& And _

      IsWindowVisible(hwnd) Then

      

     'get the window title / class name

      sTitle = GetWindowIdentification(hwnd, sIDType, sClass)



     'add to the listview

      Set itmX = Form1.ListView1.ListItems.Add(Text:=sTitle, Key:=CStr(hwnd) & "h")

      itmX.SmallIcon = Form1.ImageList1.ListImages("parent").Key

      itmX.SubItems(1) = CStr(hwnd)

      itmX.SubItems(2) = sIDType

      itmX.SubItems(3) = sClass

      

   End If

   

  'To continue enumeration, return True

  'To stop enumeration return False (0).

  'When 1 is returned, enumeration continues

  'until there are no more windows left.

   EnumWindowProc = 1

   

End Function





Private Function GetWindowIdentification(ByVal hwnd As Long, _

                                         sIDType As String, _

                                         sClass As String) As String



   Dim nSize As Long

   Dim sTitle As String



  'get the size of the string required

  'to hold the window title

   nSize = GetWindowTextLength(hwnd)

   

  'if the return is 0, there is no title

   If nSize > 0 Then

   

      sTitle = Space$(nSize + 1)

      Call GetWindowText(hwnd, sTitle, nSize + 1)

      sIDType = "title"

      

      sClass = Space$(64)

      Call GetClassName(hwnd, sClass, 64)

   

   Else

   

     'no title, so get the class name instead

      sTitle = Space$(64)

      Call GetClassName(hwnd, sTitle, 64)

      sClass = sTitle

      sIDType = "class"

   

   End If

   

   GetWindowIdentification = TrimNull(sTitle)



End Function





Public Function EnumChildProc(ByVal hwnd As Long, _

                              ByVal lParam As Long) As Long

   

  'working vars

   Dim sTitle As String

   Dim sClass As String

   Dim sIDType As String

   Dim itmX As ListItem



  'get the window title / class name

   sTitle = GetWindowIdentification(hwnd, sIDType, sClass)



  'add to the listview

   Set itmX = Form2.ListView1.ListItems.Add(Text:=sTitle)

   itmX.SmallIcon = Form2.ImageList1.ListImages("child").Key

   itmX.SubItems(1) = CStr(hwnd)

   itmX.SubItems(2) = sIDType

   itmX.SubItems(3) = sClass

      

   Listview_IndentItem Form2.ListView1.hwnd, CLng(itmX.Index), 1

   

   EnumChildProc = 1

   

End Function





Private Function TrimNull(startstr As String) As String



  Dim pos As Integer



  pos = InStr(startstr, Chr$(0))

  

  If pos Then

      TrimNull = Left$(startstr, pos - 1)

      Exit Function

  End If

  

 'if this far, there was

 'no Chr$(0), so return the string

  TrimNull = startstr

  

End Function





Private Sub Listview_IndentItem(hwnd As Long, _

                                nItem As Long, _

                                nIndent As Long)



   Dim LV As LVITEM



  'if nIndent indicates that indentation

  'is requested nItem is the item to indent

   If nIndent > 0 Then

      

      With LV

        .mask = LVIF_INDENT

        .iItem = nItem - 1 'have to subtract 1

        .iIndent = nIndent

      End With

      

      Call SendMessage(hwnd, LVM_SETITEM, 0&, LV)

      

   End If

       

End Sub

'--end block--'

'------------------------------------------------------------------------------

'

' Form Code

'

'------------------------------------------------------------------------------

Option Explicit



Private Sub Command1_Click()



   ListView1.ListItems.Clear

   Call EnumWindows(AddressOf EnumWindowProc, &H0)



End Sub





Private Sub Form_Load()



   Me.Move (Screen.Width - Me.Width) / 2, (Screen.Height - Me.Height) / 2



End Sub





Private Sub ListView1_DblClick()



   Dim hwndSelected As Long

   

   hwndSelected = Val(ListView1.SelectedItem.Key)

   

   Load Form2

   Call Form2.EnumSelectedWindow(ListView1.SelectedItem.Text, hwndSelected)

   

End Sub

'--end block--'

 

 

 Form2 Code 

  

Add the following code to Form2: 



--------------------------------------------------------------------------------

 

Option Explicit



Public Sub EnumSelectedWindow(sItem As String, hwnd As Long)

 

   ListView1.ListItems.Clear

   ListView1.ListItems.Add Text:=sItem, SmallIcon:="parent"

   

   Call EnumChildWindows(hwnd, AddressOf EnumChildProc, &H0)

   

   Me.Show vbModal

   

End Sub





Private Sub Form_Load()



   Me.Move (Screen.Width - Me.Width) / 2, (Screen.Height - Me.Height) / 2

   

End Sub

帝企鹅已被占用 2009-10-23

打赏
举报

[Quote=引用 9 楼 chenjl1031 的回复:]
标准模块：

VB codeOptionExplicitPublic DeclareFunction GetDesktopWindow Lib"user32.dll" ()AsLongPublic DeclareFunction EnumChildWindows Lib"user32.dll" (ByVal hWndParentAsLong, ByVal lpEnumFuncAsLong, ByVal lParamAsLong)AsLong'Public Declare Function EnumWindows Lib "user32" (ByVal lpEnumFunc As Long, ByVal lParam As Long) As BooleanPrivate DeclareFunction GetWindowText Lib"user32" Alias"GetWindowTextA" (ByVal hwndAsLong, ByVal lpStringAsString, ByVal cchAsLong)AsLongPrivate DeclareFunction GetWindowTextLength Lib"user32" Alias"GetWindowTextLengthA" (ByVal hwndAsLong)AsLongPublicFunction EnumWindowsProc(ByVal hwndAsLong, ByVal lParamAsLong)AsBooleanDim windowCaptionAsString, LengthCaptionAsLongOnErrorResumeNext
LengthCaption= GetWindowTextLength(hwnd)
windowCaption=Space$(LengthCaption)Call GetWindowText(hwnd, windowCaption, LengthCaption+1)
Form1.List1.AddItem Str$(hwnd)&""& windowCaption
EnumWindowsProc=TrueEnd Function

VB code'窗体Form1代码OptionExplicit'窗体上添加一个命令按钮Command1，一个列表框List1PrivateSub Command1_Click()Dim DeskTopHwndAsLong
DeskTopHwnd= GetDesktopWindow
EnumChildWindows DeskTopHwnd, AddressOf EnumWindowsProc, ByVal0&End Sub
[/Quote]
顶

东方之珠 2009-10-23

打赏
举报

标准模块：

Option Explicit



Public Declare Function GetDesktopWindow Lib "user32.dll" () As Long

Public Declare Function EnumChildWindows Lib "user32.dll" (ByVal hWndParent As Long, ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long

'Public Declare Function EnumWindows Lib "user32" (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Boolean

Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

Private Declare Function GetWindowTextLength Lib "user32" Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Long

Public Function EnumWindowsProc(ByVal hwnd As Long, ByVal lParam As Long) As Boolean

       Dim windowCaption As String, LengthCaption As Long

       

       On Error Resume Next

       LengthCaption = GetWindowTextLength(hwnd)

       windowCaption = Space$(LengthCaption)

       Call GetWindowText(hwnd, windowCaption, LengthCaption + 1)

       Form1.List1.AddItem Str$(hwnd) & "   " & windowCaption

       EnumWindowsProc = True

End Function

'窗体Form1代码

Option Explicit

'窗体上添加一个命令按钮Command1，一个列表框List1

Private Sub Command1_Click()

        Dim DeskTopHwnd As Long

        DeskTopHwnd = GetDesktopWindow

        EnumChildWindows DeskTopHwnd, AddressOf EnumWindowsProc, ByVal 0&

End Sub