34,593
社区成员
发帖
与我相关
我的任务
分享如何限定select+left join出来的记录的条数
有如下两个表
职位表
ID 所属企业Id 职位名 发布时间
1 1 美工 2009-1-1
2 1 技术 2009-1-2
3 1 开发 2009-1-3
4 2 设计 2009-1-4
5 2 美工 2009-1-5
企业表
ID 企业名
1 微软
2 金山
现在是 select top 4 职位名, 企业名 from 职位表 left join 企业表 order by 发布时间
取出来的是
职位名 企业名
美工 微软
技术 微软
开发 微软
设计 金山
可我想, 对于同一个企业, 每次最多只取2条出来, 所以取出来的应该是
职位名 企业名
美工 微软
技术 微软
设计 金山
美工 金山
请问有什么好的办法?
职位表
ID 所属企业Id 职位名 发布时间
1 1 美工 2009-1-1
2 1 技术 2009-1-2
3 1 开发 2009-1-3
4 2 设计 2009-1-4
5 2 美工 2009-1-5
企业表
ID 企业名
1 微软
2 金山
现在是 select top 4 职位名, 企业名 from 职位表 left join 企业表 order by 发布时间
取出来的是
职位名 企业名
美工 微软
技术 微软
开发 微软
设计 金山
可我想, 对于同一个企业, 每次最多只取2条出来, 所以取出来的应该是
职位名 企业名
美工 微软
技术 微软
设计 金山
美工 金山
请问有什么好的办法?
...全文
请发表友善的回复…
发表回复
ws_hgo 2009-11-02
- 打赏
- 举报
你们好快啊
水族杰纶 2009-11-02
- 打赏
- 举报
ws_hgo 2009-11-02
- 打赏
- 举报
create table #employee
(
ID int identity(1,1) primary key,
所属企业Id int,
职位名 varchar(20),
发布时间 datetime
)
insert into #employee select 1,'美工','2009-1-1'
union all select 1,'技术','2009-1-2'
union all select 1,'开发','2009-1-3'
union all select 2,'设计','2009-1-4'
union all select 2,'美工','2009-1-5'
create table #company
(
ID int identity(1,1) primary key,
企业名 varchar(20)
)
insert into #company select '微软'
insert into #company select '金山'
select 企业名,职位名 from
(
select 职位名,所属企业Id,row_number() over(partition by 所属企业Id order by 发布时间) rank from
#employee
) E join #company
on 所属企业Id=ID where rank<=2
企业名 职位名
-------------------- --------------------
微软 美工
微软 技术
金山 设计
金山 美工
--小F-- 2009-11-02
- 打赏
- 举报
----------------------------------------------------------------
-- Author :fredrickhu(我是小F，向高手学习)
-- Date :2009-11-02 11:52:23
-- Version:
-- Microsoft SQL Server 2005 - 9.00.4035.00 (Intel X86)
-- Nov 24 2008 13:01:59
-- Copyright (c) 1988-2005 Microsoft Corporation
-- Developer Edition on Windows NT 5.2 (Build 3790: Service Pack 1)
--
----------------------------------------------------------------
--> 测试数据：[职位表]
if object_id('[职位表]') is not null drop table [职位表]
go
create table [职位表]([ID] int,[所属企业Id] int,[职位名] varchar(4),[发布时间] datetime)
insert [职位表]
select 1,1,'美工','2009-1-1' union all
select 2,1,'技术','2009-1-2' union all
select 3,1,'开发','2009-1-3' union all
select 4,2,'设计','2009-1-4' union all
select 5,2,'美工','2009-1-5'
--> 测试数据：[企业表]
if object_id('[企业表]') is not null drop table [企业表]
go
create table [企业表]([ID] int,[企业名] varchar(4))
insert [企业表]
select 1,'微软' union all
select 2,'金山'
--------------开始查询--------------------------
;with f as
(
select a. 所属企业Id,a.职位名,a.发布时间,b.* from [职位表] a join [企业表] b on a.所属企业Id=b.id
)
SELECT 职位名,企业名 FROM f AS T WHERE 2>(SELECT COUNT(1) FROM f WHERE 企业名=T.企业名 AND 发布时间>T.发布时间)
----------------结果----------------------------
/*职位名 企业名
---- ----
技术 微软
开发 微软
设计 金山
美工 金山
(4 行受影响)
*/
SQL77 2009-11-02
- 打赏
- 举报
select 职位名, 企业名,发布时间 INTO #T from 职位表 left join 企业表 order by 发布时间
SELECT 职位名, 企业名 FROM #T T WHERE
发布时间=(SELECT TOP 2 发布时间 FROM #T WHERE 企业名=T.企业名 ORDER BY 发布时间 )也可以用排序列
xiequan2 2009-11-02
- 打赏
- 举报
---------------------------------
-- Author: liangCK 小梁
-- Title : 查每个分组前N条记录
-- Date : 2008-11-13 17:19:23
---------------------------------
--> 生成测试数据: #T
IF OBJECT_ID('tempdb.dbo.#T') IS NOT NULL DROP TABLE #T
CREATE TABLE #T (ID VARCHAR(3),GID INT,Author VARCHAR(29),Title VARCHAR(39),Date DATETIME)
INSERT INTO #T
SELECT '001',1,'邹建','深入浅出SQLServer2005开发管理与应用实例','2008-05-10' UNION ALL
SELECT '002',1,'胡百敬','SQLServer2005性能调校','2008-03-22' UNION ALL
SELECT '003',1,'格罗夫Groff.J.R.','SQL完全手册','2009-07-01' UNION ALL
SELECT '004',1,'KalenDelaney','SQLServer2005技术内幕存储引擎','2008-08-01' UNION ALL
SELECT '005',2,'Alex.Kriegel.Boris.M.Trukhnov','SQL宝典','2007-10-05' UNION ALL
SELECT '006',2,'飞思科技产品研发中心','SQLServer2000高级管理与开发','2007-09-10' UNION ALL
SELECT '007',2,'胡百敬','SQLServer2005数据库开发详解','2008-06-15' UNION ALL
SELECT '008',3,'陈浩奎','SQLServer2000存储过程与XML编程','2005-09-01' UNION ALL
SELECT '009',3,'赵松涛','SQLServer2005系统管理实录','2008-10-01' UNION ALL
SELECT '010',3,'黄占涛','SQL技术手册','2006-01-01'
--SQL查询如下:
--按GID分组,查每个分组中Date最新的前2条记录
--1.字段ID唯一时:
SELECT * FROM #T AS T WHERE ID IN(SELECT TOP 2 ID FROM #T WHERE GID=T.GID ORDER BY Date DESC)
--2.如果ID不唯一时:
SELECT * FROM #T AS T WHERE 2>(SELECT COUNT(*) FROM #T WHERE GID=T.GID AND Date>T.Date)
--SQL Server 2005 使用新方法
--3.使用ROW_NUMBER()进行排位分组
SELECT ID,GID,Author,Title,Date
FROM
(
SELECT rid=ROW_NUMBER() OVER(PARTITION BY GID ORDER BY Date DESC),*
FROM #T
) AS T
WHERE rid<=2
--4.使用APPLY
SELECT DISTINCT b.*
FROM #T AS a
CROSS APPLY
(
SELECT TOP(2) * FROM #T WHERE a.GID=GID ORDER BY Date DESC
) AS b
--结果
/*
ID GID Author Title Date
---- ----------- ----------------------------- --------------------------------------- -----------------------
003 1 格罗夫Groff.J.R. SQL完全手册 2009-07-01 00:00:00.000
004 1 KalenDelaney SQLServer2005技术内幕存储引擎 2008-08-01 00:00:00.000
005 2 Alex.Kriegel.Boris.M.Trukhnov SQL宝典 2007-10-05 00:00:00.000
007 2 胡百敬 SQLServer2005数据库开发详解 2008-06-15 00:00:00.000
009 3 赵松涛 SQLServer2005系统管理实录 2008-10-01 00:00:00.000
010 3 黄占涛 SQL技术手册 2006-01-01 00:00:00.000
(6 行受影响)
*/
--得到每组前几条数据
--假設每組Col1中， Col3不會重復
--建立測試環境
Create Table TEST
(Col1 Varchar(10),
Col2 Varchar(10),
Col3 Int)
--插入數據
Insert TEST Select 'BD1V','Label', 4
Union All Select 'BD1V', 'BATT', 2
Union All Select 'BD1V', 'ODD', 3
Union All Select 'BD1V', 'HDD', 5
Union All Select 'BD1V', 'LCD', 1
Union All Select 'BD1W','HDD', 3
Union All Select 'BD1W','RAM', 8
Union All Select 'BD1W','TP CABLE', 5
Union All Select 'BD1W','LCD', 6
Union All Select 'BD1W','Label', 2
Union All Select 'BL3', 'LCD CABLE', 7
Union All Select 'BL3', 'LABEL', 6
Union All Select 'BL3', 'LCD', 5
Union All Select 'BL3', 'RAM', 1
Union All Select 'BL3D', 'Label', 4
GO
--測試
--方法一：
Select Col1, Col2, Col3 From TEST A
Where (Select Count(*) From TEST Where Col1 = A.Col1 And Col3 > A.Col3) < 3
Order By Col1, Col3 Desc
--方法二：
Select Col1, Col2, Col3 From TEST A
Where Exists (Select Count(*) From TEST Where Col1 = A.Col1 And Col3 > A.Col3 Having Count(*) < 3)
Order By Col1, Col3 Desc
--方法三：
Select Col1, Col2, Col3 From TEST A
Where Col3 In (Select TOP 3 Col3 From TEST Where Col1 = A.Col1 Order By Col3 Desc)
Order By Col1, Col3 Desc
GO
--刪除測試環境
Drop Table TEST
--結果
/*
Col1 Col2 Col3
BD1V HDD 5
BD1V Label 4
BD1V ODD 3
BD1W RAM 8
BD1W LCD 6
BD1W TP CABLE 5
BL3 LCD CABLE 7
BL3 LABEL 6
BL3 LCD 5
BL3D Label 4
*/
幸运的意外 2009-11-02
- 打赏
- 举报
顶一个,利用自增列编号,然后分组取最大2条就行吧.
