if object_id('[tb]') is not null drop table [tb]

go

create table [tb]([列名] varchar(6),[类型] varchar(7),[长度] int,[精度] int,[小数位数] int)

insert [tb]

select 'sid','int',4,0,0 union all

select 'spbh','char',20,0,0 union all

select 'lshj','decimal',9,14,2 union all

select 'ishysp','bit',2,0,0

 

--->查询

declare @sql varchar(8000)

select 

  @sql=isnull(@sql+',','')

      +列名+' '+类型

      +case 

         when 类型='int' then ''

         when 类型='char' then '('+ltrim(长度)+')'

         when 类型='decimal' then '('+ltrim(长度)+','+ltrim(小数位数)+')'

         when 类型='bit' then ''

       end

from tb



exec ('create table tbtest('+@sql+')')



insert tbtest select 1,'001',12.3,1



select * from tbtest



/**

sid         spbh                 lshj        ishysp 

----------- -------------------- ----------- ------ 

1           001                  12.30       1



（所影响的行数为 1 行）

**/

举个例子，类型还可以罗列

引用 6 楼 huangqing_80 的回复:

小F的回答对于单表是正确的，如果要创建多表呢，用游标可以实现吗

多表的就你给的数据和表结构实现不了，要加一个表名的字段

比如说我现在就碰到这样一个问题，
公司原有的系统是北京时空公司的KSOA，但当时上系统时并没有考虑周全，它并不适合公司的生产流程，现在想将KSOA更换成北京时空的另一套系统STIB，两套系统之间很多表是相同的，不同的就是有些表的结构可能会发生了变化，如果手工检查，效率很低，所以我就有了这样一个想法，比较两套系统之间表的差异，并且将有差异的表进行相关处理，比如说STIB中的SPKFK表中的SPBH字段长度是20，而KSOA是24，这就需要修改STIB数据库表SPKFK中SPBH的长度，这才有了这样一个想法

huangqing_80,我抓住你了

嗯，四方城说的没错，如果要求所有，还需要表名，那么，小F的思路就要更加深一点了
期待更佳的答案

引用 13 楼 huangqing_80 的回复:

比如说我现在就碰到这样一个问题，
公司原有的系统是北京时空公司的KSOA，但当时上系统时并没有考虑周全，它并不适合公司的生产流程，现在想将KSOA更换成北京时空的另一套系统STIB，两套系统之间很多表是相同的，不同的就是有些表的结构可能会发生了变化，如果手工检查，效率很低，所以我就有了这样一个想法，比较两套系统之间表的差异，并且将有差异的表进行相关处理，比如说STIB中的SPKFK表中的SPBH字段长度是20，而KSOA是24，这就需要修改STIB数据库表SPKFK中SPBH的长度，这才有了这样一个想法

不建议这么做，这样做完以后，还是一样要检查，不检查你也不知道哪些表要改，改成功了没有，就意味着风险

无枪狙击手、邹建、海爷、大乌龟等各位大侠，如果你们在线的话，也希望能给我一些提示和启发，也希望在线的其他高手朋友看一下这个贴子

四方城，改完后结构比较的代码我倒是可以写出来，当然在上生产线之前我一定会进行比较的

set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
go
IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[SBP_DbStruCompare]') AND type in (N'P', N'PC'))
DROP PROCEDURE [dbo].[SBP_DbStruCompare]
go

create PROCEDURE [dbo].[SBP_DbStruCompare]     -- 数据库表结构比较
    @DBNameS varchar(40),
    @DBNameD varchar(40)
  as
   
  create table #tmp_keys
  (
    keyname varchar(256),
    fdname varchar(256)
  )
  create table #tmp_keyd
  (
    keyname varchar(256),
    fdname varchar(256)
  )
   
  exec('declare @tbname varchar(256), @colname varchar(256), @indid int, @i int' +
       ' declare cursor_key INSENSITIVE CURSOR' +
       ' for select a.name as tbname, b.name as colname, c.indid ' +
       ' from ' + @DBNameS + '.dbo.sysobjects a join ' + @DBNameS + '.dbo.syscolumns b on a.id = b.id ' +
       '            join ' + @DBNameS + '.dbo.sysindexes c on a.id = c.id and (c.status & 0x800) > 0 and c.IndID > 0 and c.IndID <> 255 and left(c.name,7)<>''_WA_Sys''' +
       ' where a.type = ''u''and a.name = ''kjkmfse''' +
       ' open cursor_key' +
       ' fetch next from cursor_key into @tbname, @colname, @indid' +
       ' while (@@FETCH_STATUS <> -1)' +
       ' begin'+
       '   set @i = 1'+
       '   while @i <= 16'+
       '   begin '+
       '     if @colname = index_col(''' + @DBNameS + '.dbo.''+@tbname, @indid, @i)'+
       '     begin'+
       '       insert into #tmp_keys(keyname, fdname) values(@tbname, @colname)'+
       '       break'+
       '     end'+
       '     set @i = @i + 1'+
       '   end'+
       '   fetch next from cursor_key into @tbname, @colname, @indid'+
       ' end'+
       ' close cursor_key'+
       ' deallocate cursor_key')
   
  exec('declare @tbname varchar(256), @colname varchar(256), @indid int, @i int' +
       ' declare cursor_key INSENSITIVE CURSOR' +
       ' for select a.name as tbname, b.name as colname, c.indid ' +
       ' from ' + @DBNameD + '.dbo.sysobjects a join ' + @DBNameD + '.dbo.syscolumns b on a.id = b.id ' +
       '            join ' + @DBNameD + '.dbo.sysindexes c on a.id = c.id and (c.status & 0x800) > 0 and c.IndID > 0 and c.IndID <> 255 and left(c.name,7)<>''_WA_Sys''' +
       ' where a.type = ''u''and a.name = ''kjkmfse''' +
       ' open cursor_key' +
       ' fetch next from cursor_key into @tbname, @colname, @indid' +
       ' while (@@FETCH_STATUS <> -1)' +
       ' begin'+
       '   set @i = 1'+
       '   while @i <= 16'+
       '   begin '+
       '     if @colname = index_col(''' + @DBNameD + '.dbo.''+@tbname, @indid, @i)'+
       '     begin'+
       '       insert into #tmp_keyd(keyname, fdname) values(@tbname, @colname)'+
       '       break'+
       '     end'+
       '     set @i = @i + 1'+
       '   end'+
       '   fetch next from cursor_key into @tbname, @colname, @indid'+
       ' end'+
       ' close cursor_key'+
       ' deallocate cursor_key')
      
  exec('select a.tbname as tbnamea, a.fdname as fdnamea, a.fldtype as fldtypea, ' +
       '  a.fldsize as fldsizea, a.scale as scalea, a.defvalue as defvaluea, ' +
       '  a.isnullable as nulla, a.keyname as keynamea,' +
       '  b.tbname as tbnameb, b.fdname as fdnameb, b.fldtype as fldtypeb, ' + 
       '  b.fldsize as fldsizeb, b.scale as scaleb, b.defvalue as defvalueb,' +
       '  b.isnullable as nullb, b.keyname as keynameb' +
       '   into #tmp_comptab ' +
       ' from  ' +
       '(select c.name as tbname, a.name as fdname,b.name as fldtype, isnull(a.prec, '''') as fldsize,isnull(a.scale, '''') as scale, ' +
       '     case a.cdefault when 0 then '''' else d.Text end defvalue, isnullable, isnull(e.keyname,'''') as keyname' +
       ' from  ' + @DBNameS + '.dbo.syscolumns a join  ' + @DBNameS + '.dbo.systypes b on a.xusertype = b.xusertype ' +
       '                                      join ' + @DBNameS + '.dbo.sysobjects c on a.id = c.id and c.type = ''u''' +
       '                                      left join #tmp_keys e on c.name = e.keyname and a.name = e.fdname' +
       '                                      left join ' + @DBNameS + '.dbo.syscomments d on a.cdefault = d.id ) a' +
       ' full join ' +
       '   (select c.name as tbname, a.name as fdname,b.name as fldtype, isnull(a.prec, '''') as fldsize,isnull(a.scale, '''') as scale, ' +
       '       case a.cdefault when 0 then '''' else d.Text end defvalue, isnullable, isnull(e.keyname,'''') as keyname' +
       '  from ' + @DBNameD + '.dbo.syscolumns a join ' + @DBNameD + '.dbo.systypes b on a.xusertype = b.xusertype ' +
       '                                      join ' + @DBNameD + '.dbo.sysobjects c on a.id = c.id and c.type = ''u''' +
       '                                      left join #tmp_keyd e on c.name = e.keyname and a.name = e.fdname' +
       '                                      left join ' + @DBNameD + '.dbo.syscomments d on a.cdefault = d.id ) b  ' +
       ' on a.tbname = b.tbname and a.fdname = b.fdname and a.fldtype = b.fldtype and ' +
       '    a.scale = b.scale and a.defvalue = b.defvalue and a.isnullable = b.isnullable and a.keyname = b.keyname ' +
       ' where a.tbname is null or b.tbname is null ' +
   
       ' select isnull(a.tbnamea,a.tbnameb) as tbname, isnull(a.fdnamea,a.fdnameb) as fdname, isnull(a.fldtypea,a.fldtypeb) as fldtype,' +
       '  isnull(a.fldsizea,a.fldsizeb) as fldsize, isnull(a.scalea,a.scaleb) as scale, isnull(a.defvaluea,a.defvalueb) as defvalue, ' +
       '  case isnull(a.nulla,a.nullb) when 0 then '''' else ''√'' end as nullable,' +
       '  case when isnull(isnull(a.keynamea,a.keynameb),'''') <> '''' then ''√'' end as keyname, ' +
       ' c.name as tba, b.name as fda, d.name as tbb, e.name as fdb, ' + 
       ' case when a.tbnamea is null then ''' + @DBNameD + ''' else ''' + @DBNameS + ''' end as dbname,' +
       ' b.usertype as usertypa, e.usertype as usertypb, b.prec as preca, e.prec as precb, b.scale as scalea, e.scale as scaleb,' +
       ' f.text as cdefaulta, g.text as cdefaultb, b.isnullable as nulla, e.isnullable as nullb, h.keyname as keynamea, i.keyname as keynameb' +
       '    from #tmp_comptab a left join ' + @DBNameS + '.dbo.sysobjects c on isnull(a.tbnamea, a.tbnameb) = c.name ' +
       '                        left join ' + @DBNameS + '.dbo.syscolumns b on isnull(a.fdnamea, a.fdnameb) = b.name and b.id = c.id ' +
       '                        left join ' + @DBNameS + '.dbo.syscomments f on b.cdefault = f.id ' +
       '                        left join #tmp_keys h on isnull(a.tbnamea, a.tbnameb) = h.keyname and isnull(a.fdnamea, a.fdnameb) = h.fdname' +
       '                        left join ' + @DBNameD + '.dbo.sysobjects d on isnull(a.tbnamea, a.tbnameb) = d.name ' +
       '                        left join ' + @DBNameD + '.dbo.syscolumns e on isnull(a.fdnamea, a.fdnameb) = e.name and e.id = d.id ' +
       '                        left join ' + @DBNameD + '.dbo.syscomments g on e.cdefault = g.id ' +
       '                        left join #tmp_keyd i on isnull(a.tbnamea, a.tbnameb) = i.keyname and isnull(a.fdnamea, a.fdnameb) = i.fdname' +
       ' order by case when a.tbnamea is null then a.tbnameb else a.tbnamea end, ' +
       '         case when a.fdnamea is null then a.fdnameb else a.fdnamea end,13')