→救急！如何查看哪个用户锁了哪个表

[树猫]

如何查看哪个用户锁了哪个表。
查了很多帖子，都是oracle的，sql server不能查出是哪个用户锁了哪个表吗？

[树猫]

用sql 语句怎么查询出来，我需要在程序里查出 哪个用户锁了哪个表

[快乐_石头]

http://blog.csdn.net/wufeng4552/archive/2009/11/06/4775066.aspx

[树猫]

楼上的，那个帖子我看了。
我要查询到 "哪个表 被 哪个用户" 锁了.

实际项目的问题，恳请大家发一些有用的信息给我

[--小F--]

CREATE   PROCEDURE   dbo.usp_lock   AS   
  set   nocount   on   
  select   p.hostname,   
  l.req_spid   as   spid,   
                  l.rsc_objid,   
  left(v.name,4)   As   Type,   
  left(u.name,8)   As   Mode,   
  left(x.name,6)   As   lockStatus,   
  p.program_name,   
  p.loginame,   
  p.status   as   status,   
  p.blocked   
  into   #locks   
  from   master.dbo.syslockinfo   l   
  join   (select   name,number   from   master.dbo.spt_values   v   where   type   =   'LR')   v   on   l.rsc_type   =   v.number   
  join   (select   name,number   from   master.dbo.spt_values   v   where   type   =   'L')     u   on   l.req_mode   +   1   =   u.number   
  join   (select   name,number   from   master.dbo.spt_values   v   where   type   =   'LS')   x   on   l.req_status   =   x.number   
  join   master.dbo.sysprocesses   p   on   l.req_spid=p.spid   
  where       l.rsc_dbid=db_id()     
                  and   l.rsc_objid>0   
    
  select     l.hostname,   
  l.spid,   
                  isnull(o.name,'   ')   as   objname,   
  l.Type,   
  l.Mode,   
  l.lockStatus,   
  l.program_name,   
  l.loginame,   
  l.status,   
                  l.blocked,     
                  isnull(p.hostname,'   ')   as   blockhostname,   
                  isnull(p.program_name,'   ')   as   blockprogram   
  from     #locks   l   
            join   sysobjects   o   on   l.rsc_objid=o.id     
            left   join   master.dbo.sysprocesses   p   on   l.blocked=p.spid   
  order   by   o.name,l.hostname   
    
  drop   table   #locks   
  GO   
  

[jinsenhome]

/*
功		能：查看sqlserver的表 锁定情况（用户、进程、表）
作		者：金振水
日		期：2009-12-15
备		注：在sqlserver2000上调试通过；
			所查找的对象 到数据库的基本 objects 级别
			欢迎修改完善！

*/

declare @dbname sysname
	set @dbname = 'usercenter'
declare @objname sysname
	set @objname = 'tp_uidinfo'
declare @exec varchar(500)

--准备进程快照
create table #proc(spid int,dbid int,objid bigint,indid bigint, [type] varchar(10),resource varchar(30), mode varchar(10),status varchar(10))
insert into #proc exec sp_lock 

create table #t1(dbid int,dbname sysname ,objid bigint,obj_name sysname,obj_type varchar(20))
set @exec = 'select db_id(''' + @dbname + ''') as dbid,''' + @dbname +  '''as dbname,id,name,type from ' + @dbname + '.dbo.sysobjects where name like ''%' + @objname + '%'''
insert into #t1 execute(@exec)


--准备用户信息快照
create table #who(spid int,ecid int,status varchar(20),loginame varchar(256),hostname varchar(256), blk int,dbname varchar(50),cmd varchar(32))
insert into #who exec sp_who


--查询锁资源信息(注意引起死锁的进程spid)
select a.spid,c.loginame,c.hostname,c.blk as deaded_spid,c.cmd,c.status as user_status,a.dbid,b.dbname,a.objid,b.obj_name,b.obj_type,a.indid,a.type,a.resource,a.mode,a.status
from #proc a inner join #t1 b on a.dbid = b.dbid and a.objid = b.objid inner join #who c on a.spid=c.spid
where type in ('TAB') --可以注释掉以获取更详细的资料
order by a.spid,blk



--清理临时表
drop table #t1
drop table #proc
drop table #who

--sp_who

[gaomiqzhi]

学习

[xman_78tom]

select b.session_id,b.login_name,db_name(a.resource_database_id),
object_name(a.resource_associated_entity_id,a.resource_database_id),
a.resource_type,a.request_mode,a.request_type
from sys.dm_tran_locks a inner join sys.dm_exec_sessions b
on a.request_session_id=b.session_id
where a.resource_type in ('database','object')

[xiaofan_sap]

学习了

[nalnait]

根据 DMV

[树猫]

问题没有解决，
算了，结帖。谢谢大家。