SQL执行存储过程执行报错:必须声明标量变量“@XX”!

[BTChinaVeryCD]

下面是我的一个存储过程，编译，生成都能成功，就是在代码中执行的时候出错，后来我用exec调用，也是同样的错误。。
请大家检查下我的语法和变量赋值有没问题。

if exists(select * from sysobjects where type='P' and name='Pro_GetListPager')
drop procedure Pro_GetListPager
print 'drop procedure Pro_GetListPager'
GO
print 'creating procedure Pro_GetListPager'
GO
set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
GO
Create procedure Pro_GetListPager
	@TableName varchar(200),
	@FieldList varchar(1000)='*',
	@OrderBy varchar(300)=' CreateDatetime desc ',
	@PageSize int =1,
	@PageIndex int =1,
	@Filter varchar(2000)='1=1',
	@RecordCount int output
AS
declare @strSQL varchar(5000)
declare @Total varchar(5000)
declare @startIndex int
declare @endIndex int
declare @rowcount int

if(LEN(@OrderBy)>0)
begin
	set @OrderBy='order by '+@OrderBy
end
else
begin 
	set @OrderBy=' order by CreateDatetime desc '
end 
	
if(LEN(@Filter)>0)
begin
	set @Filter=' where '+@Filter
end
if(@PageIndex>0)
begin
	set @Total='select @rowcount=count(*) from '+@TableName+''+@Filter+''
	exec (@Total)
	set @RecordCount=@rowcount
	set @startIndex= (@PageIndex-1)*@PageSize+1
	set @endIndex=@PageIndex*@PageSize
	
	set @strSQL='select * from (select ROW_NUMBER() OVER('+@OrderBy+') as cj,
	'+@FieldList+' from '+@TableName+''+@Filter+') as tbl where cj between STR(@startIndex) and STR(@endIndex)'
end
exec (@strSql)

下面是我用来调用的方法：

declare @RowCount int

exec Pro_GetListPager
    @TableName = N'UserCardTable',
    @OrderBy=N'CreateDatetime desc ',
    @RecordCount = @RowCount OUTPUT
    
    select @RowCount as RecordCount

报错：

消息 137，级别 15，状态 1，行 1
必须声明标量变量 "@rowcount"。
消息 137，级别 15，状态 2，行 2
必须声明标量变量 "@startIndex"。

(1 行受影响)

各位大大说下原因啊。。。同时希望大家提供增值服务。。。

//这是我的一个测试，仍然报错

消息 137，级别 15，状态 1，第 1 行
必须声明标量变量 "@rowcount"。
go
Create Procedure test
@recordCount int output
as 
 declare @SqlStr varchar(2000)
 declare @rowcount int
 
 set @SqlStr='select @rowcount=count(*) from UserCardTable '//我怀疑是不是这里@rowcount的错误？？？
 exec(@SqlStr)
 set @recordCount=@rowcount
 Go
 //这是调用方法
 declare @rowcount int
 
 exec test 
	@recordCount=@rowcount output
	
	select @rowcount as xxx

[SQL77]

set @SqlStr='select '+LTRIM(@rowcount)+'=count(*) from UserCardTable '//我怀疑是不是这里@rowcount的错误？？？
exec(@SqlStr)

[SQL77]

要不然用SP_EXECUTESQL
加OUTPUT参数执行

[bancxc]

set @Total='select @rowcount=count(*) from '+@TableName+''+@Filter+''
这些啊 @rowcount要申明

[SQL77]

1);EXEC 执行SQL语句

declare @rsql varchar(250)
        declare @csql varchar(300)
        declare @rc nvarchar(500)
        declare @cstucount int
        declare @ccount int
        set @rsql='(select Classroom_id from EA_RoomTime where zc='+@zc+' and xq='+@xq+' and T'+@time+'=''否'') and ClassroomType=''1'''
        --exec(@rsql)
        set @csql='select @a=sum(teststucount),@b=sum(classcount) from EA_ClassRoom where classroom_id in '
        set @rc=@csql+@rsql
        exec sp_executesql @rc,N'@a int output,@b int output',@cstucount output,@ccount output--将exec的结果放入变量中的做法
        --select @csql+@rsql
        --select @cstucount

[bancxc]

exec (@strSql)
@strSql和在外面声明的变量不能共享的

[BTChinaVeryCD]

[Quote=引用 1 楼 sql77 的回复:]
set @SqlStr='select '+LTRIM(@rowcount)+'=count(*) from UserCardTable '//我怀疑是不是这里@rowcount的错误？？？
exec(@SqlStr)

[/Quote]
多谢，这位在哥，成功了。。

你能告诉我这个关键字是什么用吗？我还没用过呢。。
同时，你在检查下我的语法，我那种方式能把rowcount作为输出变量输出去不？

set @Total='select @rowcount=count(*) from '+@TableName+''+@Filter+''
    exec (@Total)
    set @RecordCount=@rowcount

[BTChinaVeryCD]

上面打错了。是”这位大哥。“

[--小F--]

1 :普通SQL语句可以用exec执行 

Select * from tableName 
exec('select * from tableName') 
exec sp_executesql N'select * from tableName' -- 请注意字符串前一定要加N 

2:字段名，表名，数据库名之类作为变量时，必须用动态SQL 

declare @fname varchar(20) 
set @fname = 'FiledName' 
Select @fname from tableName -- 错误,不会提示错误，但结果为固定值FiledName,并非所要。 
exec('select ' + @fname + ' from tableName') -- 请注意 加号前后的 单引号的边上加空格 

当然将字符串改成变量的形式也可 
declare @fname varchar(20) 
set @fname = 'FiledName' --设置字段名 

declare @s varchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
exec(@s) -- 成功 
exec sp_executesql @s -- 此句会报错 

declare @s Nvarchar(1000) -- 注意此处改为nvarchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
exec(@s) -- 成功 
exec sp_executesql @s -- 此句正确 

3. 输出参数 
declare @num int, @sqls nvarchar(4000) 
set @sqls='select count(*) from tableName' 
exec(@sqls) 

--如何将exec执行结果放入变量中？ 

declare @num int, @sqls nvarchar(4000) 
set @sqls='select @a=count(*) from tableName ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select @num 


1 :普通SQL语句可以用Exec执行      例:      Select * from tableName 
                Exec('select * from tableName') 
                Exec sp_executesql N'select * from tableName'    -- 请注意字符串前一定要加N 

2:字段名，表名，数据库名之类作为变量时，必须用动态SQL 

    错误:       declare @fname varchar(20) 
                set @fname = 'FiledName' 
                Select @fname from tableName              -- 错误,不会提示错误，但结果为固定值FiledName,并非所要。
    正确:      Exec('select ' + @fname + ' from tableName')     -- 请注意加号前后的单引号的边上加空格

    当然将字符串改成变量的形式也可
                declare @fname varchar(20) 
                set @fname = 'FiledName' --设置字段名

                declare @s varchar(1000) 
                set @s = 'select ' + @fname + ' from tableName' 
                Exec(@s)                -- 成功
                exec sp_executesql @s   -- 此句会报错

              --注：@s参数必须为ntext或nchar或nvarchar类型,必须将declare @s varchar(1000) 改为declare @s Nvarchar(1000) 



               如下：
                declare @s Nvarchar(1000) -- 注意此处改为nvarchar(1000) 

                set @fname = 'FiledName' --设置字段名
                set @s = 'select ' + @fname + ' from tableName' 
                Exec(@s)                -- 成功    
                exec sp_executesql @s   -- 此句正确

3. 输入或输出参数

      (1)输入参数:
          declare @QueryString nvarchar(1000) --动态查询语句变量(注：必须为ntext或nchar哐nvarchar类型，不能是varchar类型)
          declare @paramstring nvarchar(200) --设置动态语句中的参数的字符串(注：必须为ntext或nchar哐nvarchar类型，不能是varchar类型)
          declare @input_id int--定义需传入动态语句的参数的值

          set @QueryString='select * from tablename  where id=@id'  --id为字段名，@id为要传入的参数
          set @paramstring='@id int' --设置动态语句中参数的定义的字符串
          set @input_id =1  --设置需传入动态语句的参数的值为1
          exec sp_executesql @querystring,@paramstring,@id=@input_id　　
          若有多个参数:
          declare @QueryString nvarchar(1000) --动态查询语句变量(注：必须为ntext或nchar哐nvarchar类型，不能是varchar类型)
          declare @paramstring nvarchar(200) --设置动态语句中的参数的字符串(注：必须为ntext或nchar哐nvarchar类型，不能是varchar类型)
          declare @input_id int--定义需传入动态语句的参数的值,参数1
          declare @input_name varchar(20)--定义需传入动态语句的参数的值,参数2

          set @QueryString='select * from tablename  where id=@id and name=@name'   --id与name为字段名，@id与@name为要传入的参数
          set @paramstring='@id int,@name varchar(20)' --设置动态语句中参数的定义的字符串,多个参数用","隔开
          set @input_id =1  --设置需传入动态语句的参数的值为1
          set @input_name='张三'   --设置需传入动态语句的参数的值为"张三"
          exec sp_executesql @querystring,@paramstring,@id=@input_id,@name=@input_name　--请注意参数的顺序
     (2)输出参数
             declare @num int, @sqls nvarchar(4000) 
            set @sqls='select count(*) from tableName' 
            exec(@sqls) 
        --如何将exec执行结果放入变量中？          
        declare @QueryString nvarchar(1000) --动态查询语名变量(注：必须为ntext或nchar哐nvarchar类型，不能是varchar类型)
        declare @paramstring nvarchar(200) --设置动态语句中的参数的字符串(注：必须为ntext或nchar哐nvarchar类型，不能是varchar类型)
        declare @output_result int--查询结果赋给@output_result 

        set @QueryString='select @totalcount=count(*) from tablename' --@totalcount　为输出结果参数
        set @paramstring='@totalcount int output' --设置动态语句中参数的定义的字符串,多个参数用","隔开
        exec sp_executesql @querystring,@paramstring,@totalcount=@output_result output
        select @output_result
        当然，输入与输出参数可以一起使用，大家可以自己去试一试。
        另外，动态语句查询的结果集要输出的话，我只想到以下用临时表的方法，不知各位有没有更好的方法.
        IF object_id('[tempdb].[dbo].#tmp') IS NOT NULL --判断临时表#tmp是否存在,存在则删除
            drop table #tmp
        select * into #tmp from tablename where 1=2 --创建临时表#tmp,其结构与tablename相同

        declare @QueryString nvarchar(1000) --动态查询语名变量(注：必须为ntext或nchar哐nvarchar类型，不能是varchar类型)
        set @QueryString='select * from tablename '
        insert into #tmp(field1,field2,...) exec(@querystirng) 

[--小F--]

同时，你在检查下我的语法，我那种方式能把rowcount作为输出变量输出去不？

看这个

输出参数 
declare @num int, @sqls nvarchar(4000) 
set @sqls='select count(*) from tableName' 
exec(@sqls) 

--如何将exec执行结果放入变量中？ 

declare @num int, @sqls nvarchar(4000) 
set @sqls='select @a=count(*) from tableName ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select @num 

[dawugui]

[Quote=引用 6 楼 btchinaverycd 的回复:]
引用 1 楼 sql77 的回复:
set @SqlStr='select '+LTRIM(@rowcount)+'=count(*) from UserCardTable '//我怀疑是不是这里@rowcount的错误？？？
exec(@SqlStr)


多谢，这位在哥，成功了。。

你能告诉我这个关键字是什么用吗？我还没用过呢。。
同时，你在检查下我的语法，我那种方式能把rowcount作为输出变量输出去不？

SQL codeset@Total='select @rowcount=count(*) from'+@TableName+''+@Filter+''exec (@Total)set@RecordCount=@rowcount
[/Quote]

看下面最后一段.

--动态sql语句基本语法

 
1 :普通SQL语句可以用Exec执行 

eg: Select * from tableName 
Exec('select * from tableName') 
Exec sp_executesql N'select * from tableName' -- 请注意字符串前一定要加N 

2:字段名，表名，数据库名之类作为变量时，必须用动态SQL 

eg: 
declare @fname varchar(20) 
set @fname = 'FiledName' 
Select @fname from tableName -- 错误,不会提示错误，但结果为固定值FiledName,并非所要。 
Exec('select ' + @fname + ' from tableName') -- 请注意 加号前后的 单引号的边上加空格 

当然将字符串改成变量的形式也可 
declare @fname varchar(20) 
set @fname = 'FiledName' --设置字段名 

declare @s varchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
Exec(@s) -- 成功 
exec sp_executesql @s -- 此句会报错 

declare @s Nvarchar(1000) -- 注意此处改为nvarchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
Exec(@s) -- 成功 
exec sp_executesql @s -- 此句正确 

3. 输出参数 
declare @num int, 
@sqls nvarchar(4000) 
set @sqls='select count(*) from tableName' 
exec(@sqls) 
--如何将exec执行结果放入变量中？ 

declare @num int, 
@sqls nvarchar(4000) 
set @sqls='select @a=count(*) from tableName ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select @num 

[BTChinaVeryCD]

[Quote=引用 9 楼 fredrickhu 的回复:]
同时，你在检查下我的语法，我那种方式能把rowcount作为输出变量输出去不？

看这个
SQL code输出参数declare@numint,@sqlsnvarchar(4000)set@sqls='select count(*) from tableName'exec(@sqls)--如何将exec执行结果放入变量中？declare@numint,@sqlsnvarchar(4000)set@sqls='select @a=count(*) from tableName'exec sp_executesql@sqls,N'@a int output',@num outputselect@num
[/Quote]
多谢。。等会成功就结贴了。。。

[chengwen2402163]

直接把@RecordCount=Count(*),不用中间变量的吧。