求CreateProcess实例源代码！谢谢

[chunaii]

求CreateProcess实例源代码！谢谢

[嗷嗷叫的老马]

Option Explicit
'*************************************************************************
'**模 块 名：ModSuperShell
'**说    明：运行指定文件,比SHELL命令更多功能
'**创 建 人：嗷嗷叫的老马
'**日    期：2006年4月22日
'**描    述：可以返回运行对象的PID与ThradID,可等待对象返回
'**版    本：V1.0
'*************************************************************************

Private Const INFINITE = &HFFFF
Private Const STARTF_USESHOWWINDOW = &H1
Public Enum enSW
    SW_HIDE = 0
    SW_NORMAL = 1
    SW_MAXIMIZE = 3
    SW_MINIMIZE = 6
End Enum
Public Enum enPriority_Class
    NORMAL_PRIORITY_CLASS = &H20
    IDLE_PRIORITY_CLASS = &H40
    HIGH_PRIORITY_CLASS = &H80
End Enum
Private Type PROCESS_INFORMATION
    hProcess As Long
    hThread As Long
    dwProcessId As Long
    dwThreadId As Long
End Type
Private Type STARTUPINFO
    cb As Long
    lpReserved As String
    lpDesktop As String
    lpTitle As String
    dwX As Long
    dwY As Long
    dwXSize As Long
    dwYSize As Long
    dwXCountChars As Long
    dwYCountChars As Long
    dwFillAttribute As Long
    dwFlags As Long
    wShowWindow As Integer
    cbReserved2 As Integer
    lpReserved2 As Byte
    hStdInput As Long
    hStdOutput As Long
    hStdError As Long
End Type
Private Type SECURITY_ATTRIBUTES
    nLength As Long
    lpSecurityDescriptor As Long
    bInheritHandle As Long
End Type
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, lpProcessAttributes As SECURITY_ATTRIBUTES, lpThreadAttributes As SECURITY_ATTRIBUTES, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDriectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long

Public Function SuperShell(ByVal App As String, ByVal WorkDir As String, dwMilliseconds As Long, ByVal start_size As enSW, ByVal Priority_Class As enPriority_Class, Optional Pid As Variant, Optional Tid As Variant) As Boolean
    Dim pclass As Long
    Dim sinfo As STARTUPINFO
    Dim pinfo As PROCESS_INFORMATION
    Dim sec1 As SECURITY_ATTRIBUTES
    Dim sec2 As SECURITY_ATTRIBUTES
    
    sec1.nLength = Len(sec1)
    sec2.nLength = Len(sec2)
    sinfo.cb = Len(sinfo)
    
    sinfo.dwFlags = STARTF_USESHOWWINDOW
    sinfo.wShowWindow = start_size
    pclass = Priority_Class
    
    If CreateProcess(vbNullString, App, sec1, sec2, False, pclass, _
    0&, WorkDir, sinfo, pinfo) Then
        'Wait
        WaitForSingleObject pinfo.hProcess, dwMilliseconds
        SuperShell = True
    Else
        SuperShell = False
    End If
    
    If Not IsMissing(Pid) Then Pid = pinfo.dwProcessId
    If Not IsMissing(Tid) Then Tid = pinfo.dwThreadId
End Function

调用:

SuperShell "c:\windows\notepad.exe","c:\windows\",3,SW_NORMAL,NORMAL_PRIORITY_CLASS

[贝隆]

帮顶～～～～～～～～～～～～～～～～

[SYSSZ]

API_GUIDE中有一个示例.

[chinaboyzyq]

mark~

[舉杯邀明月]

Ding.........

[橘子皮...]

老马你这个类是可以等文件完全打开再执行下一句命令的吗？？？还是和ShellExecute一样，立刻就跳到下一句执行了？？？


谁给个打开完毕再执行下一句的写法呀