水晶报表大写转换的问题!泰哥....

[feng442624978]

上次我在这里发帖说了 windows 7下面 我的那个水晶报表转换中文大写的函数有问题. 经你提醒把:

Function total (ls as Currency) as string 改成 Function total (ls as Number) as string

但是现在出现了一个大问题. 如果传进去的是一个 小数位数 它就要报错:

非数字字符串。调用自定义函数'toal' 时出错。文件 C:\Users\ADMINI~1.DAD\AppData\Local\Temp\Stock_OrderDetail {1DAE7B8F-2003-475A-9888-D0ADA4A294A2}.rpt 内出错：公式 . 'Function toal (ls as Number) as string ' 非数字字符串

----- 怎么解决啊. ??? 急....在线等待!!

[雷肿么了]

转中文的，你传个数字进去，当然会报错，

　你可以先判断是不是数字，如果是则不传，反之则传。。

[feng442624978]

我传的是数字啊. 不过是带小数的数字..例如 :62.42..就报这个错.

[雷肿么了]

引用 2 楼 feng442624978 的回复:

我传的是数字啊. 不过是带小数的数字..例如 :62.42..就报这个错.

传整型的就没错？　比如：62

[波导终结者]

62.42后面还有俩点？

[feng442624978]

恩..整型没问题的. 万恶的回复内容:"回复内容太短了！ "

[feng442624978]

就是一个小数传进去有错误..整数没问题!

[雷肿么了]

Function total (ls as Number) as string

还有其他 的类型没？ 你换换试下。 替换掉Number

[feng442624978]

有 我用 Double 替换过. 还是报一样错..

[雷肿么了]

我也不知道用哪个替换，

你直接用String 不行吗？

[feng442624978]

不行..哎. 我郁闷啊. 我不懂 Basic语法..

[feng442624978]

没人知道了吗? 神啊 救救我吧..

[阿泰]

你那个函数就是Basic语法的。。
我试验了下小数的情况，是可以正常执行的，不过我不确定在Win7下会有什么效果。
我家里的电脑装了win7，晚上我回去看看。


关联帖子备用
http://topic.csdn.net/u/20100202/11/c7896700-1b7d-42e8-a203-48d50636043a.html

[雷肿么了]

学习了。。。..........

[阿泰]

win7下确实存在上述问题，经过反复调试，最终修订版如下，支持Win7及其他平台。

Function total (ls as number) as string
    dim dx_sz as string
    dim dx_dw as string 
    dim str_int as string 
    dim str_dec as string
    dim dx_str as string 
    dim fu as string
    dim a as string
    dim b as string
    dim c as string
    dim d as string
    dim b2 as string
    dim num_int as number
    dim num_dec as number
    dim len_int as number
    dim i as number
    dim a_int as number
    dim pp as number

    dx_sz="零壹贰叁肆伍陆柒捌玖"
    dx_dw="万仟佰拾亿仟佰拾万仟佰拾圆"
    
    if ls=0 then dx_str="零圆整"
    
    if ls<0 then
        ls=abs(ls)
        fu="负"
    else
        fu=""
    end if

    dx_str=CStr (ls)
    dx_str=Replace (dx_str,"￥","")
    dx_str=replace(dx_str,",","")
    if (ls>=0) and (ls<1) then dx_str="0"+dx_str
    
    pp=InStr (dx_str,".")   
    if pp>0 then 
        str_int=mid(dx_str,1,instr(dx_str,".")-1)
    else
        str_int=dx_str
    end if

    num_int=ToNumber (str_int)

    if (ls>0) and (ls<1) then 
        num_dec =  ls*100
    else
        num_dec=(ls-num_int)*100
    end if

    str_dec=totext(num_dec)
    str_dec=replace(str_dec,"￥","")

    len_int=len(str_int)
    dx_str=""
    for i=1 to len_int
        a=mid(str_int,i,1)
        a_int=tonumber(a)
        b=mid(dx_sz,(a_int+1),1)
        c=mid(dx_dw,(13-len_int+i),1)
        if dx_str<>"" then
            d=mid(dx_str,len(dx_str)-1,1)
        else
            d=""
        end if
        if(b="零") and ((d="零") or (b=b2) or (c="圆") or (c="万") or (c="亿")) then b=""
        if(a="0") and (c<>"圆") and (c<>"万") and (c<>"亿") then c=""
        if((c="圆") or (c="万") or (c="亿")) and (d="零") and (a="0") then
            dx_str=mid(dx_str,1,len(dx_str)-2)
            d=mid(dx_str,len(dx_str)-1,2)
            if((c="圆") and (d="万"))or((c="万") and (d="亿")) then c=""
        end if
        dx_str=dx_str+b+c
        b2=b
    next i

    '处理金额小于1的情况
    if len(dx_str)<=2 then dx_str=""
    if(num_dec<10)and(ls>0) then
        a_int=tonumber(str_dec)
        b=mid(dx_sz,(a_int+1),1)
        if num_dec=0 then dx_str=dx_str+"整"
        if num_dec>0 then dx_str=dx_str+"零"+b+"分"
    end if
    if num_dec>=10 then
        a_int=tonumber(mid(str_dec,1,1))
        a=mid(dx_sz,(a_int+1),1)
        a_int=tonumber(mid(str_dec,2,1))
        b=mid(dx_sz,(a_int+1),1)
        if a<>"零" then a=a+"角"
        if b<>"零" then b=b+"分" else b=""
        dx_str=dx_str+a+b
    end if 
        
    dx_str=fu+dx_str

    dx_str=replace(dx_str,"零亿","亿")
    dx_str=replace(dx_str,"零万","万")
    dx_str=replace(dx_str,"零千","千")
    dx_str=replace(dx_str,"零圆","圆")


    total =dx_str
End Function

其实改动只有一处，就是把
dim num_dec as currency
替换为
dim num_dec as number

[feng442624978]

谢了 各位了. .万恶的

[feng442624978]

结贴了 .万恶 :回复内容太短了！