22,210
社区成员
发帖
与我相关
我的任务
分享
if not object_id('T2') is null
drop table T2
Go
Create table T2([col1] int,[col2] int,[col3] int,[col4] int)
Insert T2
select 80,1,1,2 union all
select 80,1,1,5 union all
select 80,1,1,1 union all
select 80,1,1,4 union all
select 80,1,1,3 union all
select 80,1,2,4 union all
select 80,1,2,1 union all
select 80,1,2,2 union all
select 80,1,3,5 union all
select 80,1,3,1 union all
select 80,1,3,3 union all
select 80,1,3,2
Go
--创建一个合并的函数
create function f_hb(@col1 int,@col2 int,@col3 int)
returns varchar(8000)
as
begin
declare @str varchar(8000)
set @str = ''
select @str = @str + ',' + cast(col4 as varchar) from t2 where col1 = @col1 and col2 = @col2 and col3 = @col3 order by col4
set @str = right(@str , len(@str) - 1)
return(@str)
End
go
--查询
select distinct col1,col2,col3,dbo.f_hb(col1,col2,col3) as col4 from t2
--结果
/*
col1 col2 col3 col4
----------------------------------
80 1 1 1,2,3,4,5
80 1 2 1,2,4
80 1 3 1,2,3,5
*/
Select
[col1],[col2],[col3], [col4]=stuff((select ','+rtrim([col4]) from tb where [col1]=a.[col1] and [col2]=a.[col2] and [col3]=a.[col3] order by [col4] for xml path('')),1,1,'')
from
tb a
group by
[col1],[col2],[col3]
use Tempdb
go
--> -->
if not object_id(N'Tempdb..#T2') is null
drop table #T2
Go
Create table #T2([col1] int,[col2] int,[col3] int,[col4] int)
Insert #T2
select 80,1,1,2 union all
select 80,1,1,5 union all
select 80,1,1,1 union all
select 80,1,1,4 union all
select 80,1,1,3 union all
select 80,1,2,4 union all
select 80,1,2,1 union all
select 80,1,2,2 union all
select 80,1,3,5 union all
select 80,1,3,1 union all
select 80,1,3,3 union all
select 80,1,3,2
Go
Select [col1],[col2],[col3], [col4]=stuff((select ','+rtrim([col4]) from #T2 where [col1]=a.[col1] and [col2]=a.[col2] and [col3]=a.[col3] order by [col4] for xml path('')),1,1,'')
from #T2 a
group by [col1],[col2],[col3]
合并列值
原著:邹建
改编:爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开) 2007-12-16 广东深圳
表结构,数据如下:
id value
----- ------
1 aa
1 bb
2 aaa
2 bbb
2 ccc
需要得到结果:
id values
------ -----------
1 aa,bb
2 aaa,bbb,ccc
即:group by id, 求 value 的和(字符串相加)
1. 旧的解决方法(在sql server 2000中只能用函数解决。)
--1. 创建处理函数
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
CREATE FUNCTION dbo.f_str(@id int)
RETURNS varchar(8000)
AS
BEGIN
DECLARE @r varchar(8000)
SET @r = ''
SELECT @r = @r + ',' + value FROM tb WHERE id=@id
RETURN STUFF(@r, 1, 1, '')
END
GO
-- 调用函数
SELECt id, value = dbo.f_str(id) FROM tb GROUP BY id
drop table tb
drop function dbo.f_str
/*
id value
----------- -----------
1 aa,bb
2 aaa,bbb,ccc
(所影响的行数为 2 行)
*/
--2、另外一种函数.
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
--创建一个合并的函数
create function f_hb(@id int)
returns varchar(8000)
as
begin
declare @str varchar(8000)
set @str = ''
select @str = @str + ',' + cast(value as varchar) from tb where id = @id
set @str = right(@str , len(@str) - 1)
return(@str)
End
go
--调用自定义函数得到结果:
select distinct id ,dbo.f_hb(id) as value from tb
drop table tb
drop function dbo.f_hb
/*
id value
----------- -----------
1 aa,bb
2 aaa,bbb,ccc
(所影响的行数为 2 行)
*/
2. 新的解决方法(在sql server 2005中用OUTER APPLY等解决。)
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
-- 查询处理
SELECT * FROM(SELECT DISTINCT id FROM tb)A OUTER APPLY(
SELECT [values]= STUFF(REPLACE(REPLACE(
(
SELECT value FROM tb N
WHERE id = A.id
FOR XML AUTO
), ' <N value="', ','), '"/>', ''), 1, 1, '')
)N
drop table tb
/*
id values
----------- -----------
1 aa,bb
2 aaa,bbb,ccc
(2 行受影响)
*/
--SQL2005中的方法2
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
select id, [values]=stuff((select ','+[value] from tb t where id=tb.id for xml path('')), 1, 1, '')
from tb
group by id
/*
id values
----------- --------------------
1 aa,bb
2 aaa,bbb,ccc
(2 row(s) affected)
*/
drop table tb