3.3w+
社区成员
一个SQL查询问题！急！！
比如说：我见了两个表，一个是图书信息表tb_bookInfo;一个是图书类型表tb_bookType
结构如下：
tb_bookType表
id typeName parentID
1 英语 0
2 生物 0
3 计算机 0
4 口语 1
5 听力 1
6 数据库 3
7 软件工程 3
8 SQL Server 6
#也就是说一个树形结构的类型表，0节点是顶节点
tb_bookInfo表
number name type ...
1 n1 6
2 n2 3
...
#图书表的type是类型表中的ID，可能是中间节点，也可能是叶子节点
我现在想查询类型表中选定ID下的所有图书？大家教教我啊！！
查询的ID可能他下面包含多层子节点，这个我不知道该怎么处理。。。
要是只有两级还好说。。。
谢谢了！
结构如下：
tb_bookType表
id typeName parentID
1 英语 0
2 生物 0
3 计算机 0
4 口语 1
5 听力 1
6 数据库 3
7 软件工程 3
8 SQL Server 6
#也就是说一个树形结构的类型表，0节点是顶节点
tb_bookInfo表
number name type ...
1 n1 6
2 n2 3
...
#图书表的type是类型表中的ID，可能是中间节点，也可能是叶子节点
我现在想查询类型表中选定ID下的所有图书？大家教教我啊！！
查询的ID可能他下面包含多层子节点，这个我不知道该怎么处理。。。
要是只有两级还好说。。。
谢谢了！
...全文
当前发帖距今超过3年，不再开放新的回复
发表回复
dawugui 2010-06-13
你可以通过上面的方法先查出一个表的情况,然后做为子查询和另外一个表连接得到你需要的东西.
dawugui 2010-06-13
/*
标题：SQL SERVER 2000中查询指定节点及其所有子节点的函数(表格形式显示)
作者：爱新觉罗·毓华(十八年风雨,守得冰山雪莲花开)
时间：2008-05-12
地点：广东深圳
*/
create table tb(id varchar(3) , pid varchar(3) , name varchar(10))
insert into tb values('001' , null , '广东省')
insert into tb values('002' , '001' , '广州市')
insert into tb values('003' , '001' , '深圳市')
insert into tb values('004' , '002' , '天河区')
insert into tb values('005' , '003' , '罗湖区')
insert into tb values('006' , '003' , '福田区')
insert into tb values('007' , '003' , '宝安区')
insert into tb values('008' , '007' , '西乡镇')
insert into tb values('009' , '007' , '龙华镇')
insert into tb values('010' , '007' , '松岗镇')
go
--查询指定节点及其所有子节点的函数
create function f_cid(@ID varchar(3)) returns @t_level table(id varchar(3) , level int)
as
begin
declare @level int
set @level = 1
insert into @t_level select @id , @level
while @@ROWCOUNT > 0
begin
set @level = @level + 1
insert into @t_level select a.id , @level
from tb a , @t_Level b
where a.pid = b.id and b.level = @level - 1
end
return
end
go
--调用函数查询001(广东省)及其所有子节点
select a.* from tb a , f_cid('001') b where a.id = b.id order by a.id
/*
id pid name
---- ---- ----------
001 NULL 广东省
002 001 广州市
003 001 深圳市
004 002 天河区
005 003 罗湖区
006 003 福田区
007 003 宝安区
008 007 西乡镇
009 007 龙华镇
010 007 松岗镇
（所影响的行数为 10 行）
*/
--调用函数查询002(广州市)及其所有子节点
select a.* from tb a , f_cid('002') b where a.id = b.id order by a.id
/*
id pid name
---- ---- ----------
002 001 广州市
004 002 天河区
（所影响的行数为 2 行）
*/
--调用函数查询003(深圳市)及其所有子节点
select a.* from tb a , f_cid('003') b where a.id = b.id order by a.id
/*
id pid name
---- ---- ----------
003 001 深圳市
005 003 罗湖区
006 003 福田区
007 003 宝安区
008 007 西乡镇
009 007 龙华镇
010 007 松岗镇
（所影响的行数为 7 行）
*/
drop table tb
drop function f_cid
@@ROWCOUNT：返回受上一语句影响的行数。
返回类型：integer。
注释：任何不返回行的语句将这一变量设置为 0 ，如 IF 语句。
示例：下面的示例执行 UPDATE 语句并用 @@ROWCOUNT 来检测是否有发生更改的行。
UPDATE authors SET au_lname = 'Jones' WHERE au_id = '999-888-7777'
IF @@ROWCOUNT = 0
print 'Warning: No rows were updated'
结果：
(所影响的行数为 0 行)
Warning: No rows were updated
/*
标题：SQL SERVER 2005中查询指定节点及其所有子节点的方法(表格形式显示)
作者：爱新觉罗·毓华(十八年风雨,守得冰山雪莲花开)
时间：2010-02-02
地点：新疆乌鲁木齐
*/
create table tb(id varchar(3) , pid varchar(3) , name nvarchar(10))
insert into tb values('001' , null , N'广东省')
insert into tb values('002' , '001' , N'广州市')
insert into tb values('003' , '001' , N'深圳市')
insert into tb values('004' , '002' , N'天河区')
insert into tb values('005' , '003' , N'罗湖区')
insert into tb values('006' , '003' , N'福田区')
insert into tb values('007' , '003' , N'宝安区')
insert into tb values('008' , '007' , N'西乡镇')
insert into tb values('009' , '007' , N'龙华镇')
insert into tb values('010' , '007' , N'松岗镇')
go
DECLARE @ID VARCHAR(3)
--查询ID = '001'的所有子节点
SET @ID = '001'
;WITH T AS
(
SELECT ID , PID , NAME
FROM TB
WHERE ID = @ID
UNION ALL
SELECT A.ID , A.PID , A.NAME
FROM TB AS A JOIN T AS B ON A.PID = B.ID
)
SELECT * FROM T ORDER BY ID
/*
ID PID NAME
---- ---- ----------
001 NULL 广东省
002 001 广州市
003 001 深圳市
004 002 天河区
005 003 罗湖区
006 003 福田区
007 003 宝安区
008 007 西乡镇
009 007 龙华镇
010 007 松岗镇
(10 行受影响)
*/
--查询ID = '002'的所有子节点
SET @ID = '002'
;WITH T AS
(
SELECT ID , PID , NAME
FROM TB
WHERE ID = @ID
UNION ALL
SELECT A.ID , A.PID , A.NAME
FROM TB AS A JOIN T AS B ON A.PID = B.ID
)
SELECT * FROM T ORDER BY ID
/*
ID PID NAME
---- ---- ----------
002 001 广州市
004 002 天河区
(2 行受影响)
*/
--查询ID = '003'的所有子节点
SET @ID = '003'
;WITH T AS
(
SELECT ID , PID , NAME
FROM TB
WHERE ID = @ID
UNION ALL
SELECT A.ID , A.PID , A.NAME
FROM TB AS A JOIN T AS B ON A.PID = B.ID
)
SELECT * FROM T ORDER BY ID
/*
ID PID NAME
---- ---- ----------
003 001 深圳市
005 003 罗湖区
006 003 福田区
007 003 宝安区
008 007 西乡镇
009 007 龙华镇
010 007 松岗镇
(7 行受影响)
*/
drop table tb
--注：除ID值不一样外，三个SQL语句是一样的。
永生天地 2010-06-13
if object_id('tb_bookInfo') is not null drop table tb_bookInfo
go
create table tb_bookInfo(number int,name varchar(10),type int)
insert tb_bookInfo
select 1 ,'n1', 6 union all
select 2 ,'n2', 3
if object_id('tb_bookType') is not null drop table tb_bookType
go
create table tb_bookType(id int,typeName varchar(10),parentid int)
insert tb_bookType
select 1,'英语',0 union all
select 2,'生物',0 union all
select 3,'计算机',0 union all
select 4,'口语',1 union all
select 5,'听力',1 union all
select 6,'数据库',3 union all
select 7,'软件工程',3 union all
select 8,'SQL Server',6
--查所有父结点
if object_id('f_getP') is not null drop function f_getP
go
create function f_getP(@id int)
returns @re table(id int,level int)
as
begin
declare @l int
set @l=0
insert @re select @id,@l
while @@rowcount>0
begin
set @l=@l+1
insert @re select a.parentid,@l from tb_bookType a,@re b
where a.id=b.id and b.level=@l-1 and a.parentid<>0
end
update @re set level=@l-level
return
end
go
select a.*,b.level from tb_bookInfo a,f_getC(3) b where a.type=b.id order by b.level
/*
number name type level
----------- ---------- ----------- -----------
2 n2 3 0
1 n1 6 1
（所影响的行数为 2 行）
*/
---------下面赠送两个其他的查找，估计能有用----------
--查所有子结点
if object_id('f_getC') is not null drop function f_getC
go
create function f_getC(@id int)
returns @re table(id int,level int)
as
begin
declare @l int
set @l=0
insert @re select @id,@l
while @@rowcount>0
begin
set @l=@l+1
insert @re select a.id,@l from tb_bookType as a,@re as b
where b.id=a.parentid and b.level=@l-1
end
return
end
go
--查所有父子结点
if object_id('f_getAll') is not null drop function f_getAll
go
create function f_getAll(@id int)
returns @re table(id int,level int)
as
begin
declare @l int
set @l=0
insert @re select @id,@l
while @@rowcount>0
begin
set @l=@l+1
insert @re select a.parentid,@l from tb_bookType a,@re b
where a.id=b.id and b.level=@l-1 and a.parentid<>0
end
update @re set level=@l-level
while @@rowcount>0
begin
set @l=@l+1
insert @re select a.id,@l from tb_bookType as a,@re as b
where b.id=a.parentid and b.level=@l-1
end
return
end
go
hbjlwhl 2010-06-13
在帮楼主顶一下。。
振乾 2010-06-13
帮顶
树形显示。
树形显示。
--小F-- 2010-06-13
----------------------------------------------------------------
-- Author :fredrickhu(小F，向高手学习)
-- Date :2010-06-13 14:50:53
-- Version:
-- Microsoft SQL Server 2005 - 9.00.4035.00 (Intel X86)
-- Nov 24 2008 13:01:59
-- Copyright (c) 1988-2005 Microsoft Corporation
-- Developer Edition on Windows NT 5.1 (Build 2600: Service Pack 3)
--
----------------------------------------------------------------
--> 测试数据：[tb_bookType]
if object_id('[tb_bookType]') is not null drop table [tb_bookType]
go
create table [tb_bookType]([id] int,[typeName] varchar(9),[parentID] int)
insert [tb_bookType]
select 1,'英语',0 union all
select 2,'生物',0 union all
select 3,'计算机',0 union all
select 4,'口语',1 union all
select 5,'听力',1 union all
select 6,'数据库',3 union all
select 7,'软件工程',3 union all
select 8,'SQLServer',6
--> 测试数据：[tb_bookInfo]
if object_id('[tb_bookInfo]') is not null drop table [tb_bookInfo]
go
create table [tb_bookInfo]([number] int,[name] varchar(2),[type] int)
insert [tb_bookInfo]
select 1,'n1',6 union all
select 2,'n2',3
--------------开始查询--------------------------
;with f as
(
select * from tb_bookType where parentID=3
union all
select a.* from tb_bookType a, f b where a.parentID=b.id
)
select * from f,tb_bookInfo b where f.parentID=b.type
----------------结果----------------------------
/* id typeName parentID number name type
----------- --------- ----------- ----------- ---- -----------
6 数据库 3 2 n2 3
7 软件工程 3 2 n2 3
8 SQLServer 6 1 n1 6
(3 行受影响)
*/zhuazhuqingchong 2010-06-13
mark，数据库也可以这样用，
SQL查询问题！急。。 主表A ： id name cardid 1 joni 111 2 tank 222 ...查询身份证号 cardid超过两次loginTime记录的姓名name和loginTime次数 如： name loginNum tank 2 fiona 3
急急急！！！SQL 年龄段查询 语句更换 上面的 SQL语句怎么更换成下面这种的？（用union alll） select … ,“29岁以下” as category, 29岁以下 as value from XXX union all select … ,“30-39岁” as category, 30-39岁 as value from XXX
SQL SERVER数据库恢复后乱码问题！！！ 从windows server 2012 R2 英文操作系统上备份的sql server 2008R2数据库，（字符集：Latin1_General_100_CI...号乱码，求大侠们帮助一下，很急很急！！！ 欢迎使用Markdown编辑器 你好！ 这是你第一次使用 Markdown...
.net 代码解决SQL查询超时问题 相关背景： 一个报表统计型的存储过程，随着数据量增加，查询时间越来越长，因为存储过程超过2K行，要优化可能需要更多的时间，因为急需要报表数据，只好先从 代码层处理超时问题。 以下是解决方案。 /// <...
sql关于对一个字段同时满足多条件判断来筛选查询 以下为本菜鸟项目中遇到的问题： 背景： /** * wangjie 180629 * * 学生需要查询四种可能的消息 * 1.班级管理员发来的，根据自身的学籍号条件查询 * 2.省级管理员发送区县全部的，根据接收对象地区号...
急急急！SQL语句 年龄段人数汇总查询 怎么更改语句类型！！！ 上面的 SQL语句怎么更换成下面这种的？（用union alll） select … ,“29岁以下” as category, 29岁以下 as value from XXX union all select … ,“30-39岁” as category, 30-39岁 as value from XXX ————...
SQLServer将查询内容拼接成字符串输出（超全面！） 一、问题回顾 当我想通过 select 语句将查询内容拼接成字符串输出时出现这种情况。 select U_ID+U_NAME from MES_USER 消息 245，级别 16，状态 1，第 1 行 在将 varchar 值 '小白' 转换成数据类型 int 时失败...
实时计算！急招！！ 朋友公司招人，找工作的可以看过来，实时计算，大数据开发/专家，各种岗位都有！急招！考虑的可以直接微信和我说，我可以直接帮忙推到对应岗位负责人那去，省去麻烦流程！有我微信的可以直接私聊我，没...
一条查询sql的执行流程和底层原理 额~~不是我不说啊，因为细说起来，我可以细分为DML(Update、Insert、Delete),DDL(表结构修改),DCL(权限操作),DQL(Select)操作,一个个去介绍，我怕大家嫌我烦！ 嗯，大家没什么意见，我继续往下自我介绍了~ 由于种....
SQL语句求助！急 newClass newClassID（PK） newClassName praventID 1 资讯 ... 如何查询newClass表praventID为-1下的所有小类的详细信息，并把所有信息都放在1张表中，急！
ibatis多条件查询问题，急！急！急！！ 本人刚刚自学了Ibatis，我现在需要查询一个两个时间之间的数据，使用的是Map传参数，但一直查不出数据，也不报错，请高手指点下，不使用map传参数也行，只要有解决的方法。谢谢。 数据库中中表t_work有一个时间的...
求BOM展开的SQL!HELP!!急! 新年好!BOM展开方面的问题请教高手:在manuf_structure表中,其主要字段是PARENT_PART与COMPONENT_PART 当我用下记SQL:select parent_part,component_part ...
牛逼！Java 从入门到精通，超全汇总版 文章目录Java 基础Head First JavaJava 核心技术卷一...Java 虚拟机Java 虚拟机规范HotSpot 实战自己动手写 Java 虚拟机MySQLMySQL 基础教程SQL 基础教程深入浅出 MySQLMySQL 必知必会SQL 必知必会高性能 MySQLMySQL
mycat小白一系列问题求解，很急！！谢谢大佬！ Mycat小白问题总结，欢迎大神指点迷津，有些问题... 现在自己接手的是一个数据存储量大概5gb的mysql集群。 想尝试在mycat上执行数据扩容，遇到了一系列问题，在网上搜索了2天的相关问题信息，还是不能解决。希望能...
