为什么我的分页存储过程不能传条件查询

jiejie526 2010-06-20 05:00:36 


EXEC PAGEVIEW exchange,ID,2,20,NULL,NULL,TRADING='出售',NULL



IF EXISTS((SELECT NAME FROM SYSOBJECTS WHERE NAME='PageView'AND TYPE='P'))

	DROP PROCEDURE PageView

GO

create PROC [dbo].[PageView] 

@tbname    sysname,          --要分页显示的表名 

@FieldKey  sysname,          --用于定位记录的主键(惟一键)字段,只能是单个字段 

@PageCurrent int=1,            --要显示的页码 

@PageSize  int=10,            --每页的大小(记录数) 

@FieldShow  nvarchar(1000)='',  --以逗号分隔的要显示的字段列表,如果不指定,则显示所有字段 

@FieldOrder  nvarchar(1000)='', --以逗号分隔的排序字段列表,可以指定在字段后面指定DESC/ASC 

                                          --用于指定排序顺序 

@Where    nvarchar(1000)='',  --查询条件 

@PageCount  int OUTPUT        --总页数 

AS 

DECLARE @sql nvarchar(4000) 

SET NOCOUNT ON 

--检查对象是否有效 

IF OBJECT_ID(@tbname) IS NULL 

BEGIN 

RAISERROR(N'对象"%s"不存在',1,16,@tbname) 

RETURN 

END 

IF OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTable')=0 

AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsView')=0 

AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTableFunction')=0 

BEGIN 

RAISERROR(N'"%s"不是表、视图或者表值函数',1,16,@tbname) 

RETURN 

END 



--分页字段检查 

IF ISNULL(@FieldKey,N'')='' 

BEGIN 

RAISERROR(N'分页处理需要主键（或者惟一键）',1,16) 

RETURN 

END 



--其他参数检查及规范 

IF ISNULL(@PageCurrent,0) <1 SET @PageCurrent=1 

IF ISNULL(@PageSize,0) <1 SET @PageSize=10 

IF ISNULL(@FieldShow,N'')=N'' SET @FieldShow=N'*' 

IF ISNULL(@FieldOrder,N'')=N'' 

SET @FieldOrder=N'' 

ELSE 

SET @FieldOrder=N'ORDER BY '+LTRIM(@FieldOrder) 

IF ISNULL(@Where,N'')=N'' 

SET @Where=N'' 

ELSE 

SET @Where=N'WHERE ('+@Where+N')' 



--如果@PageCount为NULL值,则计算总页数(这样设计可以只在第一次计算总页数,以后调用时,把总页数传回给存储过程,避免再次计算总页数,对于不想计算总页数的处理而言,可以给@PageCount赋值) 

IF @PageCount IS NULL 

BEGIN 

SET @sql=N'SELECT @PageCount=COUNT(*)' 

+N' FROM '+@tbname 

+N' '+@Where 

EXEC sp_executesql @sql,N'@PageCount int OUTPUT',@PageCount OUTPUT 

SET @PageCount=(@PageCount+@PageSize-1)/@PageSize 

END 



--计算分页显示的TOPN值 

DECLARE @TopN varchar(20),@TopN1 varchar(20) 

SELECT @TopN=@PageSize, 

@TopN1=@PageCurrent*@PageSize 



--第一页直接显示 

IF @PageCurrent=1 

EXEC(N'SELECT TOP '+@TopN 

+N' '+@FieldShow 

+N' FROM '+@tbname 

+N' '+@Where 

+N' '+@FieldOrder) 

ELSE 

BEGIN 

SELECT @PageCurrent=@TopN1, 

@sql=N'SELECT @n=@n-1,@s=CASE WHEN @n <'+@TopN 

+N' THEN @s+N'',''+QUOTENAME(RTRIM(CAST('+@FieldKey 

+N' as varchar(8000))),N'''''''') ELSE N'''' END FROM '+@tbname 

+N' '+@Where 

+N' '+@FieldOrder 

SET ROWCOUNT @PageCurrent 

EXEC sp_executesql @sql, 

N'@n int,@s nvarchar(4000) OUTPUT', 

@PageCurrent,@sql OUTPUT 

SET ROWCOUNT 0 

IF @sql=N'' 

EXEC(N'SELECT TOP 0' 

+N' '+@FieldShow 

+N' FROM '+@tbname) 

ELSE 

BEGIN 

SET @sql=STUFF(@sql,1,1,N'') 

--执行查询 

EXEC(N'SELECT TOP '+@TopN 

+N' '+@FieldShow 

+N' FROM '+@tbname 

+N' WHERE '+@FieldKey 

+N' IN('+@sql 

+N') '+@FieldOrder) 

END 

END
...全文
63 8 打赏 收藏 转发到动态 举报
写回复
用AI写文章
8 条回复
切换为时间正序
请发表友善的回复…
发表回复
jiejie526 2010-06-23
  • 打赏
  • 举报
 回复
传入的where 符合语法规则就行 TRADING like '%出售%'
htl258_Tony 2010-06-21
  • 打赏
  • 举报
 回复 
--（原代码作者：邹建）

create Proc p_show

@QueryStr nvarchar(4000), --表名、视图名、查询语句，如要加条件，直接在此加入(如：select * from tb where ....)

@PageSize int=10,   --每页的大小(行数)

@pagecount int out, --显示总页数

@PageCurrent int=1,   --要显示的页

@FdShow nvarchar (4000)='',--要显示的字段列表,如果查询结果有标识字段,需要指定此值,且不包含标识字段

@FdOrder nvarchar (1000)='' --排序字段列表

as

declare @FdName nvarchar(250) --表中的主键或表、临时表中的标识列名

 ,@Id1 varchar(20),@Id2 varchar(20) --开始和结束的记录号

 ,@Obj_ID int    --对象ID

 ,@sql nvarchar(4000)

--表中有复合主键的处理

declare @strfd nvarchar(2000) --复合主键列表

 ,@strjoin nvarchar(4000) --连接字段

 ,@strwhere nvarchar(2000) --查询条件





select @Obj_ID=object_id(@QueryStr)

 ,@FdShow=case isnull(@FdShow,'') when '' then ' *' else ' '+@FdShow end

 ,@FdOrder=case isnull(@FdOrder,'') when '' then '' else ' order by '+@FdOrder end

 ,@QueryStr=case when @Obj_ID is not null then ' '+@QueryStr else ' ('+@QueryStr+') a' end

 

--显示总页数

 

set @sql='select @pagecount=ceiling(count(*)*1./@PageSize) from '+@QueryStr

exec sp_executesql @sql,N'@pagecount int out,@PageSize int',@pagecount out,@PageSize



--如果显示第一页，可以直接用top来完成

if @PageCurrent=1 

begin

 select @Id1=cast(@PageSize as varchar(20))

 exec('select top '+@Id1+@FdShow+' from '+@QueryStr+@FdOrder)

 return

end



--如果是表,则检查表中是否有标识更或主键

if @Obj_ID is not null and objectproperty(@Obj_ID,'IsTable')=1

begin

 select @Id1=cast(@PageSize as varchar(20))

  ,@Id2=cast((@PageCurrent-1)*@PageSize as varchar(20))



 select @FdName=name from syscolumns where id=@Obj_ID and status=0x80

 if @@rowcount=0   --如果表中无标识列,则检查表中是否有主键

 begin

  if not exists(select 1 from sysobjects where parent_obj=@Obj_ID and xtype='PK')

   goto lbusetemp  --如果表中无主键,则用临时表处理



  select @FdName=name from syscolumns where id=@Obj_ID and colid in(

   select colid from sysindexkeys where @Obj_ID=id and indid in(

    select indid from sysindexes where @Obj_ID=id and name in(

     select name from sysobjects where xtype='PK' and parent_obj=@Obj_ID

   )))

  if @@rowcount>1  --检查表中的主键是否为复合主键

  begin

   select @strfd='',@strjoin='',@strwhere=''

   select @strfd=@strfd+',['+name+']'

    ,@strjoin=@strjoin+' and a.['+name+']=b.['+name+']'

    ,@strwhere=@strwhere+' and b.['+name+'] is null'

    from syscolumns where id=@Obj_ID and colid in(

    select colid from sysindexkeys where @Obj_ID=id and indid in(

     select indid from sysindexes where @Obj_ID=id and name in(

      select name from sysobjects where xtype='PK' and parent_obj=@Obj_ID

    )))

   select @strfd=substring(@strfd,2,2000)

    ,@strjoin=substring(@strjoin,5,4000)

    ,@strwhere=substring(@strwhere,5,4000)

   goto lbusepk

  end

 end

end

else

 goto lbusetemp



/*--使用标识列或主键为单一字段的处理方法--*/

lbuseidentity: 

 exec('select top '+@Id1+@FdShow+' from '+@QueryStr

  +' where '+@FdName+' not in(select top '

  +@Id2+' '+@FdName+' from '+@QueryStr+@FdOrder

  +')'+@FdOrder

  )

 return



/*--表中有复合主键的处理方法--*/

lbusepk:  

 exec('select '+@FdShow+' from(select top '+@Id1+' a.* from

  (select top 100 percent * from '+@QueryStr+@FdOrder+') a

  left join (select top '+@Id2+' '+@strfd+' 

  from '+@QueryStr+@FdOrder+') b on '+@strjoin+'

  where '+@strwhere+') a'

  )

 return



/*--用临时表处理的方法--*/

lbusetemp:  

select @FdName='[ID_'+cast(newid() as varchar(40))+']'

 ,@Id1=cast(@PageSize*(@PageCurrent-1) as varchar(20))

 ,@Id2=cast(@PageSize*@PageCurrent-1 as varchar(20))



exec('select '+@FdName+'=identity(int,0,1),'+@FdShow+'

  into #tb from'+@QueryStr+@FdOrder+'

 select '+@FdShow+' from #tb where '+@FdName+' between '

 +@Id1+' and '+@Id2

 )

GO

--调用示例：

declare @pagecount int

exec p_show 

	@QueryStr='select name from sysobjects',

	@PageSize=20,

	@pagecount=@pagecount out,

	@PageCurrent=2

select @pagecount AS 页数
另参考一下这个
htl258_Tony 2010-06-21
  • 打赏
  • 举报
 回复
把动态SQL一个一个PRINT出来看看,逐个排错.
永生天地 2010-06-21
  • 打赏
  • 举报
 回复
你用的是邹建的原版代码吗？
应该不是代码的问题
永生天地 2010-06-21
  • 打赏
  • 举报
 回复
[Quote=引用 3 楼 jiejie526 的回复:]
引用 1 楼 xys_777 的回复:
看了一遍，这样看不出问题，需要跟踪


sql语句可以跟踪吗？？
[/Quote]
print @sql 看看语句是否正确
jiejie526 2010-06-21
  • 打赏
  • 举报
 回复
[Quote=引用 1 楼 xys_777 的回复:]
看了一遍，这样看不出问题，需要跟踪
[/Quote]

sql语句可以跟踪吗？？
SQL77 2010-06-20
  • 打赏
  • 举报
 回复
检测拼接WHERE条件的语句
永生天地 2010-06-20
  • 打赏
  • 举报
 回复
看了一遍，这样看不出问题，需要跟踪
oracle查询分页条件通用存储过程
oracle数据库的查询分页加条件和排序的通用型存储过程，通过将表名以参数的形式传入到存储过程中做到多表通用，也可以是多表关联的sql语句 将其看作一个表也能调用该存储过程，分页只需要传与页数，和每页显示的行数...
Mysql分页存储过程
针对mysql分页的一个存储过程，可以动态传入表名，可带查询条件，可带排序列
JavaWeb分页技术实现
技术参数：Java+Servlet/Jsp实现分页数据库：MySQL课程中包含内存分页、数据库分页、按添加查询分页、以及分页封装及源代码，通过该课程，可以掌握分页的实现过程，建议由兴趣的同学可以学习一下！ 
通用分页存储过程——节省你的生命，N个存储过程变一个！！该存储过程几乎可以涵盖所有查询存储过程（目前本人还没有发现不能使用的）
该存储过程几乎可以涵盖所有查询存储...输入参数即可查询，无论是查询一条记录还是查询多条记录，无论是分页还是不分页，无论是需要查询条件还是不需要查询条件……，都可使用此通用的存储过程！！！ 通用性相当好！！
ASP+SQL Server带条件查询的分页存储过程及其ASP调用实例
ASP+SQL Server带条件查询的分页存储过程及其ASP调用实例
疑难问题

22,209

社区成员

121,730

社区内容

发帖
与我相关
我的任务
社区描述
MS-SQL Server 疑难问题
社区管理员
  • 疑难问题社区
  • 尘觉
加入社区
  • 近7日
  • 近30日
  • 至今

加载中

查看更多榜单
社区公告
暂无公告

试试用AI创作助手写篇文章吧

+ 用AI写文章