如何准确获取windows系统版本。

[wo22ni]

要像和点我的电脑右键属性里显示的一样准确呀。。谢谢。

[cnuser1]

VB6请参考系统自带的FrmAbout窗体，若是VB.Net，请参考My。

[xuggzu]

另，可直接使用api获取：

Option Explicit

Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (lpVersionInformation As OSVERSIONINFO) As Long

Private Type OSVERSIONINFO
dwOSVersionInfoSize As Long
dwMajorVersion As Long
dwMinorVersion As Long
dwBuildNumber As Long
dwPlatformId As Long
szCSDVersion As String * 128 ' Maintenance string for PSS usage
osName As String ' 我自己加的, 操作系统的名称
End Type

' 获得 Windows 操作系统的版本
' OSVERSIONINFO 结构中的 osName 返回操作系统的名称
Private Function GetWindowsVersion() As OSVERSIONINFO
Dim ver As OSVERSIONINFO
ver.dwOSVersionInfoSize = 148
GetVersionEx ver
With ver
Select Case .dwPlatformId
Case 1
Select Case .dwMinorVersion
Case 0
.osName = "Windows 95"
Case 10
.osName = "Windows 98"
Case 90
.osName = "Windows Mellinnium"
End Select
Case 2
Select Case .dwMajorVersion
Case 3
.osName = "Windows NT 3.51"
Case 4
.osName = "Windows NT 4.0"
Case 5
Select Case .dwMinorVersion
Case 0
.osName = "Windows 2000"
Case 1
.osName = "Windows XP"
Case 2
.osName = "Windows Server 2003"
End Select
End Select
Case Else
.osName = "Failed"
End Select
End With
GetWindowsVersion = ver
End Function

Private Sub Command1_Click()
Dim ver As OSVERSIONINFO
ver = GetWindowsVersion()
With ver
Debug.Print .osName, .dwMajorVersion, .dwMinorVersion, .dwBuildNumber, .dwPlatformId, .szCSDVersion
End With
End Sub

[bcrun]

楼上的够详细的

[wo22ni]

没列出win7,vista,还有怎么分别是专业版，还是家庭版呀。。谢谢。。。

[yangke1994]

    Set oWMINameSpace = GetObject("winmgmts:")
    Set SystemSet = oWMINameSpace.InstancesOf("Win32_OperatingSystem")
    For Each System In SystemSet
                A = A & "操作系统:   " & System.Caption & "Service Pack " & System.ServicePackMajorVersion & "." & System.ServicePackMinorVersion
    Next

[wo22ni]

[Quote=引用 5 楼 yangke1994 的回复:]
VB code
Set oWMINameSpace = GetObject("winmgmts:")
Set SystemSet = oWMINameSpace.InstancesOf("Win32_OperatingSystem")
For Each System In SystemSet
A = A & "操作系统: ……
[/Quote]

oWMINameSpace要定义成什么类型呀。。

[嗷嗷叫的老马]

object类型.

后期绑定吧.