22,209
社区成员
发帖
与我相关
我的任务
分享
use test
go
if object_id('test.dbo.表1') is not null drop table 表1
-- 创建数据表
create table 表1
(
No int,
字段2 char(8),
字段3 char(8)
)
go
--插入测试数据
insert into 表1 select 1,'xxx11','xxx21'
union all select 1,'xxx12','xxx22'
union all select 2,'xxx21','xxx21'
go
if object_id('test.dbo.表2') is not null drop table 表2
-- 创建数据表
create table 表2
(
No int,
字段2 char(8),
字段3 char(8)
)
go
--插入测试数据
insert into 表2 select 1,'zzz11','zzz21'
union all select 1,'bbb11','bbb21'
go
if object_id('test.dbo.表3') is not null drop table 表3
-- 创建数据表
create table 表3
(
No int,
字段2 char(8),
字段3 char(8)
)
go
--插入测试数据
insert into 表3 select 1,'sss11','aaa11'
union all select 1,'sss12','ss112'
union all select 1,'ddd11','dad11'
union all select 2,'sss11','www11'
union all select 2,'dddd1','ffff1'
go
--代码实现
select a.No,a.字段2,a.字段3,b.No,b.字段2,b.字段3,c.No,c.字段2,c.字段3
from (select idd=row_number()over(partition by No order by getdate()),* from 表1)a
full join (select idd=row_number()over(partition by No order by getdate()),* from 表2)b on a.idd=b.idd and a.No=b.No
full join (select idd=row_number()over(partition by No order by getdate()),* from 表3)c on a.idd=c.idd and a.No=c.No
order by c.No
/*测试结果
No 字段2 字段3 No 字段2 字段3 No 字段2 字段3
-------------------------------------------------------------------------------------
1 xxx11 xxx21 1 zzz11 zzz21 1 sss11 aaa11
1 xxx12 xxx22 1 bbb11 bbb21 1 sss12 ss112
NULL NULL NULL NULL NULL NULL 1 ddd11 dad11
NULL NULL NULL NULL NULL NULL 2 dddd1 ffff1
2 xxx21 xxx21 NULL NULL NULL 2 sss11 www11
(5 行受影响)
*/
--sql 2000,如果所有行的no+字段2+字段3能区分大小
select m1.* , m2.* , m3.* from
(select t.* , px = (select count(1) from t1 where No = t.No and (字段2 < t.字段2 or (字段2 = t.字段2 and 字段3 < t.字段3))) + 1 from t1 t) m1
full join
(select t.* , px = (select count(1) from t2 where No = t.No and (字段2 < t.字段2 or (字段2 = t.字段2 and 字段3 < t.字段3))) + 1 from t2 t) m2
on m1.no = m2.no and m1.px = m2.px full join
(select t.* , px = (select count(1) from t3 where No = t.No and (字段2 < t.字段2 or (字段2 = t.字段2 and 字段3 < t.字段3))) + 1 from t3 t) m3
on isnull(m1.no , m2.no) = m3.no and isnull(m1.px , m2.px) = m3.px
--sql 2005,使用row_number
select m1.* , m2.* , m3.* from
(select t.* , px = row_number() over(partition by no order by 字段2,字段3) from t1 t) m1
full join
(select t.* , px = row_number() over(partition by no order by 字段2,字段3) from t2 t) m2
on m1.no = m2.no and m1.px = m2.px full join
(select t.* , px = row_number() over(partition by no order by 字段2,字段3) from t3 t) m3
on isnull(m1.no , m2.no) = m3.no and isnull(m1.px , m2.px) = m3.px
/*
标题:按某字段合并字符串之一(简单合并)
作者:爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)
时间:2008-11-06
地点:广东深圳
描述:将如下形式的数据按id字段合并value字段。
id value
----- ------
1 aa
1 bb
2 aaa
2 bbb
2 ccc
需要得到结果:
id value
------ -----------
1 aa,bb
2 aaa,bbb,ccc
即:group by id, 求 value 的和(字符串相加)
*/
--1、sql2000中只能用自定义的函数解决
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
create function dbo.f_str(@id varchar(10)) returns varchar(1000)
as
begin
declare @str varchar(1000)
select @str = isnull(@str + ',' , '') + cast(value as varchar) from tb where id = @id
return @str
end
go
--调用函数
select id , value = dbo.f_str(id) from tb group by id
drop function dbo.f_str
drop table tb
--2、sql2005中的方法
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
select id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')
from tb
group by id
drop table tb
--3、使用游标合并数据
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
declare @t table(id int,value varchar(100))--定义结果集表变量
--定义游标并进行合并处理
declare my_cursor cursor local for
select id , value from tb
declare @id_old int , @id int , @value varchar(10) , @s varchar(100)
open my_cursor
fetch my_cursor into @id , @value
select @id_old = @id , @s=''
while @@FETCH_STATUS = 0
begin
if @id = @id_old
select @s = @s + ',' + cast(@value as varchar)
else
begin
insert @t values(@id_old , stuff(@s,1,1,''))
select @s = ',' + cast(@value as varchar) , @id_old = @id
end
fetch my_cursor into @id , @value
END
insert @t values(@id_old , stuff(@s,1,1,''))
close my_cursor
deallocate my_cursor
select * from @t
drop table tb