msgbox对话框，如何实现如果用户不去点击关闭，用代码实现关闭这个对话框？

[zwth001]

msgbox对话框，如何实现如果用户不去点击关闭，用代码实现关闭这个对话框？
--------------------------------------------------
我想给出提示，然后过二分钟后，程序重新启动（进行程序更新），
但是如果用户没在电脑旁边，就无法看到这个msgbox 对话框并关闭它，我想用代码关闭这个对话框，并退出程序，从而保证用户再次使用时，必须重启程序（重启程序时会执行更新程序），这样就能保证用户一定会用到修正后的版本了。

可是如何实现模拟用户点击操作，关闭msgbox对话框呢？

[VBToy]

自己用窗体做一个msgbox对话框，模式打开。用定时器在2分钟后unload这个窗体

[chinaboyzyq]

sendkeys 在定时器内发送回车

[东方之珠]

'5秒后自动关闭msgbox 5000即5秒设置 
Private Declare Function MessageBoxTimeout Lib "user32" Alias "MessageBoxTimeoutA" (ByVal hwnd As Long, ByVal lpText As String, ByVal lpCaption As String, ByVal wType As Long, ByVal wlange As Long, ByVal dwTimeout As Long) As Long

Private Sub Form_Load()
        MessageBoxTimeout Me.hwnd, "Hello World", "Tips", vbInformation, 0, 5000
        Unload Me
End Sub

[booksoon]

1#,2#,3#三种方法~~~~

[cbm6666]

3F 最完美的解答


'添加 Timer1 Command1

'3 秒后此 MsgBox 会自动关闭
Option Explicit
Private Declare Function MessageBox Lib "user32" Alias "MessageBoxA" (ByVal hwnd As Long, ByVal lpText As String, ByVal lpCaption As String, ByVal wType As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Const WM_CLOSE = &H10
Const MsgTitle As String = "SendMessage API 测试"
Private Sub Form_Load()
Timer1.Interval = 3000: Timer1.Enabled = False
End Sub

Private Sub Command1_Click()
Dim nRet&
Timer1.Enabled = True
Call MessageBox(Me.hwnd, "若您不回应的话，3 秒后此 MsgBox 会自动关闭", MsgTitle, vbOKOnly)
End Sub

Private Sub Timer1_Timer()
Dim Phwnd&
Timer1.Enabled = False
Phwnd = FindWindow(vbNullString, MsgTitle)
Call SendMessage(Phwnd, WM_CLOSE, 0, ByVal 0&)
End Sub

[帝企鹅已被占用]

[Quote=引用 5 楼 cbm666 的回复:]
3F 最完美的解答


'添加 Timer1 Command1

'3 秒后此 MsgBox 会自动关闭
Option Explicit
Private Declare Function MessageBox Lib "user32" Alias "MessageBoxA" (ByVal hwnd As Long, ByVal lpText As String, ByVal lpCa……
[/Quote]
姜是老的辣。

[赵4老师]

[Quote=引用 3 楼 chenjl1031 的回复:]
VB code
'5秒后自动关闭msgbox 5000即5秒设置
Private Declare Function MessageBoxTimeout Lib "user32" Alias "MessageBoxTimeoutA" (ByVal hwnd As Long, ByVal lpText As String, ByVal lpCaption As String, ByVal wTy……
[/Quote]
Win2000好象不支持

[ningweidong]

把自己的窗口做成对话框，想怎么控制都可以

[ttsffgg]

[Quote=引用 3 楼 chenjl1031 的回复:]

VB code
'5秒后自动关闭msgbox 5000即5秒设置
Private Declare Function MessageBoxTimeout Lib "user32" Alias "MessageBoxTimeoutA" (ByVal hwnd As Long, ByVal lpText As String, ByVal lpCaption As String, ByVal wTy……
[/Quote]

学习了!

[神马被哪个妞占用了呢]

留个记号，以后要用的时候来看。。。