SQL查询语句，把十六进制数据转换成十进制数据,在线等！

[shiquanlong]

如何写一SQL查询语句，把十六进制数据转换成十进制数据,在线等！

[guguda2008]

十六进制数据是什么格式的

[dawugui]

--十进制转为十六进制

DECLARE 
@binary varbinary(255), 
@str_return varchar(255) 

SELECT 
@binary = CONVERT(varbinary(255),29327795562177529) 


EXEC master.dbo.xp_varbintohexstr @binary, @str_return OUTPUT 
SELECT 
结果 = reverse(@str_return)

/*
结果
__________________________
008613974878369F10000011x0
*/

--十六进制转为十进制
CREATE FUNCTION dbo.f_hex_dec(@s varchar(16))
RETURNS bigint
AS
BEGIN
--作者：pbsql
--参数不得含'0'～'9'、'a'～'f'、'A'～'F'之外的任意字符（首尾空格除外），否则返回0
  DECLARE @i int,@result bigint
  SELECT @i=0,@result=0,@s=RTRIM(LTRIM(UPPER(REVERSE(@s))))
  WHILE @i<LEN(@s)
  BEGIN
    IF SUBSTRING(@s,@i+1,1) not between '0' and '9' and SUBSTRING(@s,@i+1,1) not between 'A' and 'F'
    BEGIN
      SELECT @result=0
      break
    END
    SELECT @result=@result+(CHARINDEX(SUBSTRING(@s,@i+1,1),'0123456789ABCDEF')-1)*POWER(16,@i),@i=@i+1
  END
  RETURN @result
END
GO

[fpzgm]

CREATE FUNCTION dbo.f_hex_dec(@s varchar(16))
RETURNS bigint
AS
BEGIN
  DECLARE @i int,@result bigint
  SELECT @i=0,@result=0,@s=RTRIM(LTRIM(UPPER(REVERSE(@s))))
  WHILE @i<LEN(@s)
  BEGIN
    IF SUBSTRING(@s,@i+1,1) not between '0' and '9' and SUBSTRING(@s,@i+1,1) not between 'A' and 'F'
    BEGIN
      SELECT @result=0
      break
    END
    SELECT @result=@result+(CHARINDEX(SUBSTRING(@s,@i+1,1),'0123456789ABCDEF')-1)*cast(POWER(16,@i) as bigint),@i=@i+1
  END
  RETURN @result
END
GO


select dbo.f_hex_dec('B24147FE')

go

drop function f_hex_dec
/*


                     
-------------------- 
2990622718

（所影响的行数为 1 行）



*/

[shiquanlong]

试试，谢谢