急！100分！VB6.0上机作业：计算器编码（只需加减乘除的就行）（基础编程）

2010-11-29 05:06:46 1.9k 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

ArcGIS字段计算实战：从基础到高级应用全解析字段计算是GIS数据处理中的核心技术，通过自动化运算实现属性数据的批量处理与分析。其核心原理是利用脚本语言（如Python）或内置函数对属性表中的字段进行数学运算、逻辑判断和文本处理。在国土调查、城市规划等空间分析场景中，高效的字段计算能显著提升数据处理效率，如自动计算地块面积、合并地址信息或分析人口密度分布。本文以ArcGIS字段计算器为例，深入解析数值型、文本型及日期字段的处理技巧，并分享几何计算、条件逻辑等进阶方法，帮助用户规避常见错误并优化计算性能。针对行业高频需求，特别介绍国土调查中的图斑平差计算阅读详情

界面和widows自带计算器类似，比那个简单，只要能计算“加减乘除”即可，
包含：（请指明并给出各控件的详细编程代码）
1、最上面一个文本框（怎么样将text属性设为靠右的"0."）；
2、第二行包含三个命令按钮“Backspace”“CE”“C”；
3、下面3-6行只需包含显示数字的命令按钮16个（见下图）外加一个等号“=”共计17个命令按钮。
邮箱：niranlandie@hotmail.com
高手帮忙！采用必会加送！

...全文

手把手教你解决Keil5安装时xerces-c_3_0.dll缺失和0xc000007b报错（附文件下载与路径设置）本文详细解析了Keil5安装过程中常见的xerces-c_3_0.dll缺失和0xc000007b报错问题，提供了从文件获取、路径设置到系统配置的完整解决方案。同时，文章还涵盖了STM32开发环境的搭建技巧和最佳实践，帮助开发者快速构建稳定的嵌入式开发环境。阅读详情

Sgrnrld

VB基础类 7,788 成员 197,583 内容

+ 关注 + 加入社区

切换为时间正序

Sgrnrld 2011-12-12

打赏
举报

好吧，就是不喜欢编程，或许作为女生算是个借口，考研必定要转的！！
当然还是要多谢各位前辈的忠言！

游子 2011-01-07

打赏
举报

LZ...你是不是要告诉我们。。这个是选修啊？？前天有人找我做。。我没有理。。。

chuting1 2011-01-07

打赏
举报

明明给了40分,怎么100分了?且这么简单的,最好不要上来了,那还上学干么

kewei320 2010-12-01

打赏
举报

现在的学生啊作业帮做了，还不结贴

神马被哪个妞占用了呢 2010-11-30

打赏
举报

作业啊……平常都泡妞去了？

apple_001 2010-11-30

打赏
举报

强烈抵制这样做作业的行为

chinaboyzyq 2010-11-30

打赏
举报

[Quote=引用 7 楼 choovy123 的回复:]

现在VB的高手都把人做家庭作业了
唉
你能网上COPY代码怎么会有提高呢??
[/Quote]
理解并学会MSDN上的一些例子，要比自己在那瞎琢磨好多了，至于楼主是拷贝了就交作业还是拷贝了去学习，那要看楼主将来是想搞编程，还是玩玩而已。

choovy123 2010-11-30

打赏
举报

现在VB的高手都把人做家庭作业了
唉
你能网上COPY代码怎么会有提高呢??

chinaboyzyq 2010-11-30

打赏
举报

MSDN里的例子：



' ------------------------------------------------------------------------

'               版权所有 (C) 1994 Microsoft Corporation

'

' 您可以免费以任何方式使用、修改、复制并分发您认为有用的

' 示例应用程序文件 (或任何修改过的版本)。Microsoft 对任何

' 示例应用程序文件不做任何保证，不负任何责任和义务。

' ------------------------------------------------------------------------

Option Explicit

Dim Op1, Op2                ' 预先输入操作数。

Dim DecimalFlag As Integer  ' 小数点存在吗？

Dim NumOps As Integer       ' 操作数个数。

Dim LastInput               ' 指示上一次按键事件的类型。

Dim OpFlag                  ' 指示未完成的操作。

Dim TempReadout



' C (取消) 按钮的 Click 事件过程

' 重新设置显示并初始化变量。

Private Sub Cancel_Click()

    Readout = Format(0, "0.")

    Op1 = 0

    Op2 = 0

    Form_Load

End Sub



' CE (取消输入) 按钮的 Click 事件过程。

Private Sub CancelEntry_Click()

    Readout = Format(0, "0.")

    DecimalFlag = False

    LastInput = "CE"

End Sub



' 小数点 (.) 按钮的 Click 事件过程

' 如果上一次按键为运算符，初始化 readout 为 "0."；

' 否则显示时追加一个小数点。

Private Sub Decimal_Click()

    If LastInput = "NEG" Then

        Readout = Format(0, "-0.")

    ElseIf LastInput <> "NUMS" Then

        Readout = Format(0, "0.")

    End If

    DecimalFlag = True

    LastInput = "NUMS"

End Sub



' 窗体的初始化过程

' 设置所有变量为其初始值。

Private Sub Form_Load()

    DecimalFlag = False

    NumOps = 0

    LastInput = "NONE"

    OpFlag = " "

    Readout = Format(0, "0.")

    'Decimal.Caption = Format(0, ".")

End Sub



' 数字键 (0-9) 的 Click 事件过程

' 向显示中的数追加新数。

Private Sub Number_Click(Index As Integer)

    If LastInput <> "NUMS" Then

        Readout = Format(0, ".")

        DecimalFlag = False

    End If

    If DecimalFlag Then

        Readout = Readout + Number(Index).Caption

    Else

        Readout = Left(Readout, InStr(Readout, Format(0, ".")) - 1) + Number(Index).Caption + Format(0, ".")

    End If

    If LastInput = "NEG" Then Readout = "-" & Readout

    LastInput = "NUMS"

End Sub



' 运算符 (+, -, x, /, =) 的 Click 事件过程

' 如果接下来的按键是数字键，增加 NumOps。

' 如果有一个操作数，则设置 Op1。

' 如果有两个操作数，则将 Op1 设置为 Op1 与

' 当前输入字符串的运算结果，并显示结果。

Private Sub Operator_Click(Index As Integer)

    TempReadout = Readout

    If LastInput = "NUMS" Then

        NumOps = NumOps + 1

    End If

    Select Case NumOps

        Case 0

        If Operator(Index).Caption = "-" And LastInput <> "NEG" Then

            Readout = "-" & Readout

            LastInput = "NEG"

        End If

        Case 1

        Op1 = Readout

        If Operator(Index).Caption = "-" And LastInput <> "NUMS" And OpFlag <> "=" Then

            Readout = "-"

            LastInput = "NEG"

        End If

        Case 2

        Op2 = TempReadout

        Select Case OpFlag

            Case "+"

                Op1 = CDbl(Op1) + CDbl(Op2)

            Case "-"

                Op1 = CDbl(Op1) - CDbl(Op2)

            Case "X"

                Op1 = CDbl(Op1) * CDbl(Op2)

            Case "/"

                If Op2 = 0 Then

                   MsgBox "除数不能为零", 48, "计算器"

                Else

                   Op1 = CDbl(Op1) / CDbl(Op2)

                End If

            Case "="

                Op1 = CDbl(Op2)

            Case "%"

                Op1 = CDbl(Op1) * CDbl(Op2)

            End Select

        Readout = Op1

        NumOps = 1

    End Select

    If LastInput <> "NEG" Then

        LastInput = "OPS"

        OpFlag = Operator(Index).Caption

    End If

End Sub



' 百分比键 (%) 的 Click 事件过程

' 计算并显示第一个操作数的百分数。

Private Sub Percent_Click()

    Readout = Readout / 100

    LastInput = "Ops"

    OpFlag = "%"

    NumOps = NumOps + 1

    DecimalFlag = True

End Sub