求sql语句

meijianyu 2010-12-04 10:14:32
表的结构
字段名: A B C
数据: 1001 1 75
1001 0 45
1001 1 55
1001 0 65
1002 1 75
1002 1 55
1002 0 45
1002 0 35
1003 1 25
1003 1 65
1003 1 85
1003 0 12
1003 0 22
1004 1 23
1004 0 65

想要的结果是:
1001 1 75,55
1001 0 45,65
1002 1 75,55
1002 0 45,35
. .. ..
. .. ..

其中B的取值只有0或1,对A列的值,按照B的取值的不同,将C列的值分类
...全文
102 9 打赏 收藏 转发到动态 举报
写回复
用AI写文章
9 条回复
切换为时间正序
请发表友善的回复…
发表回复
永生天地 2010-12-04
  • 打赏
  • 举报
回复
wing7742 2010-12-04
  • 打赏
  • 举报
回复
列合并 标记备用
chen8410 2010-12-04
  • 打赏
  • 举报
回复
select a.A,a.B,stuff((select ','+cast(b.C as varchar(10)) from tb as b where a.A = b.A and a.B = b.B for xml path('')),1,1,'') as res
from tb as a
group by a.A,a.B
order by A,B desc
dawugui 2010-12-04
  • 打赏
  • 举报
回复
--sql 2000
create table tb
(
A int,
B int,
C int
)

insert into tb
select 1001, 1, 75
union all
select 1001, 0, 45
union all
select 1001, 1, 55
union all
select 1001, 0, 65
union all
select 1002, 1, 75
union all
select 1002, 1, 55
union all
select 1002, 0, 45
union all
select 1002, 0, 35
union all
select 1003, 1, 25
union all
select 1003, 1, 65
union all
select 1003, 1, 85
union all
select 1003, 0, 12
union all
select 1003, 0, 22
union all
select 1004, 1, 23
union all
select 1004, 0, 65

go
create function dbo.f_str(@a int , @b int) returns varchar(1000)
as
begin
declare @str varchar(1000)
select @str = isnull(@str + ',' , '') + cast(c as varchar) from tb where a = @a and b = @b
return @str
end
go

--调用函数
select a , b , c = dbo.f_str(a , b) from tb group by a , b

drop function dbo.f_str
drop table tb

/*
a b c
----------- ----------- ----------
1001 0 45,65
1001 1 75,55
1002 0 45,35
1002 1 75,55
1003 0 12,22
1003 1 25,65,85
1004 0 65
1004 1 23

(所影响的行数为 8 行)
*/


--sql 2005
create table tb
(
A int,
B int,
C int
)

insert into tb
select 1001, 1, 75
union all
select 1001, 0, 45
union all
select 1001, 1, 55
union all
select 1001, 0, 65
union all
select 1002, 1, 75
union all
select 1002, 1, 55
union all
select 1002, 0, 45
union all
select 1002, 0, 35
union all
select 1003, 1, 25
union all
select 1003, 1, 65
union all
select 1003, 1, 85
union all
select 1003, 0, 12
union all
select 1003, 0, 22
union all
select 1004, 1, 23
union all
select 1004, 0, 65

go

select a , b, c = stuff((select ',' + cast(c as varchar) from tb t where a = tb.a and b = tb.b for xml path('')) , 1 , 1 , '')
from tb
group by a , b

drop table tb

/*
a b c
----------- ----------- ----------
1001 0 45,65
1001 1 75,55
1002 0 45,35
1002 1 75,55
1003 0 12,22
1003 1 25,65,85
1004 0 65
1004 1 23

(8 行受影响)
*/
dawugui 2010-12-04
  • 打赏
  • 举报
回复
/*
标题:按某字段合并字符串之一(简单合并)
作者:爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)
时间:2008-11-06
地点:广东深圳

描述:将如下形式的数据按id字段合并value字段。
id value
----- ------
1 aa
1 bb
2 aaa
2 bbb
2 ccc
需要得到结果:
id value
------ -----------
1 aa,bb
2 aaa,bbb,ccc
即:group by id, 求 value 的和(字符串相加)
*/
--1、sql2000中只能用自定义的函数解决
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go

create function dbo.f_str(@id varchar(10)) returns varchar(1000)
as
begin
declare @str varchar(1000)
select @str = isnull(@str + ',' , '') + cast(value as varchar) from tb where id = @id
return @str
end
go

--调用函数
select id , value = dbo.f_str(id) from tb group by id

drop function dbo.f_str
drop table tb


--2、sql2005中的方法
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go

select id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')
from tb
group by id

drop table tb


--3、使用游标合并数据
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
declare @t table(id int,value varchar(100))--定义结果集表变量
--定义游标并进行合并处理
declare my_cursor cursor local for
select id , value from tb
declare @id_old int , @id int , @value varchar(10) , @s varchar(100)
open my_cursor
fetch my_cursor into @id , @value
select @id_old = @id , @s=''
while @@FETCH_STATUS = 0
begin
if @id = @id_old
select @s = @s + ',' + cast(@value as varchar)
else
begin
insert @t values(@id_old , stuff(@s,1,1,''))
select @s = ',' + cast(@value as varchar) , @id_old = @id
end
fetch my_cursor into @id , @value
END
insert @t values(@id_old , stuff(@s,1,1,''))
close my_cursor
deallocate my_cursor

select * from @t
drop table tb
hao1hao2hao3 2010-12-04
  • 打赏
  • 举报
回复



if object_id('tb') >0
drop table tb
create table tb
(
A int,
B int,
C int
)

insert into tb
select 1001, 1, 75
union all
select 1001, 0, 45
union all
select 1001, 1, 55
union all
select 1001, 0, 65
union all
select 1002, 1, 75
union all
select 1002, 1, 55
union all
select 1002, 0, 45
union all
select 1002, 0, 35
union all
select 1003, 1, 25
union all
select 1003, 1, 65
union all
select 1003, 1, 85
union all
select 1003, 0, 12
union all
select 1003, 0, 22
union all
select 1004, 1, 23
union all
select 1004, 0, 65

select a.A,a.B,stuff((select ','+cast(b.C as varchar(10)) from tb as b where a.A = b.A and a.B = b.B for xml path('')),1,1,'') as res
from tb as a
group by a.A,a.B


--结果
1001 0 45,65
1001 1 75,55
1002 0 45,35
1002 1 75,55
1003 0 12,22
1003 1 25,65,85
1004 0 65
1004 1 23

meijianyu 2010-12-04
  • 打赏
  • 举报
回复
数据库里的数据很多,上千万条。所以得考虑服务器的负荷和sql执行所要的时间。
ACMAIN_CHM 2010-12-04
  • 打赏
  • 举报
回复
楼主用的什么数据库?!

问题说明越详细,回答也会越准确!参见如何提问。(提问的智慧


(不要高估你的汉语表达能力或者我的汉语理解能力)
建议你列出你的表结构,并提供测试数据以及基于这些测试数据的所对应正确结果。
参考一下这个贴子的提问方式http://topic.csdn.net/u/20091130/20/8343ee6a-417c-4c2d-9415-fa46604a00cf.html

1. 你的 create table xxx .. 语句
2. 你的 insert into xxx ... 语句
3. 结果是什么样,(并给以简单的算法描述)
4. 你用的数据库名称和版本(经常有人在MS SQL server版问 MySQL)

这样想帮你的人可以直接搭建和你相同的环境,并在给出方案前进行测试,避免文字描述理解上的误差。

34,575

社区成员

发帖
与我相关
我的任务
社区描述
MS-SQL Server相关内容讨论专区
社区管理员
  • 基础类社区
  • 二月十六
  • 卖水果的net
加入社区
  • 近7日
  • 近30日
  • 至今
社区公告
暂无公告

试试用AI创作助手写篇文章吧