22,207
社区成员
发帖
与我相关
我的任务
分享订单表汇总.
订单表
ID COMPANY SALEPRICE CREATER CREATTIME
1 A 100 101 2010-12-01
2 A 200 101 2010-12-01
3 B 300 301 2010-12-01
4 C 100 101 2010-12-02
5 D 200 201 2010-12-03
要求统计结果:
日期 101 201 301
总金额 不同客户数 总金额 不同客户数 总金额 不同客户数
2010-12-01 300 1 0 0 300 1
2010-12-02 100 1 0 0 0 0
2010-12-03 0 0 200 1 0 0
ID COMPANY SALEPRICE CREATER CREATTIME
1 A 100 101 2010-12-01
2 A 200 101 2010-12-01
3 B 300 301 2010-12-01
4 C 100 101 2010-12-02
5 D 200 201 2010-12-03
要求统计结果:
日期 101 201 301
总金额 不同客户数 总金额 不同客户数 总金额 不同客户数
2010-12-01 300 1 0 0 300 1
2010-12-02 100 1 0 0 0 0
2010-12-03 0 0 200 1 0 0
...全文
请发表友善的回复…
发表回复
dawugui 2010-12-29
- 打赏
- 举报
[Quote=引用 11 楼 czyoooo 的回复:]
我测试了一下,CREATER太多,所以declare @s varchar(8000)
太短了,无法执行全部.
[/Quote]
我测试了一下,CREATER太多,所以declare @s varchar(8000)
太短了,无法执行全部.
[/Quote]
/*--化解字符串不能超过8000的方法一
经常有人提到,用动态生成SQL语句的方法处理数据时,处理语句超长,无法处理的问题
下面就讨论这个问题:
--邹建 2003.9(引用请保留此信息)--*/
/*-- 测试环境
--以系统表 syscolumns 为测试数据,要求按xtype为列字段,name为行字段,统计colid的和
--要求结果
xtype filedname_1 fieldname_2 ..... fieldname_n
-------- -------------- -------------- -------- --------------
34 0 0 ..... 1
--*/
/*--常规处理方法(不加行数限制会因生成的字符串益出而出错)
set rowcount 10 --因为syscolumns的记录较,会导致生成的字符串溢出,所以限制一下行数
declare @s nvarchar(4000)
set @s=''
select @s=@s+N','+quotename([name])
+N'=sum(case name when '+quotename([name],'''')
+N' then [colid] else 0 end)'
from(select distinct [name] from [syscolumns]) a
set rowcount 0 --取消限制
exec(N'select [xtype]'+@s+N' from [syscolumns] group by [xtype]')
/*--问题
不加行数限制时,会因生成的字符串益出而出错
--*/
--*/
/*--方法1. 多个变量处理
--根据查询结果定义变量(实际处理中,应该是估计需要多少个变量,定义足够多的变量个数,多定义变量并不影响处理,下面就多定义了一个)
--生成数据处理临时表
SELECT id=IDENTITY(int,0,1),
g=0,
a=CAST(N','+QUOTENAME([name])
+N'=SUM(CASE [name] WHEN N'+QUOTENAME(name,N'''')
+N' THEN [colid] ELSE 0 END)'
as nvarchar(4000))
INTO # FROM syscolumns
WHERE name>N''
GROUP BY name
--分组临时表
UPDATE a SET G=id/i
FROM # a,(SELECT i=3800/MAX(LEN(a)) FROM #)b
SELECT MAX(g)+1 as N'需要的变量个数' FROM #
DECLARE @0 nvarchar(4000),@1 nvarchar(4000),@2 nvarchar(4000),@3 nvarchar(4000),@4 nvarchar(4000)
SELECT @0=N'',@1=N'',@2=N'',@3=N'',@4=N''
SELECT
@0=CASE g WHEN 0 THEN @0+a ELSE @0 END,
@1=CASE g WHEN 1 THEN @1+a ELSE @1 END,
@2=CASE g WHEN 2 THEN @2+a ELSE @2 END,
@3=CASE g WHEN 3 THEN @3+a ELSE @3 END,
@4=CASE g WHEN 4 THEN @4+a ELSE @4 END
FROM #
EXEC(N'SELECT xtype'+@0+@1+@2+@3+@4+N' FROM syscolumns GROUP BY xtype')
DROP TABLE #
/*--方法说明
优点:比较灵活,数据量大时只需要增加变量就行了.不用改动其他部分
缺点:要自行估计处理的数据,估计不足就会出错
--*/
--*/
/*--方法2. bcp+isql
--因为要用到bcp+isql,所以需要这些信息
declare @servername sysname,@username sysname,@pwd sysname
select @servername=@@servername --服务器名
,@username=N'' --用户名
,@pwd=N'' --密码
declare @tbname sysname,@s nvarchar(4000)
--创建数据处理临时表
set @tbname=quotename(N'##temp_'+cast(newid() as varchar(36)))
set @s=N'create table '+@tbname+'(a nvarchar(4000))
insert into '+@tbname+N'
select N''create view '
+stuff(@tbname,2,2,N'')
+N' as
select [xtype]''
union all
select N'',''+quotename([name])+''=sum(case [name] when N''
+quotename([name],'''''''')
+'' then [colid] else 0 end)''
from(select distinct [name] from [syscolumns] where name<>N''xtype'')a
union all
select N''from [syscolumns] group by [xtype]'''
exec(@s)
--生成创建视图的文件,注意使用了文件:c:\temp.txt
set @s=N'bcp "'+@tbname+N'" out "c:\'+@tbname+N'" /S"'
+@servername+N'" /U"'+@username+N'" /P"'+@pwd+N'" /w'
exec master..xp_cmdshell @s,no_output
--调用isql生成数据处理视图
set @s=N'osql /S"'+@servername
+case
when @username=N'' then N'" /E'
else N'" /U"'+@username+N'" /P"'+@pwd+N'"'
end
+N' /d"'+db_name()+N'" /i"c:\'+@tbname+'"'
exec master..xp_cmdshell @s,no_output
--删除临时文件
set @s=N'del "c:\'+@tbname+'"'
exec master..xp_cmdshell @s,no_output
--调用视图,显示处理结果
set @s=N'drop table '+@tbname+N'
select * from '+stuff(@tbname,2,2,N'')+N'
drop view '+stuff(@tbname,2,2,N'')
exec(@s)
/*--方法总结
优点:程序自动处理,不存在判断错误的问题
缺点:复杂,经过的步骤多,容易出错,而且需要一定的操作员权限
--*/
--*/
--/*-- 方法3. 多个变量处理,综合了方法1,2的优点,解决了方法1中需要人为判断,增加变量的问题,排除了方法2,需要权限和过程复杂的问题
DECLARE @sqlhead nvarchar(4000),@sqlend nvarchar(4000)
,@sql1 nvarchar(4000),@sql2 nvarchar(4000),@sql3 nvarchar(4000),@sql4 nvarchar(4000)
,@i int,@ic nvarchar(10)
--生成数据处理临时表
SELECT id=IDENTITY(int,0,1),
g=0,
a=CAST(N','
+QUOTENAME([name])
+N'=SUM(CASE [name] WHEN N'
+QUOTENAME(name,N'''')
+N' THEN [colid] ELSE 0 END)'
as nvarchar(4000))
INTO # FROM(
SELECT DISTINCT name FROM [syscolumns] WHERE name>N'')a
--分组临时表
UPDATE a SET @i=id/i,g=@i
FROM # a,(SELECT i=3800/MAX(LEN(a)) FROM #)b
SET @ic=@i
--生成数据处理语句
SELECT
@sqlhead=N''''
+REPLACE(N'SELECT [xtype]',N'''',N'''''')
+'''',
@sqlend=N''''
+REPLACE(N' FROM [syscolumns] GROUP BY [xtype]',N'''',N'''''')
+N'''',
@sql1=N'',@sql2=N'',@sql3=N'',@sql4=N''
WHILE @ic>=0
SELECT
@sql1=N',@'+@ic+N' nvarchar(4000)'+@sql1,
@sql2=N',@'+@ic+N'=N'''''+@sql2,
@sql3=N',@'+@ic
+N'=CASE g WHEN '+@ic
+N' THEN @'+@ic+N'+a ELSE @'+@ic
+N' END'+@sql3,
@sql4=N'+@'+@ic+@sql4,
@ic=@ic-1
SELECT
@sql1=STUFF(@sql1,1,1,N''),
@sql2=STUFF(@sql2,1,1,N''),
@sql3=STUFF(@sql3,1,1,N''),
@sql4=STUFF(@sql4,1,1,N'')
--执行
EXEC(N'DECLARE '+@sql1+N'
SELECT '+@sql2+N'
SELECT '+@sql3+N' FROM #
EXEC(N'+@sqlhead+N'+'+@sql4+N'+N'+@sqlend+N')')
--删除临时表
DROP TABLE #
/*--方法总结
总结了前两种方法的优点，自动判断需要处理的变量数
--*/
--*/
华夏小卒 2010-12-29
- 打赏
- 举报
用varchar（max）可以，但是这样的需求就有问题了，呵呵，就算结果出来了，又能怎么样呢
czyoooo 2010-12-29
- 打赏
- 举报
我测试了一下,CREATER太多,所以declare @s varchar(8000)
太短了,无法执行全部.
太短了,无法执行全部.
华夏小卒 2010-12-29
- 打赏
- 举报
这个是varchar 型的，楼上是int 的
--> 测试数据: [orderTb]
if object_id('[orderTb]') is not null drop table [orderTb]
go
create table [orderTb] (ID int,COMPANY varchar(1),SALEPRICE int,CREATER VARCHAR(20),CREATTIME datetime)
insert into [orderTb]
select 1,'A',100,'101','2010-12-01' union all
select 2,'A',200,'101','2010-12-01' union all
select 3,'B',300,'301','2010-12-01' union all
select 4,'C',100,'101','2010-12-02' union all
select 5,'D',200,'201','2010-12-03'
declare @s varchar(8000)
SELECT @s=isnull(@s+',','')+'SUM(CASE WHEN CREATER='+CREATER+' THEN SALEPRICE ELSE 0 END) [总金额'+CREATER+'],
(SELECT COUNT(distinct COMPANY) FROM [orderTb] WHERE CREATER='+CREATER+' and CREATTIME=t.CREATTIME) [不同客户数'+CREATER+']'
FROM (SELECT DISTINCT CREATER FROM [orderTb])T
SET @S='
SELECT 日期=CREATTIME,'+@S+' FROM [orderTb] t
GROUP BY CREATTIME'
EXEC(@S)
日期 总金额101 不同客户数101 总金额201 不同客户数201 总金额301 不同客户数301
----------------------- ----------- ----------- ----------- ----------- ----------- -----------
2010-12-01 00:00:00.000 300 1 0 0 300 1
2010-12-02 00:00:00.000 100 1 0 0 0 0
2010-12-03 00:00:00.000 0 0 200 1 0 0
(3 行受影响)
-晴天 2010-12-29
- 打赏
- 举报
create table tb(ID int,COMPANY nvarchar(10),SALEPRICE int,CREATER int,CREATTIME datetime)
insert into tb select 1,'A',100,101,'2010-12-01'
insert into tb select 2,'A',200,101,'2010-12-01'
insert into tb select 3,'B',300,301,'2010-12-01'
insert into tb select 4,'C',100,101,'2010-12-02'
insert into tb select 5,'D',200,201,'2010-12-03'
go
select creattime,
sum((case when creater=101 then saleprice else 0 end))as [101p],
sum((case when creater=101 then 1 else 0 end))as [101c],
sum((case when creater=201 then saleprice else 0 end))as [201p],
sum((case when creater=201 then 1 else 0 end)) as [201c],
sum((case when creater=301 then saleprice else 0 end))as [301p],
sum((case when creater=301 then 1 else 0 end)) as [301c]
from(
select company,sum(saleprice)as saleprice,creater,creattime
from tb group by company,creater,creattime
)t
group by creattime
go
drop table tb
/*
creattime 101p 101c 201p 201c 301p 301c
----------------------- ----------- ----------- ----------- ----------- ----------- -----------
2010-12-01 00:00:00.000 300 1 0 0 300 1
2010-12-02 00:00:00.000 100 1 0 0 0 0
2010-12-03 00:00:00.000 0 0 200 1 0 0
(3 行受影响)
*/华夏小卒 2010-12-29
- 打赏
- 举报
--> 测试数据: [orderTb]
if object_id('[orderTb]') is not null drop table [orderTb]
go
create table [orderTb] (ID int,COMPANY varchar(1),SALEPRICE int,CREATER int,CREATTIME datetime)
insert into [orderTb]
select 1,'A',100,101,'2010-12-01' union all
select 2,'A',200,101,'2010-12-01' union all
select 3,'B',300,301,'2010-12-01' union all
select 4,'C',100,101,'2010-12-02' union all
select 5,'D',200,201,'2010-12-03'
declare @s varchar(8000)
SELECT @s=isnull(@s+',','')+'SUM(CASE WHEN CREATER='''+LTRIM(CREATER)+''' THEN SALEPRICE ELSE 0 END) [总金额'+LTRIM(CREATER)+'],
(SELECT COUNT(distinct COMPANY) FROM [orderTb] WHERE CREATER='''+LTRIM(CREATER)+''' and CREATTIME=t.CREATTIME) [不同客户数'+LTRIM(CREATER)+']'
FROM (SELECT DISTINCT CREATER FROM [orderTb])T
SET @S='
SELECT 日期=CREATTIME,'+@S+' FROM [orderTb] t
GROUP BY CREATTIME'
EXEC(@S)
日期 总金额101 不同客户数101 总金额201 不同客户数201 总金额301 不同客户数301
----------------------- ----------- ----------- ----------- ----------- ----------- -----------
2010-12-01 00:00:00.000 300 1 0 0 300 1
2010-12-02 00:00:00.000 100 1 0 0 0 0
2010-12-03 00:00:00.000 0 0 200 1 0 0
(3 行受影响)czyoooo 2010-12-29
- 打赏
- 举报
from (select DISTINCT CREATER FROM orderTb)a
czyoooo 2010-12-29
- 打赏
- 举报
CREATER是VARCHAR(50)
华夏小卒 2010-12-29
- 打赏
- 举报
CREATER 是什么类型？
czyoooo 2010-12-29
- 打赏
- 举报
TO:js_szy
要求工号不写死,写死了就麻烦了,主要碰到的问题是不同客户数汇总
要求工号不写死,写死了就麻烦了,主要碰到的问题是不同客户数汇总
czyoooo 2010-12-29
- 打赏
- 举报
要求统计结果:
日期 101 201 301
总金额 不同客户数 总金额 不同客户数 总金额 不同客户数
2010-12-01 300 1 0 0 300 1
2010-12-02 100 1 0 0 0 0
2010-12-03 0 0 200 1 0 0
日期 101 201 301
总金额 不同客户数 总金额 不同客户数 总金额 不同客户数
2010-12-01 300 1 0 0 300 1
2010-12-02 100 1 0 0 0 0
2010-12-03 0 0 200 1 0 0
华夏小卒 2010-12-29
- 打赏
- 举报
--> 测试数据: [orderTb]
if object_id('[orderTb]') is not null drop table [orderTb]
go
create table [orderTb] (ID int,COMPANY varchar(1),SALEPRICE int,CREATER int,CREATTIME datetime)
insert into [orderTb]
select 1,'A',100,101,'2010-12-01' union all
select 2,'A',200,101,'2010-12-01' union all
select 3,'B',300,301,'2010-12-01' union all
select 4,'C',100,101,'2010-12-02' union all
select 5,'D',200,201,'2010-12-03'
select 日期=CREATTIME,
总金额101=sum(case when CREATER='101' then SALEPRICE else 0 end),
不同客户数101=(select count(distinct COMPANY) from [orderTb] where CREATER='101' and CREATTIME=t.CREATTIME),
总金额102=sum(case when CREATER='201' then SALEPRICE else 0 end),
不同客户数102=(select count(distinct COMPANY) from [orderTb] where CREATER='201' and CREATTIME=t.CREATTIME),
总金额103=sum(case when CREATER='301' then SALEPRICE else 0 end),
不同客户数103=(select count(distinct COMPANY) from [orderTb] where CREATER='301' and CREATTIME=t.CREATTIME)
from [orderTb] t
group by CREATTIME
日期 总金额101 不同客户数101 总金额102 不同客户数102 总金额103 不同客户数103
----------------------- ----------- ----------- ----------- ----------- ----------- -----------
2010-12-01 00:00:00.000 300 1 0 0 300 1
2010-12-02 00:00:00.000 100 1 0 0 0 0
2010-12-03 00:00:00.000 0 0 200 1 0 0
(3 行受影响)
日期 总金额101 不同客户数101 总金额102 不同客户数102 总金额103 不同客户数103
----------------------- ----------- ----------- ----------- ----------- ----------- -----------
2010-12-01 00:00:00.000 300 1 0 0 300 1
2010-12-02 00:00:00.000 100 1 0 0 0 0
2010-12-03 00:00:00.000 0 0 200 1 0 0
(3 行受影响)
billpu 2010-12-29
- 打赏
- 举报
没看懂 日期怎么到上面去了
