单路线的公交怎么进行OD调查统计（根据单路公交数据）

[hwsdu2010]

单路线的公交怎么进行OD调查统计（根据单路公交数据）

[叶子]

OD调查结果通常用一个二维表格表示，称为OD OD调查
表，也叫OD矩阵。OD调查结果还可以通过期望值图、交通发生统计图、交通统计量图、交通等值线图、各种不同因素与OD量两两相关的分布曲线（相关曲线）等来表示。

楼主没有给出数据及想要的结果。

[飘零一叶]

什么都没有....

[王向飞]

[Quote=引用楼主 hwsdu2010 的回复:]
单路线的公交怎么进行OD调查统计（根据单路公交数据）
[/Quote]去书店找本书看 SQL2008程序设计 图灵出版社

[dawugui]

最好给出完整的表结构,测试数据,计算方法和正确结果.否则耽搁的是你宝贵的时间。
如果有多表,表之间如何关联?

发帖注意事项
http://topic.csdn.net/u/20091130/21/fb718680-98ff-4afb-98d8-cff2f8293ed5.html?24281

[dawugui]

这里有个最短乘车路线查询示例,你参考

--最短乘车路线查询示例(邹老大的。)
CREATE TABLE T_Line(
ID      nvarchar(10),  --公交线路号
Station nvarchar(10),  --站点名称
Orders  int)           --行车方向(通过它反应每个站的上一个、下一个站)
INSERT T_Line 
SELECT N'8路'  ,N'站A',1 UNION ALL
SELECT N'8路'  ,N'站B',2 UNION ALL
SELECT N'8路'  ,N'站C',3 UNION ALL
SELECT N'8路'  ,N'站D',4 UNION ALL
SELECT N'8路'  ,N'站J',5 UNION ALL
SELECT N'8路'  ,N'站L',6 UNION ALL
SELECT N'8路'  ,N'站M',7 UNION ALL
SELECT N'20路' ,N'站G',1 UNION ALL
SELECT N'20路' ,N'站H',2 UNION ALL
SELECT N'20路' ,N'站I',3 UNION ALL
SELECT N'20路' ,N'站J',4 UNION ALL
SELECT N'20路' ,N'站L',5 UNION ALL
SELECT N'20路' ,N'站M',6 UNION ALL
SELECT N'255路',N'站N',1 UNION ALL
SELECT N'255路',N'站O',2 UNION ALL
SELECT N'255路',N'站P',3 UNION ALL
SELECT N'255路',N'站Q',4 UNION ALL
SELECT N'255路',N'站J',5 UNION ALL
SELECT N'255路',N'站D',6 UNION ALL
SELECT N'255路',N'站E',7 UNION ALL
SELECT N'255路',N'站F',8
GO

--乘车线路查询存储过程
CREATE PROC p_qry
@Station_Start nvarchar(10),
@Station_Stop  nvarchar(10)
AS
SET NOCOUNT ON
DECLARE @l int
SET @l=0
SELECT ID,Station,
	Line=CAST('('+RTRIM(ID)+': '+RTRIM(Station) as nvarchar(4000)),
	Orders=Orders,
	[Level]=@l
INTO # FROM T_Line
WHERE Station=@Station_Start
WHILE @@ROWCOUNT>0 
	AND NOT EXISTS(SELECT * FROM # WHERE Station=@Station_Stop)
BEGIN
	SET @l=@l+1
	INSERT #(Line,ID,Station,Orders,[Level])
	SELECT 
		Line=a.Line+CASE
			WHEN a.ID=b.ID THEN N'->'+RTRIM(b.Station)
			ELSE N') ∝ ('+RTRIM(b.ID)
				+N': '+RTRIM(b.Station) END,
		b.ID,b.Station,b.Orders,@l
	FROM # a,T_Line b
	WHERE a.[Level]=@l-1
		AND(a.Station=b.Station AND a.ID<>b.ID
			OR a.ID=b.ID AND(
				a.Orders=b.Orders+1
				OR
				a.Orders=b.Orders-1))
		AND LEN(a.Line)<4000
		AND PATINDEX('%[ >]'+b.Station+'[-)]%',a.Line)=0
END
SELECT N'起点站'=@Station_Start
	,N'终点站'=@Station_Stop
	,N'乘车线路'=Line+N')' 
FROM # 
WHERE [Level]=@l 
	AND Station=@Station_Stop
IF @@ROWCOUNT =0 --如果未有可以到达的线路,则显示处理结果表备查
	SELECT * FROM #
GO

--调用
EXEC p_qry N'站A',N'站L'
/*--结果
起点站  终点站  乘车线路
---------- ------------ -----------------------------------------------------------
站A    站L    (8路: 站A->站B->站C->站D->站J->站L)
--*/