求教一个日期问题

[贾斯提斯]

一个函数问题
2个日期输入参数,1个状态参数,求出这2个日期之间包含的星期n的天数

比如输入参数 '2011-1-1','2011-3-10',1,则求出'2011-1-1'与'2011-3-10'之间星期天的天数

输入
'2011-4-1','2011-7-10',6,则求出'2011-4-1'与'2011-7-10'之间星期六的天数

要求不能用循环,不能用游标

请问怎么实现呢?
一条select语句是否可以实现呢?

[jiao3630]

查询2个日期分别是星期几
2个日期天数差
计算……
貌似挺麻烦 下班了 回家

[jxqn_liu]

贴个

--原帖地址：http://blog.csdn.net/DengXingJie/archive/2011/02/25/6208762.aspx

/*

**********************************************

Program ID: FUN_GetDaysOfWeek

Purpose   : 求某段时间内某一星期日期的天数

Author    : Jesse

Date      : 2011.02.19

**********************************************

*/

go

Create Function dbo.FUN_GetDaysOfWeek(    

@DateS smalldatetime,--开始时间

@DateE smalldatetime,--结束

@WeekValue int)      --星期的某一天：-周日、-周一...7-周六

Returns nvarchar(100)

As

Begin

    declare

        @sResult nvarchar(100),    --结果描述

        @nResult int,              --结果天数

        @nWeekValue int,           --起始日期是星期几(1-周日、-周一...7-周六)

        @nDays int,                --时间段内的天数

        @nBeforeDays int,          --起始日期到第一次相符日期的天数

        @sWeekName varchar(20),    --所求日期的星期名称

        @tmpDate smalldatetime

    

    set @WeekValue=@WeekValue % 7

    if @WeekValue=0 

        set @WeekValue=7

 

    --如果起始日期大于终止日期，则对换

    if @DateS>@DateE

        select @tmpDate=@DateE,@DateE=@DateS,@DateS=@tmpDate

 

    --取得起始日期的星期数，与设置无关(1-周日、-周一...7-周六)

    select @nWeekValue=(Datepart(dw,@DateS)+(@@Datefirst %7))%7

    if @nWeekValue=0

        set @nWeekValue=7

    

    set @sWeekName=DateName(dw,DateAdd(d,@WeekValue-@nWeekValue,@DateS))

 

    if @WeekValue>=@nWeekValue

        set @nBeforeDays=@WeekValue-@nWeekValue

    else

        set @nBeforeDays=7-abs(@WeekValue-@nWeekValue)

 

    --取得时间段内的天数

    select @nDays=Datediff(d,@DateS,@DateE)+1

    if @nDays<@nBeforeDays

        select @nResult=0

    else

        select @nResult=ceiling((@nDays-@nBeforeDays)/7.0)

    set @sResult=N'日期区间：'+ convert(varchar(10),@DateS,120)+ N' 到' +convert(varchar(10),@DateE,120) +' 之间'

                +@sWeekName +N' 共有'+cast(@nResult as varchar(100))+N' 天'

    Return @sResult

end    

 

go

--测试示例

select dbo.FUN_GetDaysOfWeek('2011-03-01','2011-05-31',1)

 

--运行结果

/*

日期区间：2011-03-01 到2011-05-31 之间Sunday 共有13 天

*/

 



本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/maco_wang/archive/2011/03/20/6262935.aspx

[叶子]

一条语句太有难度了，用函数可以处理。

[贾斯提斯]

如果是查一个月内的星期天的天数的话,我可以一条语句写出
Case when (datediff(day,@start,@end)+1)%7 >=datepart(w,@end) then 5 else 4 end
因为一个月内星期天的天数不是5就是4

但是扩展到任意2天内,就一时间想不明白,该怎么写

[叶子]

declare @k int;set @k=1 -- 星期几
declare @i datetime;set @i='2011-03-01' --开始时间
declare @j datetime;set @j='2011-05-08' --结束时间

select case when @k>=case datepart(w,@i)-1 when 0 then 7 else datepart(w,@i)-1 end then (datediff(d,@i,@j)-(@k-case datepart(w,@i)-1 when 0 then 7 else datepart(w,@i)-1 end))/7+1 else (datediff(d,@i,@j)-(7-(case datepart(w,@i)-1 when 0 then 7 else datepart(w,@i)-1 end-@k)))/7+1 end

/*
星期 个数
---- ----
1 9
2 10
3 10
4 10
5 10
6 10
7 10
*/

你测试下，看看行不

[叶子]

declare @k int;set @k=3 -- 星期几
declare @i datetime;set @i='2011-03-01' --开始时间
declare @j datetime;set @j='2011-03-19' --结束时间

select case when @k>=case datepart(w,@i)-1 when 0 then 7 else datepart(w,@i)-1 end then (datediff(d,@i,@j)-(@k-case datepart(w,@i)-1 when 0 then 7 else datepart(w,@i)-1 end))/7+1 else (datediff(d,@i,@j)-(7-(case datepart(w,@i)-1 when 0 then 7 else datepart(w,@i)-1 end-@k)))/7+1 end

这样比较容易看，除了周日和周一是2天，其他的都是3天，测试无误。

[xiangyehpu]

declare @startdate datetime
declare @enddate datetime
declare @i int

set @startdate = '2011-05-01'
set @enddate = '2011-05-22'
set @i = 1

select (datediff(day,@startdate,@enddate) 
      + datepart(weekday,@startdate) 
      + (7 - datepart(weekday,@enddate)))/7 
+ (case 
   when datepart(weekday,@startdate) > @i then -1
   else 0
   end)
+ (case 
   when datepart(weekday,@enddate) < @i then -1
   else 0
   end)

应该没问题，楼主试试

[xyytuo]

[火光闪耀]

难度不小，就是用一条写出来了 花费的时间也太大了，不划算啊。

[windfeel2008]

写的很简单，但测试了下好像是对了，呵呵

Declare @StartDate DateTime
Declare @EndDate DateTime
Set @StartDate='2008-5-7'
Set @EndDate='2008-5-31'
Select DateDiff(wk,@StartDate,@EndDate)+(Case When Datepart(dw,@StartDate)=1 Then 1 Else 0 End)

[贾斯提斯]

谢谢
windfeel2008的结果是最准确的,可惜只能指定星期天

maco_wang 的结果误差比较大

xiangyehpu 的结果误差小,很接近了

[贾斯提斯]

提供测试数据

declare @tdate datetime , @sdate datetime , @edate datetime ,@i int ,@s int 
declare @t_temp table(c_sdate datetime,c_edate datetime,c_s int)

set @s = 1

set @i=1000
while @i>=0
begin

set @tdate='2011-1-1' 
set @sdate=dateadd(day,cast(RAND()*365 as int),@tdate)
set @edate=dateadd(day,cast(RAND()*365 as int),@tdate)

if @sdate>@edate 
select @tdate=@sdate , @sdate=@edate , @edate=@tdate

insert into @t_temp(c_sdate ,c_edate ,c_s)
select @sdate,@edate,@s

set @i=@i-1 
end

select a.* from @t_temp as a

这里有1000行随机数据可供应测试,发现windfeel2008是最准确的,如今正在想办法在windfeel2008的基础上扩展为任意星期几