怎样才能让程序10秒后运行下一语句？

[qdaijchf]

不使用Timer控件，运行messagebox.show("你好")后，间隔10秒，再运行messagebox.show("大家好")。

[zhao38322684]

哦。。是10秒。

[娃都会打酱油了]

Thread.Sleep(10*1000);
//开启新线程

[qq37724861]

Private Declare Sub Sleep Lib "Kernel32" (ByVal dwMilliseconds As Long)

Private Sub Form_click()
    MsgBox "你好1"
    DoEvents
    Sleep 1000 * 10
    MsgBox "你好2"
End Sub

[shiyuabc]

VB无卡死延时（非sleep）
2009-11-12 18:05
首先添加类模块。

内容如下：

'''''''''''''''''''''''''''''''''''''''''

Option Explicit

Private Type FILETIME
dwLowDateTime As Long
dwHighDateTime As Long
End Type

Private Const WAIT_ABANDONED& = &H80&
Private Const WAIT_ABANDONED_0& = &H80&
Private Const WAIT_FAILED& = -1&
Private Const WAIT_IO_COMPLETION& = &HC0&
Private Const WAIT_OBJECT_0& = 0
Private Const WAIT_OBJECT_1& = 1
Private Const WAIT_TIMEOUT& = &H102&
Private Const INFINITE = &HFFFF
Private Const ERROR_ALREADY_EXISTS = 183&
Private Const QS_HOTKEY& = &H80
Private Const QS_KEY& = &H1
Private Const QS_MOUSEBUTTON& = &H4
Private Const QS_MOUSEMOVE& = &H2
Private Const QS_PAINT& = &H20
Private Const QS_POSTMESSAGE& = &H8
Private Const QS_SENDMESSAGE& = &H40
Private Const QS_TIMER& = &H10
Private Const QS_MOUSE& = (QS_MOUSEMOVE Or QS_MOUSEBUTTON)
Private Const QS_INPUT& = (QS_MOUSE Or QS_KEY)
Private Const QS_ALLEVENTS& = (QS_INPUT Or QS_POSTMESSAGE Or QS_TIMER Or QS_PAINT Or QS_HOTKEY)
Private Const QS_ALLINPUT& = (QS_SENDMESSAGE Or QS_PAINT Or QS_TIMER Or QS_POSTMESSAGE Or QS_MOUSEBUTTON Or QS_MOUSEMOVE Or QS_HOTKEY Or QS_KEY)

Private Const UNITS = 4294967296#
Private Const MAX_LONG = -2147483648#

Private Declare Function CreateWaitableTimer Lib "kernel32" Alias "CreateWaitableTimerA" (ByVal lpSemaphoreAttributes As Long, ByVal bManualReset As Long, ByVal lpName As String) As Long
Private Declare Function OpenWaitableTimer Lib "kernel32" Alias "OpenWaitableTimerA" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal lpName As String) As Long
Private Declare Function SetWaitableTimer Lib "kernel32" (ByVal hTimer As Long, lpDueTime As FILETIME, ByVal lPeriod As Long, ByVal pfnCompletionRoutine As Long, ByVal lpArgToCompletionRoutine As Long, ByVal fResume As Long) As Long
Private Declare Function CancelWaitableTimer Lib "kernel32" (ByVal hTimer As Long)
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function MsgWaitForMultipleObjects Lib "user32" (ByVal nCount As Long, pHandles As Long, ByVal fWaitAll As Long, ByVal dwMilliseconds As Long, ByVal dwWakeMask As Long) As Long

Private mlTimer As Long

Private Sub Class_Terminate()
On Error Resume Next
If mlTimer <> 0 Then CloseHandle mlTimer
End Sub

Public Sub Wait(MilliSeconds As Long)
On Error GoTo ErrHandler
Dim ft As FILETIME
Dim lBusy As Long
Dim lRet As Long
Dim dblDelay As Double
Dim dblDelayLow As Double

mlTimer = CreateWaitableTimer(0, True, App.EXEName & "Timer" & Format$(Now(), "NNSS"))

If Err.LastDllError <> ERROR_ALREADY_EXISTS Then
ft.dwLowDateTime = -1
ft.dwHighDateTime = -1
lRet = SetWaitableTimer(mlTimer, ft, 0, 0, 0, 0)
End If

' Convert the Units to nanoseconds.
dblDelay = CDbl(MilliSeconds) * 10000#

' By setting the high/low time to a negative number, it tells
' the Wait (in SetWaitableTimer) to use an offset time as
' opposed to a hardcoded time. If it were positive, it would
' try to convert the value to GMT.
ft.dwHighDateTime = -CLng(dblDelay / UNITS) - 1
dblDelayLow = -UNITS * (dblDelay / UNITS - Fix(CStr(dblDelay / UNITS)))

If dblDelayLow < MAX_LONG Then dblDelayLow = UNITS + dblDelayLow

ft.dwLowDateTime = CLng(dblDelayLow)
lRet = SetWaitableTimer(mlTimer, ft, 0, 0, 0, False)

Do
' QS_ALLINPUT means that MsgWaitForMultipleObjects will
' return every time the thread in which it is running gets
' a message. If you wanted to handle messages in here you could,
' but by calling Doevents you are letting DefWindowProc
' do its normal windows message handling---Like DDE, etc.
lBusy = MsgWaitForMultipleObjects(1, mlTimer, False, INFINITE, QS_ALLINPUT&)
DoEvents
Loop Until lBusy = WAIT_OBJECT_0

' Close the handles when you are done with them.
CloseHandle mlTimer
mlTimer = 0
Exit Sub

ErrHandler:
Err.Raise Err.Number, Err.Source, "[clsWaitableTimer.Wait]" & Err.Description
End Sub

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

'以上保存名字为：clsWaitableTimer

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

把这个放到程序里：

Private mobjWaitTimer As clsWaitableTimer

Set objTimer = New clsWaitableTimer

使用方法：

mobjWaitTimer.Wait(5000) '延时5秒。



很不错，不过调用方法不对。
正确的应该是
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private mobjWaitTimer As clsWaitableTimer
Dim objTimer As clsWaitableTimer

Private Sub Command1_Click()
Set objTimer = New clsWaitableTimer
objTimer.Wait (5000) '延时5秒。
Print "test"
End Sub

[shiyuabc]

以上代码刚不久前才用过，VB6.0测试是可用的。虽然看起来代码很多，其实就一个模块，改下模块名，然后在需调用窗口中加两句定义就可以调用了。

[dengfeiling]

messagebox.show("你好");
System.Threading.Thread.Sleep(10*1000);
messagebox.show("大家好")

[tk600158]

用最简单的

    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim RunTime As Date = Now()
        MsgBox("你好")
        Do
            My.Application.DoEvents() '释放控制权给程序的其他事件
            Dim i As Integer = DateDiff("s", RunTime, Now)
            If i > 5 Then Exit Do
        Loop
        MsgBox("大家好")
    End Sub

[tk600158]

修改
If i > 5 Then Exit Do
可以更改延时的秒数

[rmini]

继续关注

[gooodiuck]

用这个试试，
Private Declare Function GetTickCount Lib "kernel32" () As Integer
'获取系统开机到现在所过去的时间，ms级
dim a as integer=GetTickCount
Do : My.Application.DoEvents()
Loop Until GetTickCount - a >= 1000'1000毫秒
继续执行你要执行的语句

[killeruser]

System.Threading.Thread.Sleep(10000)

[cosmo_sei]

如果要求界面不锁死，必须使用多线程

new System.Threading.Thread(
    () => { 
        MessageBox.Show("你好"); 
        System.Threading.Thread.Sleep(3000); 
        MessageBox.Show("大家好"); 
    }
).Start();

[123工艺品]

为什么不用TIMER控件？
控件不就是让我们用的吗
。。。。

[SP12345678902]

'********************************************************************************
'延迟函数，使程序延迟若干秒
'@date 2011/03/30
'@param delaytime 延迟的秒数
'@return 无
'********************************************************************************
Public Sub delaySeconds(delaytime As Single)
Dim start As Single
start = Timer
While delaytime > Timer - start
DoEvents
Wend
End Sub

[huzengzeng1]

if MessageBox.Show("你好") then
t = VB.Timer() '获取当前时间
Do
System.Windows.Forms.Application.DoEvents()
Loop Until VB.Timer() > t + 10.0#
'延迟10秒
MessageBox.Show("大家好")
end if

[nice_L]

System.Threading.Thread.Sleep(10000)

[赫克托尔]

System.Threading.Thread.Sleep(10*1000)；

[wqs12ec056]

dim i as integer
Private Sub Timer1_Timer()
select case i
case 0:messagebox.show("你好")
case 1:messagebox.show("大家好")
case 2:messagebox.show("我很好")
......
end select
i=i+1
End Sub

Timer1的间隔时间设置成10秒

[jk0144]

我来学习

[kxyzjm]

刚学.net,向大家学习