winsock传送字符串编码的问题

[itakeblue]

Winsock.SendData string & vbCrLf

string 为一般赋值，未做过编码设置，都说vb的字符串编码是unicode的，但经测试：

在简体中文操作系统中Winsock.SendData此字符串是以 gb2312 编码发送的
在韩文操作系统中Winsock.SendData此字符串是以 EUC_KR 编码发送的

因为客户端只有用以上编码收取字符串才不会出现乱码。

有什么办法可以统一成一种编码发送吗？最好是 utf-8 编码

尝试过 Winsock.SendData StrConv((string & vbCrLf), vbUnicode) 不行，失败
还有将 string 通过 adodb.stream 以 utf-8 编码写入一个临时文本文件，再以 utf-8 读出再发送，还是不行

[c_cyd2008]

用Byte(),不要用string,VB会对string做本地化处理
发送端：
dim s() as byte
s="XXXXX"
wsksnd.senddata s

接收端：
dim s() as byte
wskrcv.getdata s

vb使用的编码为utf-16

[咸清]

这个嘛，以前讨论过多次了。
VB不直接支持UTF8，但是可以在收发出转换。
好久不贴代码了，今天破例了

Option Explicit


Public Declare Function WideCharToMultiByte Lib "kernel32" (ByVal CodePage As Long, ByVal dwFlags As Long, ByVal lpWideCharStr As Long, ByVal cchWideChar As Long, ByRef lpMultiByteStr As Any, ByVal cchMultiByte As Long, ByVal lpDefaultChar As String, ByVal lpUsedDefaultChar As Long) As Long
Public Declare Function MultiByteToWideChar Lib "kernel32" (ByVal CodePage As Long, ByVal dwFlags As Long, ByVal lpMultiByteStr As Long, ByVal cchMultiByte As Long, ByVal lpWideCharStr As Long, ByVal cchWideChar As Long) As Long

Public Function UTF8_Encode(ByVal strUnicode As String) As Byte()
'UTF-8 编码

    Dim TLen As Long
    Dim lngBufferSize As Long
    Dim lngResult As Long
    Dim bytUtf8() As Byte
    
    TLen = Len(strUnicode)
    If TLen = 0 Then Exit Function
    
    lngBufferSize = TLen * 3 + 1
    ReDim bytUtf8(lngBufferSize - 1)
    
    lngResult = WideCharToMultiByte(CP_UTF8, 0, StrPtr(strUnicode), TLen, bytUtf8(0), lngBufferSize, vbNullString, 0)
    
    If lngResult <> 0 Then
        lngResult = lngResult - 1
        ReDim Preserve bytUtf8(lngResult)
    End If
    
    UTF8_Encode = bytUtf8
End Function

Public Function UTF8_Decode(ByRef bUTF8() As Byte) As String
'UTF-8 解码
    Dim lret As Long
    Dim lLen As Long
    Dim lBufferSize As Long
    Dim sBuffer As String
    Dim bBuffer() As Byte
    
    lLen = UBound(bUTF8) + 1
    
    If lLen = 0 Then Exit Function
    
    lBufferSize = lLen * 2
    
    sBuffer = String$(lBufferSize, Chr(0))
    
    lret = MultiByteToWideChar(CP_UTF8, 0, VarPtr(bUTF8(0)), lLen, StrPtr(sBuffer), lBufferSize)
    
    If lret <> 0 Then
        sBuffer = Left(sBuffer, lret)
    End If
    
    UTF8_Decode = sBuffer
End Function

Public Function CreateStringFromByte(ByRef byteArray() As Byte, ByVal ByteLength As Long) As String
'字节数组中的数据连接成字符串

    Dim StringData As String
    
    '** 分配字符串空间
    StringData = Space(ByteLength)
    '** 复制字符数组地址内容到字符串地址
    MoveMemory ByVal StringData, ByVal VarPtr(byteArray(0)), ByteLength
    
    '** 返回字符串
    CreateStringFromByte = StringData
End Function

Public Function SaveStringToByteArry(ByRef strString As String) As Byte()
'把字符串存入字节数组
    
    Dim BytArray() As Byte, lngStrLen As Long
    
    '** 获取字符串的长度(字节)
    lngStrLen = LenB(StrConv(strString, vbFromUnicode))
    
    '** 分配数组空间
    ReDim BytArray(lngStrLen - 1)

    '** 将字符串地址中的内容拷贝到数组
    MoveMemory ByVal VarPtr(BytArray(0)), ByVal strString, lngStrLen
    
    SaveStringToByteArry = BytArray
End Function

'gb2312编码
Public Function GBKEncode(szInput) As String
    Dim i As Long
    Dim startIndex As Long
    Dim endIndex As Long
    Dim X() As Byte
    
    X = StrConv(szInput, vbFromUnicode)
    
    startIndex = LBound(X)
    endIndex = UBound(X)
    For i = startIndex To endIndex
        GBKEncode = GBKEncode & "%" & Hex(X(i))
    Next
End Function

'GB2312编码
Public Function GBKDecode(ByVal code As String) As String
    code = Replace(code, "%", "")
    Dim bytes(1) As Byte
    Dim Index As Long
    Dim Length As Long
    Dim codelen As Long
    codelen = Len(code)
    While (codelen > 3)
        For Index = 1 To 2
            bytes(Index - 1) = Val("&H" & Mid(code, Index * 2 - 1, 2))
        Next Index
        GBKDecode = GBKDecode & StrConv(bytes, vbUnicode)
        code = Right(code, codelen - 4)
        codelen = Len(code)
    Wend
End Function

[itakeblue]

谢谢楼上两位，我试试

[owlinrye]

我也想知道啊