有没有哪位仁兄帮忙调试下

[I'm Daniel Du]

杨季文的80x86汇编语言程序设计
masm汇编时说类型不匹配
检查了下发现也没错误,用debug太麻烦了,哪位电脑上有od的,就拜托了.

mlength=128;buffer size
;
dseg segment
buff db mlength
db ?
db mlength dup (?)
mess0 db 'please input:$"'
mess1 db 'length=$'
mess2 db 'x=$';number in bh
mess3 db 'y=$';letter in bl
dseg ends
;
cseg segment
assume cs:cseg,ds:dseg
start:mov ax,dseg
mov ds,ax
mov dx,offset mess0
call dispmess
mov dx,offset buff
mov ah,10;10=oah
int 21h
call newline
;清数字符计数 bh
;清字母符计数器 bl
;mov bh,0
;mov bl,0
xor bx,bx
;
mov cl,buff+1;get character string's actual length
mov ch,0
jcxz cok
mov si,buff+2
again:mov al,[si]
inc si
cmp al,'0'
jb next
cmp al,'9'
ja nodec
inc bh
jmp short next
nodec:or al,20h
cmp al,'a'
jb next
cmp al,'z'
ja next
inc bl
next:loop again
;
cok:mov dx,offset mess1
call dispmess
mov al,buff+1
xor ah,ah
call dispal
call newline
;
mov dx,offset mess2
call dispmess
mov al,bh
xor ah,ah
call dispal
call newline
;
mov dx,offset mess3
mov al,bl
xor ah,ah
call dispal
call newline
;
mov ax,4c00h
int 21h
;
;dispal
;in:al=8 bit binary digit
;out:null
dispal proc
mov cx,3
mov dl,10
disp1:div dl
xchg ah,al
add al,'0'
push ax
xchg ah,al
mov ah,0
loop disp1
mov cx,3
disp2:pop dx
call echoch
loop disp2
ret
dispal endp
;
;explanation:show dx
dispmess proc
mov ah,9
int 21h
ret
dispmess endp
;
;explanation:show dl
echoch proc
mov ah,2
int 21h
ret
echoch endp
;
newline proc
push ax
push dx
mov dl,0dh
mov ah,2
int 21h
mov dl,0ah
mov ah,2
int 21h
pop dx
pop ax
ret
newline endp
;
cseg ends
end start

[zara]

; ...
mov ch,0
jcxz cok
mov si,buff+2  ; 这里改为 mov  si, offset buff[2] 试试
again:mov al,[si]
inc si
; ...
; 另外，你这个是 dos16 类的程序吧，od 针对的是 Win32 类程序调试的
; 这个程序运行大体上是对的，虽然显示上略有瑕疵

[masmaster]

mov si,buff+2 ；buff是db类型，与si不符，改成
mov si,word ptr buff+2 ；试一试

ps：od不能调试16位程序吧？

[钱国正]

看到上面的大牛就晕了

[abee23]

jcxz cok
mov si,buff+2
again:mov al,[si]

改成：
jcxz cok
mov si,offset buff+2
again:mov al,[si]
或者改成：
jcxz cok
mov si,offset [buff+2]
again:mov al,[si]

;;;;-------
;原先的mov si,buff+2的意思把buff+2这个位置的值传给si，buff是byte的！所以buff+2也是byte的，而si是word来的,MOV要求两个操作数的长度大小一样的呀，所以MASM报错啦。！
;si应该存放buff+2这个地址的偏移，应该是16位的！
;而lz的mov si,buff+2 尝试直接把一个8数数值放到 si，16位寄存器当中。
;还好 mov 发现 两个操作数是不同长度的....呵呵。

[I'm Daniel Du]

16位od,你们不知道吧

[I'm Daniel Du]

谢谢了,我这就结贴.