在GRID中添加下拉列表框后为何看不见？

[lxhlxh110110]

在GRID中添加下拉列表框，为何看到的还是TEXT,而看不到下拉列表框，怎么办？请大家帮帮忙！

[sun8330]

1.column.sparse=.f.
2.加入复选框或组合框后，可以将原来的textbox删掉

[wds81787023]

我估计可能是TXT把你的下拉列表框给覆盖住了~~把TXT的visible属性 设置为 .F.假 就可以了！~

[十豆三]

如何在Grid中加入复选框或组合框？

*-----------------------------

方法一：

1、把 Grid 的列数改为>0 &&方法二不需要此项
2、右键单击 Grid ，编辑，在工具条中把 Checkbox 拿到要加入复选框的列中
3、右键单击 Grid ，编辑，然后选择加入复选框的列。
在属性窗口上的“数据”页面上把 Grid 的 Colum（加入复选框的Column）的 CurrentControl 值改成 Check1，
然后根据你的需要修改 Sparse 的值，来指定 CurrentControl 属性是影响列对象中的全部单元，还是仅影响列对象中的活动单元。


方法二：在 Grid 的INIT 事件中：

With This.Column4
	.AddObject("Check1","CheckBox")
	.CurrentControl='Check1'
	.Sparse=.F.
	.Check1.Caption=''
	.Check1.Visible=.T.
Endwith
*******************************************************************
同理可向 Grid 中添加 ComboBox 控件等

Grid 的 Init 事件

With This.Column3    && 假设姓别字段对应 Grid 的第3列
	.AddObject("Combo100","Combobox")
	.CurrentControl='Combo100'
	*    .sparse=.f.
	.Combo100.Style=2
	.Combo100.RowSourceType=0
	.Combo100.Visible=.T.
Endwith
This.Column3.Combo100.AddItem('男')
This.Column3.Combo100.AddItem('女')

或

Grid 的 Init 事件

With This.Column3
	.AddObject("Combo100","Combobox")
	.CurrentControl='Combo100'
	*	.sparse=.f.
	.Combo100.Style=2
	.Combo100.RowSourceType=0
	.Combo100.Visible=.T.
Endwith
Select 表名 &&此表可以是Grid的数据源也可以不是Grid的数据源
Scan
	This.Column3.Combo100.AddItem(字段名)
Endscan

或

Public gcBtmc(8)
gcBtmc(1)=''
gcBtmc(2)='补贴一'
gcBtmc(3)='补贴二'
gcBtmc(4)='补贴三'
gcBtmc(5)='补贴四'
gcBtmc(6)='补贴五'
gcBtmc(7)='补贴六'
gcBtmc(8)='补贴七'
With This.Column8
	.AddObject('Combobox1','Combobox')
	.CurrentControl='Combobox1'
	.Combobox1.Style=2
	.Combobox1.RowSourceType=5
	.Combobox1.RowSource='gcBtmc'
	.Combobox1.Visible=.T.
Endwith

[lxhlxh110110]

记了说明，是在VFP中

[十豆三]

[Quote=引用 4 楼 lxhlxh110110 的回复:]
记了说明，是在VFP中
[/Quote]

就是在 vfp 中呀。

[jiafangliang]

在属性窗口中选中要删除的text，将光标移到表单标题，按删除键即可.

[sghgy]

除了1楼，其他都没有参考意见。

[jack_wang0823]

[Quote=引用 6 楼 jiafangliang 的回复:]
在属性窗口中选中要删除的text，将光标移到表单标题，按删除键即可.
[/Quote]
按删除好像不行， 正确的是按退格键

[yyuuu2003]

VB code是不是FOXPRO9.0之类的语言?

[yyuuu2003]

With This.Column8
.AddObject('Combobox1','Combobox')
.CurrentControl='Combobox1'
.Combobox1.Style=2
.Combobox1.RowSourceType=5
.Combobox1.RowSource='gcBtmc'
.Combobox1.Visible=.T.
Endwith
象这样的WITH....
ENDWITH在FOXPRO6.0中可用的吗?

[十豆三]

[Quote=引用 10 楼 的回复:]
With This.Column8
.AddObject('Combobox1','Combobox')
E……
象这样的WITH....
ENDWITH在FOXPRO6.0中可用的吗?
[/Quote]可以。打开 vfp6.0，按 F1，查一下 with ... endwith 的用法。

[myperry]

主要是设置一下Sparse属性

[dbtelalwin]

2楼的就行了