存储过程问题

[koumingjie]

create procedure pr_1(@tableName carchar(100))
as
begin
declare @sql varchar(max)
declare @rowCount int
set @sql='select count(*) from ' + @tableName
..... 问题所在
end


问题所在：如何将count(*) 的值取到赋给变量@rowCount，我需要该值进行以后的处理

[AcHerat]

set @sql=N'select @count = count(*) from ' + @tableName 
exec sp_executesql @sql,N'@count int output',@rowCount output

[NBDBA]

create procedure pr_1(@tableName nvarchar(100))
as  
begin  
  declare @sql nvarchar(max)
  declare @rowCount int
  set @sql=N'select @r=count(*) from ' + @tableName  
  exec sp_executesql @sql ,N'@r int output',@rowCount output
  select @rowCount
end

[--小F--]

输出参数 
declare @num int, @sqls nvarchar(4000) 
set @sqls='select count(*) from tableName' 
exec(@sqls) 

--如何将exec执行结果放入变量中？ 

declare @num int, @sqls nvarchar(4000) 
set @sqls='select @a=count(*) from tableName ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select @num 

[dawugui]

看最后一段
--动态sql语句基本语法

 
1 :普通SQL语句可以用Exec执行 

eg: Select * from tableName 
Exec('select * from tableName') 
Exec sp_executesql N'select * from tableName' -- 请注意字符串前一定要加N 

2:字段名，表名，数据库名之类作为变量时，必须用动态SQL 

eg: 
declare @fname varchar(20) 
set @fname = 'FiledName' 
Select @fname from tableName -- 错误,不会提示错误，但结果为固定值FiledName,并非所要。 
Exec('select ' + @fname + ' from tableName') -- 请注意 加号前后的 单引号的边上加空格 

当然将字符串改成变量的形式也可 
declare @fname varchar(20) 
set @fname = 'FiledName' --设置字段名 

declare @s varchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
Exec(@s) -- 成功 
exec sp_executesql @s -- 此句会报错 

declare @s Nvarchar(1000) -- 注意此处改为nvarchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
Exec(@s) -- 成功 
exec sp_executesql @s -- 此句正确 

3. 输出参数 
declare @num int, 
@sqls nvarchar(4000) 
set @sqls='select count(*) from tableName' 
exec(@sqls) 
--如何将exec执行结果放入变量中？ 

declare @num int, 
@sqls nvarchar(4000) 
set @sqls='select @a=count(*) from tableName ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select @num 

[Lemon2013]

像这样的拼接SQL为参数赋值的语句 SQL需要这样才可以赋值，我以前也遇到过。

Declare @sql nvarchar(1000);
set @sql=N'select @count = count(*) from ' + @tableName 
exec sp_executesql @sql,N'@count int output',@rowCount output