句柄到底是个什么玩意？

[mummyII]

对于一个treeview来说，每一个item的句柄是固定的还是变化的？我想根据一个item的属性item.data查找该item的句柄从而定位这个item。看了几个例子都很麻烦。我就想如果句柄似乎固定的话，我在建立treeview的时候就把每一个item的句柄保存在一个数据库表里，这样就简单多了。那么是不是可以这么做呢？

[yyoinge]

句柄是控件的ID号，就想我们人的身份证号一样

不过treeviewitem的handle其实是有规律的，率先被insert的handle为1，后面被insert的依次加1递增

但是你的想法是无法实现的，因为handle不是固定的

[路人甲cw]

句柄在一个应用程序实例中是固定的,但如果你将这个实例关闭再打开可能就会发现变化,因为这是操作系统分配给应用程序的,他实质上是对指针的一种系统级的封装,在API编程中调用者不需要知道对象的指针地址只需要知道对象句柄就可以了,系统会根据句柄去调用它指向的指针地址,因为指针可能由系统动态改变它所指向的内存区域,但句柄并不会改变而是更新它所指向的指针地址,此时对于调用者来讲并没有发生改变.而句柄的作用就是用于间接定位内存中的对象,当对象被释放时句柄也会被释放,所以下次再创建同一类型的对象时它的句柄可能就不会再是上一次创建时的句柄了,因为它可能已经被分配给其它对象了.

[yyoinge]

f_tv_find 函数

global function long f_tv_find (treeview atv, string as_data, boolean ab_data, long al_handle_s, long al_handle_e);//===========================================================
//	f_tv_find ：在树atv中从句柄为al_handle_s的节点开始查找内容
//	（	当ab_data为true时，	查找节点的data属性值；
//		当ab_data为false时，	查找节点的label属性值）as_data，
//	当查找到句柄为al_handle_e的节点时还没有找到符合条件的节点，则停止查找并返回-1
// 当查找到符合条件的节点时，则返回该节点的句柄
// 当查找完整棵树，未找到符合条件的节点，且未被中止时，则返回0
//===========================================================
if al_handle_s <= 0 then return 0
long ll_h
treeviewitem	lt_tvi
if atv.GetItem(al_handle_s, lt_tvi) = -1 then return -1
if ab_data then //查找data
	if (Not IsNull(lt_tvi.data)) and (string(lt_tvi.data) <> "") then
		if lt_tvi.data = as_data then return al_handle_s
	end if
else//查找label
	if lt_tvi.label = as_data then return al_handle_s
end if
if al_handle_s = al_handle_e then return -1 //强制中止查找
al_handle_s = atv.FindItem(ChildTreeItem!, al_handle_s)

do while al_handle_s > 0
	ll_h = f_tv_find(atv,as_data,ab_data,al_handle_s,al_handle_e)
	if ll_h = -1 or ll_h > 0 then return ll_h //强制中止或者找到节点，则直接返回
	//查找下一个兄弟节点
	al_handle_s = atv.FindItem(NextTreeItem!, al_handle_s)
loop
//没有找到，则返回0
return 0
end function

在tv_1中从根节点开始查找label内容为“明细备注”的第一个节点

long ll
ll = f_tv_find(tv_1,'明细备注',false, tv_1.FindItem(RootTreeItem!, 0), 0)

在tv_1中从根节点开始查找data内容为“明细备注”的第一个节点

long ll
ll = f_tv_find(tv_1,'明细备注',true, tv_1.FindItem(RootTreeItem!, 0), 0)

在tv_1中从句柄为5的节点开始查找data内容为“明细备注”的第一个节点

long ll
ll = f_tv_find(tv_1,'明细备注',true, 5, 0)

在tv_1中的节点5到节点20之间查找data内容为“明细备注”的第一个节点

long ll
ll = f_tv_find(tv_1,'明细备注',true, 5, 20)

[mummyII]

如果是用itempopulate才形成的treeview不能用这个把

[wag_enu]

句柄：
在TV 里，句柄handle 是每插入一 item 所返回的一个 long 型的数值。它是程序运行时产生的，根据item 插入的先后，依次计数。根据这个handle 就可以操作TV 的对应的ITEM 。

[Quote=引用 4 楼 mummyii 的回复:]
如果是用itempopulate才形成的treeview不能用这个把
[/Quote]
不管用什么方法构建的TV，只要像yyoinge 在3#那样 灵活应用finditem 方法和相关事件里的 handle ，都可以很方便的找到需要的节点。

[mummyII]

由于我的数据量太大，每次打开时至形成了treeview的第一层，然后用itempopulate才得到并打开下一层（你知道的),这个函数也适用么？

[wlj768]

顶一下，也被句柄搞糊涂，C#里什么类型就是什么类型，PB里能用数字代表某个东西，前段时间一直转不过弯来。

[Samoon]

发现PB一提到Treeview就连大神都会出现了。一刷新句柄就会变的，所以判断data比较好。

[路人甲cw]

[Quote=引用 7 楼 wlj768 的回复:]

顶一下，也被句柄搞糊涂，C#里什么类型就是什么类型，PB里能用数字代表某个东西，前段时间一直转不过弯来。
[/Quote]
Win32编程中句柄都是一样的,C#里只不过把它封装成了IntPtr类型,但实质上都是长整型数值,十进制表示对象的句柄地址

[mummyII]

呵呵，大神都来了

[yyoinge]

[Quote=引用 6 楼 mummyii 的回复:]
由于我的数据量太大，每次打开时至形成了treeview的第一层，然后用itempopulate才得到并打开下一层（你知道的),这个函数也适用么？
[/Quote]

只要你单击了，响应了itempopulate，则我提供的方法可以找到itempopulate中新增的节点

但是如果某节点没有被单击响应过itempopulate事件，则它的子节点此时并没有被插入，即便它在数据库中是存在，也无法finditem

你可以用一个实例变量数据存储来存储ids_node树形控件已经生成了的节点的data属性、label属性、handle属性
（1）在树形控件初始化及触发itempopulate事件时，往数据存储ids_node里面插入尚未存在的node信息。
（2）每次查找时，先到ids_node中进行查找，找到则直接定位到handle所对应的节点； 找不到，则到数据库中查找。
（3）如果数据库中也找不到对应的数据，则表示查找的内容不存在，查找结束
（4）如果数据库中查找得到对应的数据，则接着在数据库中查找该数据对应的父数据（也就是该数据在树形控件中的节点对应的父节点），如果父数据存在与ids_node中（假设在ids_node中存储的handle为100），则可以通过强制触发itempopulate事件来及时添加子节点（tv_1.event itempopulate(100) ），添加完子节点后，再到ids_node中查找数据，找到则选中节点。
（5）注意，步骤（4）中查找父数据的过程，应该用循环来表示。比如有数据链：a → aa → aaa → aaaa ，其中a是最父亲级别的数据，aaaa是最子级的数据，如果要查找的数据是“aaaa”，它不存在于ids_node中，其父数据“aaa”也不存在于ids_node中，则需要再查找“aaa”的父数据“aa”，如果“aa”还是不存在于ids_node中，则需要再查找父数据“a”。如果“a”存在与ids_node中，则需要先勇“a”所在节点添加子节点（tv_1.event itempopulate(a对应handle)），然后再为“aa”所在节点添加子节点（tv_1.event itempopulate(aa对应handle)），知道“aaaa”对应的节点被添加，才选中“aaaa”所在节点。
（6）当ids_node的rowcount()等于数据库中的数据量时，则不再检索数据库，这样可以减少与数据库的交互次数

[yyoinge]

上面的步骤（5）用递归来实现比较简单，也好理解一些