如何获取某一周是从几号到几号呢？

[bccu]

如何获取某一周是从几号到几号呢？

[bccu]

多谢。。。。

[bccu]

没人？

[-晴天]

哪一周?

[-晴天]

--本周:
select dateadd(d,number,'2011-01-01') 
from master..spt_values 
where type='p' and number<365
and datepart(wk,dateadd(d,number,'2011-01-01'))=datepart(wk,getdate())
/*
-----------------------
2011-10-16 00:00:00.000
2011-10-17 00:00:00.000
2011-10-18 00:00:00.000
2011-10-19 00:00:00.000
2011-10-20 00:00:00.000
2011-10-21 00:00:00.000
2011-10-22 00:00:00.000

(7 行受影响)

*/

[中国风]

DECLARE @year nvarchar(4),@week INT
SElecT @year=2011,@week=43
;WITH a
AS
(
SELECT CAST(@year+'0101' AS DATETIME) AS dt
UNION ALL
SELECT dt+1 FROM a WHERE YEAR(dt+1)<@year+1
) 
SELECT * 
FROM a 
WHERE DATEPART(wk,DATEADD(Day,1-(DATEPART(Weekday,dt)+@@DATEFIRST-2)%7-1,dt))=@week
OPTION(MAXRECURSION 0)
/*
2011-10-17 00:00:00.000
2011-10-18 00:00:00.000
2011-10-19 00:00:00.000
2011-10-20 00:00:00.000
2011-10-21 00:00:00.000
2011-10-22 00:00:00.000
2011-10-23 00:00:00.000
*/

[中国风]

--星期一做为一周的第1天
可這樣計算

[--小F--]

DECLARE @dt datetime
SET @dt=GETDATE()

DECLARE @number int
SET @number=3

--1．指定日期该年的第一天或最后一天
--A. 年的第一天
SELECT CONVERT(char(5),@dt,120)+'1-1'

--B. 年的最后一天
SELECT CONVERT(char(5),@dt,120)+'12-31'


--2．指定日期所在季度的第一天或最后一天
--A. 季度的第一天
SELECT CONVERT(datetime,
    CONVERT(char(8),
        DATEADD(Month,
            DATEPART(Quarter,@dt)*3-Month(@dt)-2,
            @dt),
        120)+'1')

--B. 季度的最后一天（CASE判断法）
SELECT CONVERT(datetime,
    CONVERT(char(8),
        DATEADD(Month,
            DATEPART(Quarter,@dt)*3-Month(@dt),
            @dt),
        120)
    +CASE WHEN DATEPART(Quarter,@dt) in(1,4)
        THEN '31'ELSE '30' END)

--C. 季度的最后一天（直接推算法）
SELECT DATEADD(Day,-1,
    CONVERT(char(8),
        DATEADD(Month,
            1+DATEPART(Quarter,@dt)*3-Month(@dt),
            @dt),
        120)+'1')


--3．指定日期所在月份的第一天或最后一天
--A. 月的第一天
SELECT CONVERT(datetime,CONVERT(char(8),@dt,120)+'1')

--B. 月的最后一天
SELECT DATEADD(Day,-1,CONVERT(char(8),DATEADD(Month,1,@dt),120)+'1')

--C. 月的最后一天（容易使用的错误方法）
SELECT DATEADD(Month,1,DATEADD(Day,-DAY(@dt),@dt))


--4．指定日期所在周的任意一天
SELECT DATEADD(Day,@number-DATEPART(Weekday,@dt),@dt)


--5．指定日期所在周的任意星期几
--A.  星期天做为一周的第1天
SELECT DATEADD(Day,@number-(DATEPART(Weekday,@dt)+@@DATEFIRST-1)%7,@dt)

--B.  星期一做为一周的第1天
SELECT DATEADD(Day,@number-(DATEPART(Weekday,@dt)+@@DATEFIRST-2)%7-1,@dt)

[--小F--]

再结合master..spt_values来做。

[Lyongt]

楼上的阿哥是对的，可以结贴了