求彩票缩水代码

[yjbike2011]

双色球中六保五的缩水代码，需直接对表进行操作，不要缩好的号码表

[yjbike2011]

ls66 有一个长度17的字符型字段 HMC，用来存放号码，如：05 07 21 24 30 33等


PRIVATE ALL
SET TALK OFF
SET DELETED ON
CLOSE DATABASES

cFile=[中6保四.txt]
lcCRLF = CHR(13) + CHR(10)
cStr=[]
USE ls66
SELECT hmc FROM ls66 INTO CURSOR ls1

GO TOP
cc=hmc
cStr=cc+lcCRLF
SELECT ls66
USE

DO WHILE .T.
SELECT hmc FROM ls1 WHERE h2cfgs(cc,hmc)<4 INTO CURSOR ls2

IF RECCOUNT()>0
cc=hmc
cStr=cStr+cc+lcCRLF
SELECT hmc FROM ls2 INTO CURSOR ls1
ELSE
EXIT
ENDIF
ENDDO
=STRTOFILE(cStr,cFile)

RETURN


FUNCTION h2cfgs
PARAMETERS cc1,cc2
PRIVATE ALL
k=0
FOR i=1 TO 6
k=IIF(SUBSTR(cc1,i*3-2,2)$cc2,k+1,k)
ENDFOR
RETURN k

用是能用，千条记录以下，0.2秒左右，5千条数据，就需3.5秒了，12376条记录更是需要14.6秒了，那更多不是要等上半天了，请各位高手帮忙改改，速度能快点

[十豆三]

说明一下你字段内容，最好举3条记录以上。
再说明一下你的需求，
最后说明一下你要的结果，帖3条记录以上。

[yjbike2011]

HMC　指彩票号码，如表内：
01 02 03 04 05 06
01 02 03 04 05 07
01 02 03 06 08 09
10 11 12 15 17 20
11 12 15 17 21 25
13 15 17 20 29 30
.....
运行结果
01 02 03 04 05 06
10 11 12 15 17 20
13 15 17 21 29 30
...

[yjbike2011]

思路是：1、第一条记录与表内的每条记录比较，相同号码4个或以上的删除，保存第一条记录；
2、取剩下的记录的第一条记录与剩下的记录逐一进行比较，相同号码4个或以上的删除，保存第一条记录；一直到表中剩余记录为0

[十豆三]

不玩彩票，还是帮顶吧。

[yjbike2011]

谢谢，快了4-5秒

[十豆三]

Create Table T1 (a1 c(2),a2 c(2),a3 c(2),a4 c(2),a5 c(2),a6 c(2))
Insert Into T1 Values ('01','02','03','04','05','06')
Insert Into T1 Values ('01','02','03','04','05','07')
Insert Into T1 Values ('01','02','03','06','08','09')
Insert Into T1 Values ('10','11','12','15','17','20')
Insert Into T1 Values ('11','12','15','17','21','25')
Insert Into T1 Values ('13','15','17','20','29','30')
Browse	&& 缩水前

Scan For !Deleted()
	lca1=a1
	lca2=a2
	lca3=a3
	lca4=a4
	lca5=a5
	lca6=a6
	lnRecno=Recno()
	Delete All For Recno()<>lnRecno And (;
		Iif(Inlist(a1,lca1,lca2,lca3,lca4,lca5,lca6),1,0)+;
		Iif(Inlist(a2,lca1,lca2,lca3,lca4,lca5,lca6),1,0)+;
		Iif(Inlist(a3,lca1,lca2,lca3,lca4,lca5,lca6),1,0)+;
		Iif(Inlist(a4,lca1,lca2,lca3,lca4,lca5,lca6),1,0)+;
		Iif(Inlist(a5,lca1,lca2,lca3,lca4,lca5,lca6),1,0)+;
		Iif(Inlist(a6,lca1,lca2,lca3,lca4,lca5,lca6),1,0))>3
	Go lnRecno
Endscan
Pack
Browse 	&& 缩水后

[十豆三]

1、把每列都索引试试速度。
2、设置 Set Deleted On，然后
Scan For !Deleted()
改为
Scan
再试试。