vb.net中richtextbox控件字体颜色的设置

[aishuishuichen]

两个本地记事本的内容进行比较，不同的用颜色进行标记
While (Not fs.EndOfStream)
str = fs.ReadLine()
str1 = ft.ReadLine()
RichTextBox1.Text += str + Chr(13) + Chr(10)
RichTextBox2.Text += str1 + Chr(13) + Chr(10)
If str.Length <= str1.Length Then
For i = 0 To str.Length - 1
If str.Substring(i, 1) <> str1.Substring(i, 1) Then
RichTextBox1.Select(i + b, 1)
RichTextBox1.SelectionColor = Color.Red
RichTextBox2.Select(i + a, 1)
RichTextBox2.SelectionColor = Color.Red
Else
RichTextBox1.Select(i + b, 1)
RichTextBox1.SelectionColor = Color.Black
RichTextBox2.Select(i + a, 1)
RichTextBox2.SelectionColor = Color.Black
End If
Next i


'For j = str.Length To str1.Length - 1
' RichTextBox2.Select(j, 1)
' RichTextBox2.SelectionColor = Color.Red
'Next j
'Else
'RichTextBox2.Select(str.Length + 1, 1)
'RichTextBox2.SelectionColor = Color.Red
'RichTextBox1.Text += Chr(13) + Chr(10)
'RichTextBox2.Select(str.Length, str1.Length - str.Length)
'RichTextBox2.SelectionColor = Color.Red
'RichTextBox1.Text += str1.Substring(str.Length, str1.Length - str.Length)
'RichTextBox2.Text += Chr(13) + Chr(10)
End If
b = b + str.Length + 1
a = a + str1.Length + 1
End While
为什么总改变最后一行的内容
（在线等答案）
谢谢！！！

[aishuishuichen]

有什么解决的方法吗？？？
急需解决方法

[苦苦的潜行者]

因为你每次
RichTextBox1.Text += str + Chr(13) + Chr(10)
RichTextBox2.Text += str1 + Chr(13) + Chr(10)
之后,前面标红的字体又重置为黑色,所以只有最后一行才是红色,

你可以测试一下
操作完之后加上一个空行,是不是你最后一行标红的也没有了.
RichTextBox1.Text += "" + Chr(13) + Chr(10)
RichTextBox2.Text += "" + Chr(13) + Chr(10)

[苦苦的潜行者]

应公司一个部门要求,刚写了一个RichTextbox比对的程序,思路和你的差不多,给你帖一下.
控件需要一个button(btnCompare),两个RichTextBox(rtbCorrect rtbTarget)
我这边只对英文字符进行测试通过,没试过中文.

'比对
    Private Sub btnCompare_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnCompare.Click
        Dim i As Integer
        Dim ct1, ct2 As Long
        Dim num1, num2 As Integer
        num1 = rtbCorrect.Lines.Length
        num2 = rtbTarget.Lines.Length
        If num2 < num1 Then
            i = CompareLine(num2)
            ct1 = CountText(rtbCorrect, i)
            rtbCorrect.Select(ct1, rtbCorrect.TextLength - ct1)
            rtbCorrect.SelectionColor = Color.Blue
        ElseIf num1 < num2 Then
            i = CompareLine(num1)
            ct2 = CountText(rtbTarget, i)
            rtbTarget.Select(ct2, rtbTarget.TextLength - ct2)
            rtbTarget.SelectionColor = Color.Red
        Else
            CompareLine(num2)
        End If
    End Sub

    '统计小于n行的richtextbox中的字数(注意每一行后面有回车符)
    Private Function CountText(ByVal rtb As RichTextBox, ByVal n As Integer) As Long
        Dim sum As Long = 0
        If n = 0 Then
            Return 0
        Else
            For i As Integer = 0 To n - 1
                sum += rtb.Lines(i).Length + 1   '千万别忘记最后+1,回车符占位一格
            Next
            Return sum
        End If
    End Function

    '行对行的比对
    Private Function CompareLine(ByVal LineSum As Integer) As Integer
        Dim ct1, ct2 As Integer
        Dim str1, str2 As String
        Dim i, j As Integer
        For i = 0 To LineSum - 1
            str1 = rtbCorrect.Lines(i)
            str2 = rtbTarget.Lines(i)
            ct1 = CountText(rtbCorrect, i)
            ct2 = CountText(rtbTarget, i)
            If str1 <> str2 Then
                If str2.Length < str1.Length Then
                    For j = 0 To str2.Length - 1
                        If str2.Substring(j, 1) <> str1.Substring(j, 1) Then
                            rtbTarget.Select(j + ct2, 1)
                            rtbTarget.SelectionColor = Color.Red
                            rtbCorrect.Select(j + ct1, 1)
                            rtbCorrect.SelectionColor = Color.Blue
                        End If
                    Next
                    rtbCorrect.Select(j + ct1, str1.Length - j)
                    rtbCorrect.SelectionColor = Color.Blue
                ElseIf str2.Length > str1.Length Then
                    For j = 0 To str1.Length - 1
                        If str2.Substring(j, 1) <> str1.Substring(j, 1) Then
                            rtbCorrect.Select(j + ct1, 1)
                            rtbCorrect.SelectionColor = Color.Blue
                            rtbTarget.Select(j + ct2, 1)
                            rtbTarget.SelectionColor = Color.Red
                        End If
                    Next
                    rtbTarget.Select(j + ct2, str2.Length - j)
                    rtbTarget.SelectionColor = Color.Red
                Else
                    For j = 0 To str2.Length - 1
                        If str2.Substring(j, 1) <> str1.Substring(j, 1) Then
                            rtbTarget.Select(j + ct2, 1)
                            rtbTarget.SelectionColor = Color.Red
                            rtbCorrect.Select(j + ct1, 1)
                            rtbCorrect.SelectionColor = Color.Blue
                        End If
                    Next
                End If
            End If
        Next
        Return i
    End Function