--> 测试数据：[tb]

if object_id('[tb]') is not null drop table [tb]

go 

create table [tb]([id] varchar(1),[name] varchar(4))

insert [tb]

select 'a','1001' union all

select 'a','1002' union all

select 'b','1001' union all

select 'b','errs'

--------------开始查询--------------------------



select id, name =stuff((select '-'+name from tb where id=a.id for xml path('')),1,1,'')

from [tb] a

group by id

----------------结果----------------------------

/* 

id   name

---- -------------

a    1001-1002

b    1001-errs

*/

/****************************************************************************************************************************************************** 

合并分拆表数据 



整理人：中国风(Roy) 



日期:2008.06.06 

******************************************************************************************************************************************************/ 



--> --> (Roy)生成測試數據 



if not object_id('Tab') is null 

    drop table Tab 

Go 

Create table Tab([Col1] int,[Col2] nvarchar(1)) 

Insert Tab 

select 1,N'a' union all 

select 1,N'b' union all 

select 1,N'c' union all 

select 2,N'd' union all 

select 2,N'e' union all 

select 3,N'f' 

Go 



合并表: 



SQL2000用函数: 



go 

if object_id('F_Str') is not null 

    drop function F_Str 

go 

create function F_Str(@Col1 int) 

returns nvarchar(100) 

as 

begin 

    declare @S nvarchar(100) 

    select @S=isnull(@S+',','')+Col2 from Tab where Col1=@Col1 

    return @S 

end 

go 

Select distinct Col1,Col2=dbo.F_Str(Col1) from Tab 



go 



SQL2005用XML: 



方法1: 



select 

    a.Col1,Col2=stuff(b.Col2.value('/R[1]','nvarchar(max)'),1,1,'') 

from 

    (select distinct COl1 from Tab) a 

Cross apply 

    (select COl2=(select N','+Col2 from Tab where Col1=a.COl1 For XML PATH(''), ROOT('R'), TYPE))b 



方法2: 



select 

    a.Col1,COl2=replace(b.Col2.value('/Tab[1]','nvarchar(max)'),char(44)+char(32),char(44)) 

from 

    (select distinct COl1 from Tab) a 

cross apply 

    (select Col2=(select COl2 from Tab  where COl1=a.COl1 FOR XML AUTO, TYPE) 

                .query(' <Tab> 

                {for $i in /Tab[position() <last()]/@COl2 return concat(string($i),",")} 

                {concat("",string(/Tab[last()]/@COl2))} 

                </Tab>') 

                )b 



SQL05用CTE: 



;with roy as(select Col1,Col2,row=row_number()over(partition by COl1 order by COl1) from Tab) 

,Roy2 as 

(select COl1,cast(COl2 as nvarchar(100))COl2,row from Roy where row=1 

union all 

select a.Col1,cast(b.COl2+','+a.COl2 as nvarchar(100)),a.row from Roy a join Roy2 b on a.COl1=b.COl1 and a.row=b.row+1) 

select Col1,Col2 from Roy2 a where row=(select max(row) from roy where Col1=a.COl1) order by Col1 option (MAXRECURSION 0) 





生成结果: 

/* 

Col1        COl2 

----------- ------------ 

1          a,b,c 

2          d,e 

3          f 



(3 行受影响) 

*/ 





--参考

拆分表:



--> --> (Roy)生成測試數據

 

if not object_id('Tab') is null

    drop table Tab

Go

Create table Tab([Col1] int,[COl2] nvarchar(5))

Insert Tab

select 1,N'a,b,c' union all

select 2,N'd,e' union all

select 3,N'f'

Go



--SQL2000用辅助表:

if object_id('Tempdb..#Num') is not null

    drop table #Num

go

select top 100 ID=Identity(int,1,1) into #Num from syscolumns a,syscolumns b

Select 

    a.Col1,COl2=substring(a.Col2,b.ID,charindex(',',a.Col2+',',b.ID)-b.ID) 

from 

    Tab a,#Num b

where

    charindex(',',','+a.Col2,b.ID)=b.ID --也可用 substring(','+a.COl2,b.ID,1)=','

--2000不使用辅助表

Select

    a.Col1,COl2=substring(a.Col2,b.number,charindex(',',a.Col2+',',b.number)-b.number) 

from 

    Tab a join master..spt_values  b 

    ON B.type='p' AND B.number BETWEEN 1 AND LEN(A.col2)

where

     substring(','+a.COl2,b.number,1)=','





SQL2005用Xml:



select 

    a.COl1,b.Col2

from 

    (select Col1,COl2=convert(xml,'<root><v>'+replace(COl2,',','</v><v>')+'</v></root>') from Tab)a

outer apply

    (select Col2=C.v.value('.','nvarchar(100)') from a.COl2.nodes('/root/v')C(v))b









SQL05用CTE:



;with roy as 

(select Col1,COl2=cast(left(Col2,charindex(',',Col2+',')-1) as nvarchar(100)),Split=cast(stuff(COl2+',',1,charindex(',',Col2+','),'') as nvarchar(100)) from Tab

union all

select Col1,COl2=cast(left(Split,charindex(',',Split)-1) as nvarchar(100)),Split= cast(stuff(Split,1,charindex(',',Split),'') as nvarchar(100)) from Roy where split>''

)

select COl1,COl2 from roy order by COl1 option (MAXRECURSION 0)



生成结果:

/*

Col1        COl2

----------- -----

1           a

1           b

1           c

2           d

2           e

3           f

*/

/*

标题：按某字段合并字符串之一(简单合并)

作者：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)

时间：2008-11-06

地点：广东深圳



描述：将如下形式的数据按id字段合并value字段。

id    value

----- ------

1     aa

1     bb

2     aaa

2     bbb

2     ccc

需要得到结果：

id     value

------ -----------

1      aa,bb

2      aaa,bbb,ccc

即：group by id, 求 value 的和（字符串相加）

*/

--1、sql2000中只能用自定义的函数解决

create table tb(id int, value varchar(10))

insert into tb values(1, 'aa')

insert into tb values(1, 'bb')

insert into tb values(2, 'aaa')

insert into tb values(2, 'bbb')

insert into tb values(2, 'ccc')

go



create function dbo.f_str(@id varchar(10)) returns varchar(1000)

as

begin

  declare @str varchar(1000)

  select @str = isnull(@str + ',' , '') + cast(value as varchar) from tb where id = @id

  return @str

end

go



--调用函数

select id , value = dbo.f_str(id) from tb group by id



drop function dbo.f_str

drop table tb





--2、sql2005中的方法

create table tb(id int, value varchar(10))

insert into tb values(1, 'aa')

insert into tb values(1, 'bb')

insert into tb values(2, 'aaa')

insert into tb values(2, 'bbb')

insert into tb values(2, 'ccc')

go



select id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')

from tb

group by id



drop table tb





--3、使用游标合并数据

create table tb(id int, value varchar(10))

insert into tb values(1, 'aa')

insert into tb values(1, 'bb')

insert into tb values(2, 'aaa')

insert into tb values(2, 'bbb')

insert into tb values(2, 'ccc')

go

declare @t table(id int,value varchar(100))--定义结果集表变量

--定义游标并进行合并处理

declare my_cursor cursor local for

select id , value from tb

declare @id_old int , @id int , @value varchar(10) , @s varchar(100)

open my_cursor

fetch my_cursor into @id , @value

select @id_old = @id , @s=''

while @@FETCH_STATUS = 0

begin

    if @id = @id_old

       select @s = @s + ',' + cast(@value as varchar)

    else

      begin

        insert @t values(@id_old , stuff(@s,1,1,''))

        select @s = ',' + cast(@value as varchar) , @id_old = @id

      end

    fetch my_cursor into @id , @value

END

insert @t values(@id_old , stuff(@s,1,1,''))

close my_cursor

deallocate my_cursor



select * from @t

drop table tb

create table tb(c1 varchar(10), c2 varchar(10))

insert into tb values('a', '1001')

insert into tb values('a', '1002')

insert into tb values('b', '1001')

insert into tb values('b', 'errs')

go



select c1 , c2 = (min(c2) + '-' + max(c2)) from tb group by c1



drop table tb



/*

c1         c2                    

---------- --------------------- 

a          1001-1002

b          1001-errs



（所影响的行数为 2 行）

*/

create table tb(c1 varchar(10), c2 varchar(10))

insert into tb values('a', '1001')

insert into tb values('a', '1002')

insert into tb values('b', '1001')

insert into tb values('b', 'errs')

go



create function dbo.f_str(@c1 varchar(10)) returns varchar(1000)

as

begin

  declare @str varchar(1000)

  select @str = isnull(@str + '-' , '') + cast(c2 as varchar) from tb where c1 = @c1

  return @str

end

go



--调用函数

select c1 , c2 = dbo.f_str(c1) from tb group by c1



drop function dbo.f_str

drop table tb



/*

c1         c2       

---------- ---------

a          1001-1002

b          1001-errs



（所影响的行数为 2 行）

*/

create table tb(c1 varchar(10), c2 varchar(10))

insert into tb values('a', '1001')

insert into tb values('a', '1002')

insert into tb values('b', '1001')

insert into tb values('b', 'errs')

go



select c1, c2 = stuff((select '-' + c2 from tb t where c1 = tb.c1 for xml path('')) , 1 , 1 , '')

from tb

group by c1



drop table tb



/*

c1         c2

---------- ----------

a          1001-1002

b          1001-errs



(2 行受影响)



*/