有這樣的sql語句嗎?

[gopark]

用一句從兩個表中抓出兩個recordset,並返回.也就是把兩個select用一句返回.

[jsidiot]

两个表有关联才可以那

[xyzoem]

可以用union执行并操作,不过这也只能返回一个recordset

[gopark]

沒有人會嗎?

[N_chow]

可以實現的。
假如你的前端程式是用ADO連的話，可以把兩句Select語句擺在一起，它就會返回兩個Recordset.
例:
Dim rs As New ADODB.Recordset
Dim tmp As New ADODB.Recordset

Dim Conn as New Adodb.Connection
Conn.CursorLocation = adUseClient
Conn.Open "Provider=SQLOLEDB;UID=sa;PWD=;Initial Catalog=Var2000;Data Source=NIPSAN"

rs.Open "Select * From tblStock; Select * From tblStockSub", Conn, adOpenStatic, adLockBatchOptimistic
Set tmp = rs.NextRecordset

MsgBox rs.RecordCount
MsgBox tmp.RecordCount
Set Conn = Nothing

[panther_totem]

学习

[gopark]

Thanks!

[knightzhou]

该范例使用 NextRecordset 方法，查看使用了由三个独立 SELECT 语句组成的复合命令语句的记录集中的数据。

Public Sub NextRecordsetX()

Dim rstCompound As ADODB.Recordset
Dim strCnn As String
Dim intCount As Integer

' 打开复合记录集。
strCnn = "Provider=sqloledb;" & _
"Data Source=srv;Initial Catalog=pubs;User Id=sa;Password=; "

Set rstCompound = New ADODB.Recordset
rstCompound.Open "SELECT * FROM authors; " & _
"SELECT * FROM stores; " & _
"SELECT * FROM jobs", strCnn, , , adCmdText

' 显示每一个 SELECT 语句的结果。
intCount = 1
Do Until rstCompound Is Nothing
Debug.Print "Contents of recordset #" & intCount
Do While Not rstCompound.EOF
Debug.Print , rstCompound.Fields(0), _
rstCompound.Fields(1)
rstCompound.MoveNext
Loop

Set rstCompound = rstCompound.NextRecordset
intCount = intCount + 1
Loop

End Sub