VBscript 批量合并PPT

[噢噢噢噢]

下面的代码怎么使用呃 ？

Option Explicit
Public FileNames As Variant
Public SaveName As Variant
Public pptApp As Object

Sub GetFiles()
    FileNames = Application.GetOpenFilename _
    (FileFilter:="演示文稿(*.ppt),*.ppt", FilterIndex:=1, _
    MultiSelect:=True, Title:="打开需要合并的文件")
End Sub

Sub SaveFileAs()
    SaveName = Application.GetSaveAsFilename(InitialFileName:="文稿合并结果", _
    FileFilter:="演示文稿(*.ppt),*.ppt", FilterIndex:=1, _
    Title:="保存文稿合并结果")
End Sub
Sub Merge()
    Dim Pre As Object
    Dim i As Double
    Dim n As Double
    Err.Clear
    On Error Resume Next
    Set pptApp = CreateObject("PowerPoint.application")
    pptApp.DisplayAlerts = False
    On Error GoTo 0
    If Err.Number <> 0 Then
        Beep
        MsgBox "出错，系统没有安装 MS PowerPoint", vbOKOnly, "合并演示文稿"
        pptApp.Quit
        Application.Quit
    End If
    Err.Clear
    On Error Resume Next
    
    Set Pre = pptApp.Presentations.Add
    For i = LBound(FileNames) To UBound(FileNames)
        DoEvents
        n = Pre.Slides.Count
        Pre.Slides.InsertFromFile Index:=n, FileName:=FileNames(i)
        UserForm1.Label.Caption = "正在合并演示文稿…" & i & "个已完成！"
    Next
    On Error GoTo 0
    If Err.Number <> 0 Then
        Beep
        MsgBox "出现未知错误！退出？", vbOKOnly, "合并演示文稿"
        pptApp.Quit
        Application.Quit
    End If
    Pre.SaveAs (SaveName)
    pptApp.DisplayAlerts = True
    pptApp.Quit
    UserForm1.Label.Caption = "演示文稿合并完成！"
    UserForm1.cmdQuit.Caption = "确定(Q)"
    
End Sub

[Microogle]

貌似VBA而不是VBSCRIPT，添加为宏并执行吧。

[Q2565093493]

Set pptApp = CreateObject("PowerPoint.application")
看起来像vb代码 加入ppt引用构建vb试试！！

[wygai]

是Excel VBA 。
1、将以上代码加入模块1
2、添加用户窗体UserForm1，在窗体上放置四个按钮，一个标签
3、编辑代码

'窗体UserForm1部分代码如下：
Private Sub CommandButton1_Click()
GetFiles
End Sub

Private Sub CommandButton2_Click()
SaveFileAs
End Sub

Private Sub CommandButton3_Click()
Merge
End Sub

Private Sub CommandButton4_Click()
Unload UserForm1
Application.Workbooks.Close
Application.Quit
End
End Sub

Private Sub UserForm_Initialize()
CommandButton1.Caption = "1、选择要合并的PPT文件"
CommandButton2.Caption = "2、将目标文件保存为..."
CommandButton3.Caption = "3、开始合并"
CommandButton4.Caption = "退出"
End Sub

'为WorkBook添加如下代码
Private Sub Workbook_Open()
UserForm1.Show
Application.WindowState = xlMinimized
End Sub