发个封装好的类,提高bitmap.GetPixel和bitmap.SetPixel速度

2012-07-13 10:23:17 1.1k 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

C#实现图片隐写术：将文件隐藏于图像像素中的完整指南隐写术是一种将信息隐藏于其他载体中的信息安全技术，其核心原理是利用载体数据的冗余或不易察觉的部分嵌入秘密信息。在数字图像处理领域，最低有效位（LSB）隐写是常用方法，通过修改像素颜色通道的最低有效位来嵌入数据，对人眼视觉影响极小。这项技术的工程价值在于实现数据的隐蔽传输与存储，常应用于数字水印、隐蔽通信和信息安全教学等场景。本文以C#编程实践为例，详细讲解如何利用System.Drawing进行文件流操作和像素处理，实现将任意文件隐藏至PNG或JPG图片中，并完整解析编码与解码的核心逻辑，涵盖字节流转换、容阅读详情

我写的这个类很简单,只封装了两个常用方法,根据实际需求,可自行改造它!

Imports System.Drawing.Imaging



Public Class FastBitmap



    Private bmpData As BitmapData

    Private ptr As IntPtr = IntPtr.Zero

    Private rgbValues() As Byte = Nothing

    Private bytes As Integer

    Private mWidth As Integer

    Private id As Integer



    ''' <summary>

    ''' 

    ''' </summary>

    ''' <param name="image">设置读写的图片对象</param>

    ''' <remarks></remarks>

    Public Sub New(ByVal image As Bitmap)

        MyClass.Image = image

    End Sub



    Public Sub New()

        '

    End Sub



    ''' <summary>

    ''' 开始读写操作

    ''' </summary>

    ''' <remarks></remarks>

    Public Sub BeginReadWrite()

        If Image Is Nothing Then Throw New Exception("调用BeginReadWrite方法,前必须先设置Image属性!")

        Dim rect As New Rectangle(0, 0, Image.Width, Image.Height)

        bmpData = Image.LockBits(rect, ImageLockMode.ReadWrite, Image.PixelFormat)

        ptr = bmpData.Scan0

        bytes = Math.Abs(bmpData.Stride) * Image.Height

        ReDim rgbValues(bytes - 1)

        System.Runtime.InteropServices.Marshal.Copy(ptr, rgbValues, 0, bytes)

        mWidth = Image.Width

    End Sub



    ''' <summary>

    ''' 获取指定位置的点颜色

    ''' </summary>

    ''' <param name="x"></param>

    ''' <param name="y"></param>

    ''' <returns></returns>

    ''' <remarks></remarks>

    Public Function GetPixel(ByVal x As Integer, ByVal y As Integer) As Color

        If ptr = IntPtr.Zero Then Throw New Exception("读写操作前必须先调用BeginReadWrite方法!")

        id = mWidth * 4 * y + x * 4 '每个点在这变成4个字节(按顺序代表b\g\r\a)

        Return Color.FromArgb(rgbValues(id + 3), _

                              rgbValues(id + 2), _

                              rgbValues(id + 1), _

                              rgbValues(id))

    End Function



    ''' <summary>

    ''' 设置指定位置的点颜色

    ''' </summary>

    ''' <param name="x"></param>

    ''' <param name="y"></param>

    ''' <param name="color"></param>

    ''' <remarks></remarks>

    Public Sub SetPixel(ByVal x As Integer, ByVal y As Integer, ByVal color As Color)

        If ptr = IntPtr.Zero Then Throw New Exception("读写操作前必须先调用BeginReadWrite方法!")

        id = mWidth * 4 * y + x * 4

        rgbValues(id) = color.B

        rgbValues(id + 1) = color.G

        rgbValues(id + 2) = color.R

        rgbValues(id + 3) = color.A

    End Sub



    ''' <summary>

    ''' 结束读取操作

    ''' </summary>

    ''' <remarks></remarks>

    Public Sub EndReadWrite()

        If ptr = IntPtr.Zero Then Return

        System.Runtime.InteropServices.Marshal.Copy(rgbValues, 0, ptr, bytes)

        Image.UnlockBits(bmpData)

        ptr = IntPtr.Zero

        rgbValues = Nothing

    End Sub



    ''' <summary>

    ''' 获取或设置读写的图片对象

    ''' </summary>

    ''' <value></value>

    ''' <returns></returns>

    ''' <remarks></remarks>

    Public Property Image As Bitmap = Nothing



End Class