求通用分页存储过程

[暗尘掩月]

要求支持distinct，group by,max,sum等等聚合函数
支持如下形式

/*SortTree，SortChild表中并不存在*/
select NavID,NavName,ParentID,Sort,SortTree = case when ParentID=0 then NavID else ParentID end ,SortChild=ParentID+Sort  from  Navigation order by SortTree,SortChild,ParentID

[暗尘掩月]

ALTER proc [dbo].[uspGetPage]
(
 @Tables nvarchar(1000),  --表名
 @Fields nvarchar(2000)='*', --字段
 @PageIndex int=1, --第N页
 @PageSize int=10, --每页的大小
 @Where nvarchar(4000)='', --条件
 @OrderBy nvarchar(200),  --排序
 @TotalRecord int = 0 output --符合条件记录数量
 )
AS
BEGIN

Declare @SQL nvarchar(max)

-- @Where 处理
SELECT @Where=(CASE WHEN (@Where IS NULL OR @Where='') THEN '' ELSE ' Where '+@Where END)

--计算总记录数
set @SQL = 'select @Total = count(1) from ' + @Tables + @Where
EXEC sp_executesql @SQL,N'@Total int OUTPUT',@TotalRecord OUTPUT


 --计算边界
 SELECT @PageIndex=(CASE WHEN @PageIndex<1 THEN 1 ELSE @PageIndex-1 END)

 --下面构造分页函数

 SELECT @SQL='SELECT row_number() OVER (ORDER BY '+@ORDERBY+') AS _rowid, '+ @Fields + ' FROM ' + @Tables + @Where

 --执行分页
 Declare @EXECSQL varchar(max)
 SELECT @EXECSQL='SET ROWCOUNT '+Convert(varchar(4),@PageSize)+'; WITH SP_TABLE AS( '+@SQL+' ) SELECT * FROM SP_TABLE WHERE _rowid > '+ Convert(varchar(50),(@PageIndex * @PageSize))+' '
 
EXEC(@EXECSQL)

--PRINT @EXECSQL
--返回页数

END

或者帮我把这个改改

[--小F--]

set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
go





ALTER PROC [dbo].[PROCE_PageView2000]
(
@tbname     nvarchar(100),               --要分页显示的表名
@FieldKey   nvarchar(1000),      --用于定位记录的主键(惟一键)字段,可以是逗号分隔的多个字段
@PageCurrent int=1,               --要显示的页码
@PageSize   int=10,                --每页的大小(记录数)
@FieldShow nvarchar(1000)='',      --以逗号分隔的要显示的字段列表,如果不指定,则显示所有字段
@FieldOrder nvarchar(1000)='',      --以逗号分隔的排序字段列表,可以指定在字段后面指定DESC/ASC
@WhereString    nvarchar(1000)=N'',     --查询条件
@RecordCount int OUTPUT             --总记录数
)
AS
SET NOCOUNT ON
--检查对象是否有效
--IF OBJECT_ID(@tbname) IS NULL
--BEGIN
--    RAISERROR(N'对象"%s"不存在',1,16,@tbname)
--    RETURN
--END
--IF OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTable')=0
--    AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsView')=0
--    AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTableFunction')=0
--BEGIN
--    RAISERROR(N'"%s"不是表、视图或者表值函数',1,16,@tbname)
--    RETURN
--END

--分页字段检查
IF ISNULL(@FieldKey,N'')=''
BEGIN
    RAISERROR(N'分页处理需要主键（或者惟一键）',1,16)
    RETURN
END

--其他参数检查及规范
IF ISNULL(@PageCurrent,0)<1 SET @PageCurrent=1
IF ISNULL(@PageSize,0)<1 SET @PageSize=10
IF ISNULL(@FieldShow,N'')=N'' SET @FieldShow=N'*'
IF ISNULL(@FieldOrder,N'')=N''
    SET @FieldOrder=N''
ELSE
    SET @FieldOrder=N'ORDER BY '+LTRIM(@FieldOrder)
IF ISNULL(@WhereString,N'')=N''
    SET @WhereString=N''
ELSE
    SET @WhereString=N'WHERE ('+@WhereString+N')'

--如果@RecordCount为NULL值,则计算总页数(这样设计可以只在第一次计算总页数,以后调用时,把总页数传回给存储过程,避免再次计算总页数,对于不想计算总页数的处理而言,可以给@RecordCount赋值)
IF @RecordCount IS NULL
BEGIN
    DECLARE @sql nvarchar(4000)
    SET @sql=N'SELECT @RecordCount=COUNT(*)'
        +N' FROM '+@tbname
        +N' '+@WhereString
    EXEC sp_executesql @sql,N'@RecordCount int OUTPUT',@RecordCount OUTPUT
END

--计算分页显示的TOPN值
DECLARE @TopN varchar(20),@TopN1 varchar(20)
SELECT @TopN=@PageSize,
    @TopN1=(@PageCurrent-1)*@PageSize

--第一页直接显示
IF @PageCurrent=1
    EXEC(N'SELECT TOP '+@TopN
        +N' '+@FieldShow
        +N' FROM '+@tbname
        +N' '+@WhereString
        +N' '+@FieldOrder)
ELSE
BEGIN
    --处理别名
    IF @FieldShow=N'*'
        SET @FieldShow=N'a.*'

    --生成主键(惟一键)处理条件
    DECLARE @Where1 nvarchar(4000),@Where2 nvarchar(4000),
        @s nvarchar(1000),@Field sysname
    SELECT @Where1=N'',@Where2=N'',@s=@FieldKey
    WHILE CHARINDEX(N',',@s)>0
        SELECT @Field=LEFT(@s,CHARINDEX(N',',@s)-1),
            @s=STUFF(@s,1,CHARINDEX(N',',@s),N''),
            @Where1=@Where1+N' AND a.'+@Field+N'=b.'+@Field,
            @Where2=@Where2+N' AND b.'+@Field+N' IS NULL',
            @WhereString=REPLACE(@WhereString,@Field,N'a.'+@Field),
            @FieldOrder=REPLACE(@FieldOrder,@Field,N'a.'+@Field),
            @FieldShow=REPLACE(@FieldShow,@Field,N'a.'+@Field)
    SELECT @WhereString=REPLACE(@WhereString,@s,N'a.'+@s),
        @FieldOrder=REPLACE(@FieldOrder,@s,N'a.'+@s),
        @FieldShow=REPLACE(@FieldShow,@s,N'a.'+@s),
        @Where1=STUFF(@Where1+N' AND a.'+@s+N'=b.'+@s,1,5,N''),    
        @Where2=CASE
            WHEN @WhereString='' THEN N'WHERE ('
            ELSE @WhereString+N' AND ('
            END+N'b.'+@s+N' IS NULL'+@Where2+N')'

    --执行查询
    EXEC(N'SELECT TOP '+@TopN
        +N' '+@FieldShow
        +N' FROM '+@tbname
        +N' a LEFT JOIN(SELECT TOP '+@TopN1
        +N' '+@FieldKey
        +N' FROM '+@tbname
        +N' a '+@WhereString
        +N' '+@FieldOrder
        +N')b ON '+@Where1
        +N' '+@Where2
        +N' '+@FieldOrder)
END






 


MSSQL2005

set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
go






ALTER PROCEDURE [dbo].[PROCE_SQL2005PAGECHANGE]
(
 @TableName varchar(50),            --表名
 @ReFieldsStr varchar(200) = '*',   --字段名(全部字段为*)
 @OrderString varchar(200),         --排序字段(必须!支持多字段不用加order by)
 @WhereString varchar(500) =N'',  --条件语句(不用加where)
 @PageSize int,                     --每页多少条记录
 @PageIndex int = 1 ,               --指定当前为第几页
 @TotalRecord int output            --返回总记录数
)
AS
 
BEGIN    

    --处理开始点和结束点
    Declare @StartRecord int;
    Declare @EndRecord int; 
    Declare @TotalCountSql nvarchar(500); 
    Declare @SqlString nvarchar(2000);    
    set @StartRecord = (@PageIndex-1)*@PageSize + 1
    set @EndRecord = @StartRecord + @PageSize - 1 
    SET @TotalCountSql= N'select @TotalRecord = count(*) from ' + @TableName;--总记录数语句
    SET @SqlString = N'(select row_number() over (order by '+ @OrderString +') as rowId,'+@ReFieldsStr+' from '+ @TableName;--查询语句
    --
    IF (@WhereString! = '' or @WhereString!=null)
        BEGIN
            SET @TotalCountSql=@TotalCountSql + '  where '+ @WhereString;
            SET @SqlString =@SqlString+ '  where '+ @WhereString;            
        END
    --第一次执行得到
    --IF(@TotalRecord is null)
    --   BEGIN
           EXEC sp_executesql @totalCountSql,N'@TotalRecord int out',@TotalRecord output;--返回总记录数
    --  END
    ----执行主语句
    set @SqlString ='select * from ' + @SqlString + ') as t where rowId between ' + ltrim(str(@StartRecord)) + ' and ' +  ltrim(str(@EndRecord));
    Exec(@SqlString)    
END

[暗尘掩月]

先去试一下

[筱筱澄]

CREATE PROCEDURE GetRecordPage
               @tblName         NVARCHAR(1000), 
               @SelectFieldName NVARCHAR(4000)  = '*',
               @strWhere        NVARCHAR(4000)  = NULL,
               @OrderField  NVARCHAR(255),
               @PageSize        INT  = 10,      
               @PageIndex       INT  = 1,   
               @iRowCount       INT  OUTPUT
AS
  DECLARE  @strFilter NVARCHAR(2000)
  DECLARE  @sql NVARCHAR(4000)
  
--  SET @SelectFieldName = Replace(@SelectFieldName,'''','')  
--  SET @tblName = Replace(@tblName,'''','')   
--  SET @strWhere = Replace(@strWhere,'''','''''')    
 

  IF @strWhere IS NOT NULL
     AND @strWhere != ''
    BEGIN
      SET @strFilter = ' WHERE ' + @strWhere + ' '
    END
  ELSE
    BEGIN
      SET @strFilter = ''
    END
  
  SET @sql = 'SELECT  @iRowCount=Count(*) FROM ' + @tblName + @strFilter
  
  EXEC Sp_executesql
    @sql ,
    N'@iRowCount int out' ,
    @iRowCount OUT
  
  IF @PageIndex < 1
    SET @PageIndex = 1
  
  IF @PageIndex = 1 
    BEGIN
      SET @sql = 'select top ' + Str(@PageSize) + ' ' + @SelectFieldName + ' from ' + @tblName + ' ' + @strFilter + ' ORDER BY ' + @OrderField
    END
  ELSE
    BEGIN
      DECLARE  @START_ID VARCHAR(50)
      
      DECLARE  @END_ID VARCHAR(50)
      
      SET @START_ID = Convert(VARCHAR(50),(@PageIndex - 1) * @PageSize + 1)
      
      SET @END_ID = Convert(VARCHAR(50),@PageIndex * @PageSize)
      
      SET @sql = ' SELECT * FROM (SELECT ROW_NUMBER() OVER(ORDER BY ' + @OrderField + ') AS rownum, ' + @SelectFieldName + ' FROM ' + @tblName + ' ' +@strFilter + ') AS D WHERE rownum BETWEEN ' + @START_ID + ' AND ' + @END_ID
    END
  
  --PRINT @sql
  
  EXEC( @sql)

[暗尘掩月]

有错误 根本无法执行啊 注释是不是弄错了

[筱筱澄]

row_number写通用的是很方便的
我的那个 @tblName 你可以传一个语句块进去。

[暗尘掩月]

我在测试是不是支持distinct 等等有些聚合函数

[暗尘掩月]

不支持group by啊

[暗尘掩月]

发现分页存储过程始终有些sql语句无法支持 要不不支持 left join ,inner join 要么不支持外延字段，要么不支持聚合函数，要么不支持group by