请问，回滚事务

[ds32vf33]

书上说的，ROLLBACK只能在一个事务处理内使用，也就是在执行一条BEGIN TRANSACTION命令之后
那请问，ROLLBACK TRANSACTION呢？是不是也必须出现在执行一条BEGIN TRANSACTION命令之后，如果不是，那又回滚到何处？

[问苍天人生几何]

引用自：http://www.cnblogs.com/fgynew/archive/2011/12/16/2290525.html


Commit transaction 会提交所有嵌套的transaction修改。但是如果嵌套的transaction里面有rollback tran to save point, 那么save point之后的部分会revert掉。

delete from dbo.numbertable

begin tran out1

insert into dbo.numbertable values(1)

insert into dbo.numbertable values(2)



begin tran inn1

insert into dbo.numbertable values(3)

insert into dbo.numbertable values(4)

save tran inn1SavePoint

insert into dbo.numbertable values(5)

rollback tran inn1SavePoint

commit tran inn1

commit tran out1



· @@TRANCOUNT可以用来记录当前session transaction的个数，对于嵌套的transaction来讲，每次begin transaction都让它加一，每次commit tran都会让它减一。所以在语句里面可以通过select @@TRANCOUNT 来检查当前是否在一个transaction里面。如果当前@@TRANCOUNT为0，那调用commit还是rollback都会出现语句错误。在嵌套的transaction里面，rollback是很特殊的，它会直接把@@TRANCOUNT设置为0。

begin tran

begin tran

begin tran

print @@trancount

rollback tran

print @@trancount



· 对于嵌套的transaction来讲，rollback的写法是很特殊。如果嵌套，rollback transaction后面是不能带transaction的name的，要带也只能是最外面的transaction的name。Rollback只会抛弃所有嵌套transaction在rollback语句之前的修改。Rollback之后的更新依然提交就去了，原因在于：rollback之后，@@trancount为0，那么rollback之后的语句就不属于explicit transaction, 属于autocmmit transaction了，自动提交。

delete from dbo.numbertable

begin tran t1

insert into dbo.numbertable values(1)



begin tran t2

insert into dbo.numbertable values(2)

rollback tran

print 'after rollback in innert transaction, the transaction count is: '+cast(@@trancount, varchar(5))

insert into dbo.numbertable values(3)

--commit tran

select * from dbo.numbertable



· 存储过程里面也可以begin transaction，如果调用的地方也begin transaction,那么这种情况也属于嵌套transaction，如果在存储过程里面rollback，得到的结果和上面一样。但是有一点特殊的地方在与，执行存储过程结束的时候会比较开始执行sp的@@trancount和结束时候@@trancount的值，如果不一样，它会给出一个消息像“Transaction count after EXECUTE indicates that a COMMIT or ROLLBACK TRANSACTION statement is missing. Previous count = 1, current count = 0.”这个给出的消息并不会影响其后的执行。

CREATE PROCEDURE [dbo].[AddNumber]

AS

BEGIN

begin tran

insert into dbo.numbertable values(1)

insert into dbo.numbertable values(2)

insert into dbo.numbertable values(3)

rollback tran

END

delete from dbo.numbertable

begin tran out1

exec dbo.addnumber

print @@trancount

insert into dbo.numbertable values(3)

select * from dbo.numbertable



· 如果在sp里面rollback了，那到外满做commit， 或者rollback都是没有效果并且出错了，因为嵌套的transaction内部transaction一旦调用了rollback，@@trancount就为0了，在外满commit，rollback直接出错。比如如下sp，我想像在最外面rollback，那就出错了，因为sp里面语句rollback了。表里面始终会插入值3。

delete from dbo.numbertable

begin tran out1

exec dbo.addnumber

print @@trancount

insert into dbo.numbertable values(3)

rollback tran out1

select * from dbo.numbertable



· 所有对于嵌套的transaction来讲，如果内部transaction一旦rollback，就会给外部的transaction留下一个大坑。为了解决这个为题，有两种解决方案：

1. 在外部的transaction里面检查@@trancount，如果这个值跟你代码begin tran的可以一致，那说明内部transaction没有rollback，那可以继续commit或者rollback。

delete from dbo.numbertable

begin tran t1

insert into dbo.numbertable values(1)



begin transaction t2

insert into dbo.numbertable values(2)

rollback tran



if @@trancount = 1

begin

insert into dbo.numbertable values(3)

commit tran

end

2. 在所有的内部transaction里面，只能commit，不能rollback。如果必须rollback，那怎么办？save point就可以派上用场了。比如sp改成这样子：

ALTER PROCEDURE [dbo].[AddNumber]

AS

BEGIN

begin tran

save tran pp

insert into dbo.numbertable values(1)

insert into dbo.numbertable values(2)

insert into dbo.numbertable values(3)

rollback tran pp

commit tran

END



begin tran out1

exec dbo.addnumber

print @@trancount

insert into dbo.numbertable values(3)

commit tran out1

[人生无悔]

ROLLBACK和ROLLBACK TRANSACTION呢？
这两个同一个意思，只是简略的写法而已

如果是存储过程中，rollback tran必须显示声明begin tran
如果是在触发器中，不需显式声明，本身就会开启一个事务，可以直接rollback tran

[筱筱澄]

ROLLBACK
ROLLBACK TRAN
ROLLBACK TRANSACTION
这三个都一样，写法不同而已

[叶子]

参考微软官方示例：

USE tempdb;
GO
CREATE TABLE ValueTable ([value] int;)
GO

DECLARE @TransactionName varchar(20) = 'Transaction1';

--The following statements start a named transaction,
--insert two rows, and then roll back
--the transaction named in the variable @TransactionName.
--Another statement outside of the named transaction inserts two rows.
--The query returns the results of the previous statements.

BEGIN TRAN @TransactionName
       INSERT INTO ValueTable VALUES(1), (2);
ROLLBACK TRAN @TransactionName;

INSERT INTO ValueTable VALUES(3),(4);

SELECT [value] FROM ValueTable;

DROP TABLE ValueTable;

--Results
--value
-------------
--3
--4

详见：
http://technet.microsoft.com/zh-cn/library/ms181299.aspx

[筱筱澄]

ROLLBACK TRAN清除自事务的起点或到某个保存点所做的所有数据修改。

可以回滚到 BEGIN TRAN 的位置可以回滚到 SAVE TRAN 位置

--test
create table tb(id int)
begin tran t1
insert into tb select 1
save tran t1
insert into tb select 2
rollback  tran t1

select * from  tb
/*
id
-----------
1

(1 行受影响)


*/

drop table tb

[筱筱澄]

我晕。。。。。。。。以为晚了没人，慢慢悠悠的回答，结果还有一群夜猫子啊

[ds32vf33]

[Quote=引用 2 楼 的回复:]

ROLLBACK和ROLLBACK TRANSACTION呢？
这两个同一个意思，只是简略的写法而已

如果是存储过程中，rollback tran必须显示声明begin tran
如果是在触发器中，不需显式声明，本身就会开启一个事务，可以直接rollback tran
[/Quote]
在触发器中，不需显式声明，本身就会开启一个事务，可以直接rollback tran

那请问，直接rollback tran，回滚到何处呢？如果有begin tran的话，就回滚到begin tran那里，没有
begin tran，又回滚到何处呢？

[问苍天人生几何]

Rollback会抛弃所有嵌套transaction在rollback语句之前的修改。rollback之后，@@trancount为0

如果没有begin tran,那看看@@trancount是否为0，一般来说没有begin tran的话,@@trancount是为0的，此时没有事务可回滚。

[筱筱澄]

[Quote=引用 7 楼 的回复:]

引用 2 楼 的回复:

ROLLBACK和ROLLBACK TRANSACTION呢？
这两个同一个意思，只是简略的写法而已

如果是存储过程中，rollback tran必须显示声明begin tran
如果是在触发器中，不需显式声明，本身就会开启一个事务，可以直接rollback tran

在触发器中，不需显式声明，本身就会开启一个事务，可以直接rollback tra……
[/Quote]
你也说了本身开启了一个事务，隐式的
所以不代表他没有事务
显式的指定回滚能够达到效果，回滚rollback前面的所以操作
但是这样会报错的，所以是不建议和允许在触发器中显式的指定事物。

[以学习为目的]

BEGIN TRANSACTION exampletrans  -- 开始一个事务
  USE 销售管理
GO
UPDATE 员工                         --执行一次更新操作
SET 基本工资=基本工资*1.1
   WHERE 部门号='40'
GO
SAVE TRANSACTION change

UPDATE 员工                          --第二次执行更新操作           
SET  基本工资=基本工资*1.1
   WHERE  职务='经理'
GO
ROLLBACK TRANSACTION change      --回滚到保存点
PRINT '程序继续执行!'
COMMIT TRANSACTION
/*
这个例子一共执行两次更新操作，第一次操作完成后，设置一个保存点；第二次更新操作执行之后，程序执行了事务回滚，使得第二次更新操作被取消，但是第一次操作依然有效，程序继续从回滚处执行，打印出一行字
注意：ROLLBACK   ROLLBACK TRAN   ROLLBACK TRANSACTION 三种写法作用一样 

*/