行转列数据合并问题

smilewmr 2013-08-27 02:50:18

原始表格内容：
XBBH ZBDJBH ONE TWO GUANCI
172753 HNT00010163 616 255 配比
172754 HNT00010163 643 278 第1罐
172755 HNT00010163 616 255 配比
172756 HNT00010163 604 292 第2罐
172757 HNT00010163 1247 570 累计值
172758 HNT00010163 1.22 11.76 总误差%

现需要表格内容：
ZBDJBH ONE配1 ONE1罐 ONE配2 ONE2罐 ONE累 ONE总误 TWO配1 TWO1罐 TWO配2 TWO2罐 TWO累 TWO总误
HNT00010163 616 643 616 604 1247 1.22 255 278 255 292 570 11.76

说明：
在原始表中，有多个列，从one到ten，举例只写出了两个列的内容。这个如何将多列转换为1行呢？望大侠们指点指点！
在此谢啦！

...全文

126 4 打赏收藏转发到动态举报

写回复

用AI写文章

4 条回复

切换为时间正序

请发表友善的回复…

发表回复

Shawn 2013-08-27

打赏
举报

if OBJECT_ID('tempdb..#temp', 'u') is not null   drop table #temp;
go
create table #temp( [XBBH] varchar(100), [ZBDJBH] varchar(100), [ONE] varchar(100), [TWO] varchar(100), [GUANCI] varchar(100));
insert #temp
select '172753','HNT00010163','616','255','配比' union all
select '172754','HNT00010163','643','278','第1罐' union all
select '172755','HNT00010163','616','255','配比' union all
select '172756','HNT00010163','604','292','第2罐' union all
select '172757','HNT00010163','1247','570','累计值' union all
select '172758','HNT00010163','1.22','11.76','总误差%' 

--SQL
DECLARE @sql NVARCHAR(MAX), @colList NVARCHAR(MAX)
SET @colList = STUFF((
SELECT ','+QUOTENAME(guanci+(CASE WHEN rowid > 1 THEN LTRIM(rowid) ELSE '' END))
FROM
(
	SELECT rowid = ROW_NUMBER() OVER(PARTITION BY zbdjbh, guanci ORDER BY GETDATE()), * FROM
	(
		select zbdjbh,one,guanci='one'+guanci from #temp
		UNION ALL
		select zbdjbh,two,guanci='two'+guanci from #temp
		--这儿把剩下8个补全
	)  x
) t
FOR XML PATH('')),1,1,'')

SET @sql = N'
	SELECT * FROM
	(
		SELECT zbdjbh,one,guanci=guanci+(CASE WHEN rowid > 1 THEN LTRIM(rowid) ELSE '''' END)
		FROM
		(
			SELECT rowid = ROW_NUMBER() OVER(PARTITION BY zbdjbh, guanci ORDER BY GETDATE()), * FROM
			(
				select zbdjbh,one,guanci=''one''+guanci from #temp
				UNION ALL
				select zbdjbh,two,guanci=''two''+guanci from #temp
				--这儿把剩下8个补全
			)  x
		) t
	) y
	PIVOT
	(
		MAX(one) FOR guanci IN('+ @colList +')
	) M
'
PRINT @sql
EXEC(@sql)
/*
zbdjbh	one第1罐	one第2罐	one累计值	one配比	one配比2	one总误差%	two第1罐	two第2罐	two累计值	two配比	two配比2	two总误差%
HNT00010163	643	604	1247	616	616	1.22	278	292	570	255	255	11.76
*/

Andy__Huang 2013-08-27

打赏
举报

create table #tb(XBBH int,ZBDJBH varchar(20),
	ONE numeric(12,2),TWO numeric(12,2),GUANCI varchar(10))
insert into #tb
select 172753,'HNT00010163',616,255,'配比'
union all select 172754,'HNT00010163',643,278,'第1罐'
union all select 172755,'HNT00010163',616,255,'配比'
union all select 172756,'HNT00010163',604,292,'第2罐'
union all select 172757,'HNT00010163',1247,570,'累计值'
union all select 172758,'HNT00010163',1.22,11.76,'总误差%'

declare @sql varchar(8000)
set @sql=''
select @sql=@sql + ',[ONE'+rtrim(GUANCI)+']=max(case GUANCI when '''+rtrim(GUANCI)+''' then ONE end)'
from #tb group by GUANCI
select @sql=@sql + ',[TWO'+rtrim(GUANCI)+']=max(case GUANCI when '''+rtrim(GUANCI)+''' then TWO end)'
from #tb group by GUANCI
exec('select ZBDJBH'+@sql+'from  #tb group by ZBDJBH' )

drop table #tb

/*
ZBDJBH	ONE第1罐	ONE第2罐	ONE累计值	ONE配比	ONE总误差%	TWO第1罐	TWO第2罐	TWO累计值	TWO配比	TWO总误差%
HNT00010163	643.00	604.00	1247.00	616.00	1.22	278.00	292.00	570.00	255.00	11.76
*/

开着拖拉机泡妞 2013-08-27

打赏
举报

--行列互转
--摘自中国风博客，引用请标明内容来源
--1、行换列
if object_id('Class') is not  null
    drop table Class
Go
Create table Class(
[Student] nvarchar(2),
[Course] nvarchar(2),
[Score] int)
Insert Class
select N'张三',N'语文',78 union all
select N'张三',N'数学',87 union all
select N'张三',N'英语',82 union all
select N'张三',N'物理',90 union all
select N'李四',N'语文',65 union all
select N'李四',N'数学',77 union all
select N'李四',N'英语',65 union all
select N'李四',N'物理',85 
Go

--2000方法:
--动态:
declare @s nvarchar(4000)
set @s=''
Select @s=@s+','+quotename([Course])+'=max(case when [Course]='    
   
    +quotename([Course],'''')+' then [Score] else 0 end)'
from 
    Class group by[Course]
--select @s
exec('select [Student]'+@s+' from Class group by [Student]')
--生成静态:
select 
    [Student],
    [数学]=max(case when [Course]='数学' then [Score] else 0 end),
    [物理]=max(case when [Course]='物理' then [Score] else 0 end),
    [英语]=max(case when [Course]='英语' then [Score] else 0 end),
    [语文]=max(case when [Course]='语文' then [Score] else 0 end) 
from 
    Class 
group by [Student]
GO
--动态:

declare @s nvarchar(4000)
Select @s=isnull(@s+',','')+quotename([Course]) from Class group by[Course]
select @s
exec('select * from Class pivot (max([Score]) for [Course] in('+@s+'))b')

--生成静态:
select * 
from 
    Class 
pivot 
    (max([Score]) for [Course] in([数学],[物理],[英语],[语文]))b

--生成格式:
/*
Student 数学         物理         英语         语文
------- ----------- ----------- ----------- -----------
李四     77          85          65          65
张三     87          90          82          78

(2 行受影响)
*/

go
--加上总成绩(学科平均分)

--2000方法:
--动态:

declare @s nvarchar(4000)
set @s=''
Select @s=@s+','+quotename([Course])+'=max(case when [Course]='+quotename([Course],'''')+'then [Score] else 0 end)'
from Class group by[Course]
exec('select [Student]'+@s+',[总成绩]=sum([Score])  from Class group by [Student]')--加多一列(学科平均分用avg([Score]))

生成动态:

select 
    [Student],
    [数学]=max(case when [Course]='数学' then [Score] else 0 end),
    [物理]=max(case when [Course]='物理' then [Score] else 0 end),
    [英语]=max(case when [Course]='英语' then [Score] else 0 end),
    [语文]=max(case when [Course]='语文' then [Score] else 0 end),
    [总成绩]=([Score]) --加多一列(学科平均分用avg([Score]))
from 
    Class 
group by [Student]

go

--2005方法:

动态:

declare @s nvarchar(4000)
Select  @s=isnull(@s+',','')+quotename([Course]) from Class group by[Course] 
--isnull(@s+',','') 去掉字符串@s中第一个逗号

exec('select [Student],'+@s+',[总成绩] from (select *,[总成绩]=sum([Score])over(partition by [Student]) from Class) a 
pivot (max([Score]) for [Course] in('+@s+'))b ')

--生成静态:

select 
    [Student],[数学],[物理],[英语],[语文],[总成绩] 
from 
    (select *,[总成绩]=sum([Score])over(partition by [Student]) from Class) a --平均分时用avg([Score])
pivot 
    (max([Score]) for [Course] in([数学],[物理],[英语],[语文]))b 

生成格式:

/*
Student 数学         物理         英语         语文         总成绩
------- ----------- ----------- ----------- ----------- -----------
李四     77          85          65          65          292
张三     87          90          82          78          337

(2 行受影响)
*/

go

--2、列转行
 
if not object_id('Class') is null
    drop table Class
Go
Create table Class([Student] nvarchar(2),[数学] int,[物理] int,[英语] int,[语文] int)
Insert Class
select N'李四',77,85,65,65 union all
select N'张三',87,90,82,78
Go

--2000:

动态:

declare @s nvarchar(4000)
select @s=isnull(@s+' union all ','')+'select [Student],[Course]='+quotename(Name,'''')--isnull(@s+' union all ','') 去掉字符串@s中第一个union all
+',[Score]='+quotename(Name)+' from Class'
from syscolumns where ID=object_id('Class') and Name not in('Student')--排除不转换的列
order by Colid
exec('select * from ('+@s+')t order by [Student],[Course]')--增加一个排序

生成静态:
select * 
from (select [Student],[Course]='数学',[Score]=[数学] from Class union all 
select [Student],[Course]='物理',[Score]=[物理] from Class union all 
select [Student],[Course]='英语',[Score]=[英语] from Class union all 
select [Student],[Course]='语文',[Score]=[语文] from Class)t 
order by [Student],[Course]

go
--2005:

动态:

declare @s nvarchar(4000)
select @s=isnull(@s+',','')+quotename(Name)
from syscolumns where ID=object_id('Class') and Name not in('Student') 
order by Colid
exec('select Student,[Course],[Score] from Class unpivot ([Score] for [Course] in('+@s+'))b')

go
select 
    Student,[Course],[Score] 
from 
    Class 
unpivot 
    ([Score] for [Course] in([数学],[物理],[英语],[语文]))b
生成格式:
/*
Student Course Score
------- ------- -----------
李四     数学     77
李四     物理     85
李四     英语     65
李四     语文     65
张三     数学     87
张三     物理     90
张三     英语     82
张三     语文     78
*/

原理是一样的，列多了就多写点

开着拖拉机泡妞 2013-08-27