批处理实现有效文件选择处理

[zhensoft163]

原帖需求：
在C:/A 文件夹中有多个数据库备份文件，全备份文件名为database_full_备份时间.bak，差异备份文件名为database_diff_备份时间.bak，我想写一个批处理来选择最新的备份文件，规则如下：
1、如果最新的备份文件为全备份文件，则直接复制全备份文件到文件目录C:/B
2、如果最新的备份文件为差异备份文件，则还需要再找到最后一次的全备份文件，然后将两个文件复制到文件目录C:/B


图片里面是我的备份文件，按照实际需求，我想取的是
database_diff_20130906001000.bak和database_full_20130903003000.bak这两个文件才对，但是执行了下面的这个语句，每次取到的文件都只有database_full_20130831003000.bak一个，而且文件日期也不对。
哪位大虾会是批处理高手帮忙修改下，非常感谢！

@echo off
setlocal enabledelayedexpansion
set src_dir=c:\a
set dst_dir=c:\b
set last_full_time=0
set last_diff_time=0
 
rem 遍历源文件夹里的文件
rem 把文件名用下划线_作为分隔符分成3个部分
rem 判断文件名第2部分是diff或full，分别获取最新时间的文件
rem 第3部分就是备份时间，比较其数值，数值越大则表示文件越新
for /r "%src_dir%" %%a in (*) do (
  for /f "tokens=2,3 delims=_" %%b in ("%%~na") do (
    if "%%b"=="diff" (
      if %%c gtr !last_diff_time! (
        set last_diff_time=%%c
        set last_diff_name=%%a
      )
    ) else if "%%b"=="full" (
      if %%c gtr !last_full_time! (
        set last_full_time=%%c
        set last_full_name=%%a
      )
    )  
  )
)
 
if %last_full_time% equ 0 goto :eof
copy /b "%last_full_name%" "%dst_dir%"
if %last_full_time% lss %last_diff_time% (
  copy /b "%last_diff_name%" "%dst_dir%"
  goto B
) else (goto A)
 
:B
echo 选中两个还原文件，差异备份还原
goto :eof
 
:A
echo 选中一个还原文件，全备份还原
goto :eof

[s11ss]

代码作如下3处修改： if %%c gtr !last_diff_time! ( if "%%c" gtr "!last_diff_time!" ( if %%c gtr !last_full_time! ( if "%%c" gtr "!last_full_time!" ( if %last_full_time% lss %last_diff_time% ( if "%last_full_time%" lss "%last_diff_time%" (