动态创建控件及事件的问题

[kellyicu]

在网上看到一个文章，讲动态创建控件及事件 自己就试试 只有32分了，希望大家帮帮忙，共同学习。
现在的问题是创建控件成功，但代码进行到 CtrlItems.Add ctrl 报错：实时错误'91':对象变量或 With 块变量未设置
谁能帮我看看为什么？怎么解决。


类模块：ControlItem

Public WithEvents ctrl As VBControlExtender
Dim m_Parent As ControlItems
Sub Init(ctl As Object, parnt As ControlItems)
    Set ctrl = ctl
    Set m_Parent = parnt
End Sub
Private Sub Ctrl_Validate(Cancel As Boolean)
    m_Parent.Notify_Validate Me, Cancel
End Sub

类模块：ControlItems

Event Validate(CtrlItem As ControlItem, Cancel As Boolean)
Private m_ControlItems As New Collection
Function Add(ctrl As Control) As ControlItem
    Dim newItem As New ControlItem
    newItem.Init ctrl, Me
    m_ControlItems.Add newItem
    Set Add = newItem
End Function
Friend Sub Notify_Validate(Item As ControlItem, Cancel As Boolean)
    RaiseEvent Validate(Item, Cancel)
End Sub

窗体：Form1

'Dim WithEvents CtrlItems As New ControlItems 文章上是这样的，但不行，会报错，要去掉New
Dim WithEvents CtrlItems As ControlItems
Private Sub cmdCreateControls_Click()
    Dim ctrl As Control

    Set ctrl = Controls.Add("VB.TextBox", "One")
    ctrl.Move 100, 200, 1000, 300
    ctrl.Visible = True
    CtrlItems.Add ctrl

    Set ctrl = Controls.Add("VB.TextBox", "Two")
    ctrl.Move 100, 800, 1000, 300
    ctrl.Visible = True
    CtrlItems.Add ctrl
End Sub
Private Sub CtrlItems_Validate(CtrlItem As ControlItem, Cancel As Boolean)
    If CtrlItem.ctrl.Text = "" Then Cancel = True
End Sub

现在的问题是创建控件成功，但代码进到到 CtrlItems.Add ctrl 报错：实时错误'91':对象变量或 With 块变量未设置
谁能帮我看看为什么？怎么解决。

[笨狗先飞]

没有创建新实例 CtrlItems 在form load的时候创建 在Form里加上这段代码

Private Sub Form_Load()
    Set CtrlItems = New ControlItems
End Sub

运行后还有别的错误，你自己查查先

[yachong]

楼主真可怜，可用分0 已转账200分，请查收

[yachong]

擦，系统好黑 转200还扣税20

[kellyicu]

引用 2 楼 yachong 的回复:

楼主真可怜，可用分0 已转账200分，请查收

为什么总是能遇到这么多好人呢，真的感谢你。