sql插入6W多条数据

[baidu_18750827]

数据库只有一张表 Acc_Num 只有一个字段num

向里面插入6w条数据...

从1-60000插入。怎么插入是最快的。

我实在不知道怎么插入，我唯一想到的就是while循坏...一直循坏60000次...

[-晴天]

if exists(select 1 from sys.objects where type='U' and name='Acc_Num') drop table Acc_Num
go
select top 60000 num=identity(int,1,1)into Acc_Num from syscolumns a,syscolumns b
go
select * from acc_num

[Tiger_Zhao]

DECLARE @maxNum int

INSERT INTO Acc_Num VALUES(1)
SET @maxNum = 1

WHILE @maxNum < 60000
BEGIN
    INSERT INTO Acc_Num
    SELECT @maxNum + num
      FROM Acc_Num
     WHERE @maxNum + num <= 60000

    SET @maxNum = @maxNum*2
END

16次INSERT搞定。

[baidu_18750827]

引用 2 楼 Tiger_Zhao 的回复:

DECLARE @maxNum int

INSERT INTO Acc_Num VALUES(1)
SET @maxNum = 1

WHILE @maxNum < 60000
BEGIN
    INSERT INTO Acc_Num
    SELECT @maxNum + num
      FROM Acc_Num
     WHERE @maxNum + num <= 60000

    SET @maxNum = @maxNum*2
END

16次INSERT搞定。

为何这么屌.... 按照这个写上去，领导会不会夸我能干啊

[-晴天]

create table Acc_num(num int)
go
;with cte as(
select 1 as id
union all
select id+1 as id from cte where id<60000
)
INSERT INTO Acc_Num select id from cte OPTION (MAXRECURSION 0);
go
select * from Acc_num order by num
/*
......
59994
59995
59996
59997
59998
59999
60000

(60000 行受影响)

*/
go
drop table Acc_num

[卖水果的net]

drop table t 
go
create table t(num int )
go
insert into t(num) 
select top 6000 row_number() over (order by a.id) 
from sysobjects a, sysobjects b
go 
select * from t 
go


(6000 行受影响)
num
-----------
1
2
3
4
....
5997
5998
5999
6000

(6000 行受影响)

[jph1122]

才6W直接插很快的吧

[山寨DBA]

用CTE+递归吧，目前我见过最快的了。。。 不晓得6W 数据需要多久，但是我上个月有测试2000万条数据使用CTE+递归的插入，只需要10分钟左右 ，估计你那个6W条，应该是极快的吧

[山寨DBA]

具体操作可以看我下面这个链接： http://bbs.csdn.net/topics/390941777