急求：如何枚举到某文件夹下的最底层子文件夹（且只要最底层）

2015-08-11 07:13:57 332 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

lpide619689 墨衍会员 · AI 创作全网分发关注 + 加入社区

C#实现Windows文件占用检测：基于句柄枚举定位锁定进程在Windows系统开发与运维中，文件被占用导致无法删除或修改是常见问题，其根源在于进程通过文件句柄持有资源。理解句柄作为系统内核对象引用凭证的原理，是解决此类问题的关键。通过调用NtQuerySystemInformation等底层API遍历进程句柄表，可以精准定位占用文件的进程，这项技术对于调试文件锁异常、系统维护和日常故障排查具有重要价值。本文以C#工程实践为例，详细解析如何利用句柄枚举技术实现类似File Locksmith的工具，涵盖从API调用、路径转换到性能优化的完整方案，帮助开发者深入掌握W 阅读详情

菜鸟
某文件夹下面有很多子文件夹，然后子文件夹下面又包含很多子文件夹......而且这样多次....
比如c:/01/ 下面又 a b c 子文件夹。然后a 下面又有1 2 3 子文件夹。。。
现在我只想要遍历获取到所有最底层子文件夹（且只要最底层，其它的全部不要，子文件夹路径，文件名也也不要。），含完整路径。
最好是用 Dir 速度快是不？
非常感谢！

...全文

Windows 10共享文件夹配置：组策略深度解析与实战排错网络文件共享是局域网内实现资源高效分发的核心技术，其本质是基于SMB/CIFS等协议实现跨设备的数据访问。在Windows系统中，这一功能通过多层安全架构实现，涉及网络发现、身份验证和文件权限等多个环节。理解其工作原理对于解决常见的“无法访问”或“权限不足”等工程问题至关重要。本地组策略编辑器作为调整Windows核心网络行为的管理工具，能够精细控制诸如“不安全的来宾登录”、“网络访问共享和安全模型”等关键策略，从而在安全与便利间取得平衡。通过合理配置这些策略，并结合防火墙规则与用户权限设置，可以稳定实现家阅读详情

lpide619689

VB基础类 7,788 成员 197,583 内容

+ 关注 + 加入社区

切换为时间正序

舉杯邀明月 2015-08-18

打赏
举报

' 应用示例：
Private Sub Command1_Click()
   Dim aBuff() As String
   Dim i As Long
   
   aBuff = EnmuFolders("E:\WPS Office")
         ' 参数： 要枚举“最底层子文件夹”的路径。
         '     不能从“驱动器”开始（比如 C:\ 或 C:）
         '     路径最后不要带 \ 字符
   For i = 0& To UBound(aBuff)
      Debug.Print aBuff(i)
   Next
End Sub

' 标准模块的代码：
Option Explicit

Public Function EnmuFolders(ByVal TopPath As String) As String()
   Dim arrBuff()  As String
   Dim arrTemp()  As String
   Dim strPath As String
   Dim lUSize  As Long
   Dim lUseNum As Long
   Dim lCurPnt As Long
   Dim lpValid As Long
   Dim i&, n&

   lpValid = -1
   lUSize = 31
   lCurPnt = 0
   lUseNum = 0
   ReDim arrBuff(lUSize)
   arrBuff(lUseNum) = TopPath
   Do
      strPath = arrBuff(lCurPnt)
      n = EnmuSubFolders(strPath, arrTemp)
      If (n = 0) Then
         lpValid = lpValid + 1
         arrBuff(lpValid) = strPath
      Else
         i = lUseNum + n
         strPath = strPath & "\"
         If (i > lUSize) Then
            lUSize = 7 Or (lUSize + n)
            ReDim Preserve arrBuff(lUSize)
         End If
         For i = 1 To n
            lUseNum = lUseNum + 1
            arrBuff(lUseNum) = strPath & arrTemp(i)
         Next
      End If
      lCurPnt = lCurPnt + 1
      If (lCurPnt > lUseNum) Then Exit Do
   Loop
   ReDim Preserve arrBuff(lpValid)
   EnmuFolders = arrBuff
End Function

Private Function EnmuSubFolders(ByVal FullPath As String, OutBuff() As String) As Long
   Dim t$, c&, p&

   c = -1:  p = -1
   FullPath = FullPath & "\"
   t = Dir$(FullPath & "*.*", 23)
   Do
      t = Dir$()
      If (t = "") Then Exit Do
      If (vbDirectory And GetAttr(FullPath & t)) Then
         p = p + 1
         If (p > c) Then c = c + 4: ReDim Preserve OutBuff(c)
         OutBuff(p) = t
      End If
   Loop
   EnmuSubFolders = p
End Function

lpide619689 2015-08-12

打赏
举报

引用 2 楼 Chen8013 的回复:

你这个说的有点模糊啊，看样子，是有可能要返回很多个文件夹路径？还有，并列的、但“层次深度”不相同的，算不算需要返回的呢？就拿你在主贴中的“C:\01”的例子来说：
C:\01
C:\01\a
C:\01\a\1
C:\01\a\2
C:\01\a\3
C:\01\b
C:\01\c
这种情况下，是只返回3、4、5这三项，还是3到7这５项？毕竟，从6、7这两条路径来说，它也算各自的“最底层”。另外一种再复杂点的情况：
C:\01
C:\01\a
C:\01\a\1
C:\01\a\2
C:\01\a\3\x\y
C:\01\b
C:\01\c\w
这时返回的是3到7？　还是5和7？　或者只能是5？所以，从你的含糊的问题描述，根本就搞不清楚你要的是什么结果。

晕。非常抱歉楼上说错了。应该是两个都需要的是3到7 。总之如果还存在有下级层子文件夹的就不要。

lpide619689 2015-08-12

打赏
举报

引用 2 楼 Chen8013 的回复:

你这个说的有点模糊啊，看样子，是有可能要返回很多个文件夹路径？还有，并列的、但“层次深度”不相同的，算不算需要返回的呢？就拿你在主贴中的“C:\01”的例子来说：
C:\01
C:\01\a
C:\01\a\1
C:\01\a\2
C:\01\a\3
C:\01\b
C:\01\c
这种情况下，是只返回3、4、5这三项，还是3到7这５项？毕竟，从6、7这两条路径来说，它也算各自的“最底层”。另外一种再复杂点的情况：
C:\01
C:\01\a
C:\01\a\1
C:\01\a\2
C:\01\a\3\x\y
C:\01\b
C:\01\c\w
这时返回的是3到7？　还是5和7？　或者只能是5？所以，从你的含糊的问题描述，根本就搞不清楚你要的是什么结果。

多谢！第一个需要的是3 4 5. 第二个需要的是5到7. 总之如果还存在有下级层子文件夹的就不要。非常感谢！

Tiger_Zhao 2015-08-12

打赏
举报

Option Explicit



Sub Main()

    Dim oLeafDir    As Collection

    Dim i           As Long

    

    Set oLeafDir = GetLeafDirectory("c:\01\")



    Debug.Print "== Leaf =="

    For i = 1 To oLeafDir.Count

        Debug.Print oLeafDir(i)

    Next

End Sub



Function GetLeafDirectory(ByVal Path As String) As Collection

    Dim oLeafDir    As Collection

    Dim oStackDir   As Collection

    Dim sPath       As String

    Dim sSubPath    As String

    Dim lSubCount   As Long



    Set oLeafDir = New Collection

    Set oStackDir = New Collection

    oStackDir.Add NormalizePath(Path)



    While oStackDir.Count > 0

        sPath = oStackDir(oStackDir.Count)

        oStackDir.Remove oStackDir.Count

        lSubCount = 0

        'Debug.Print sPath



        sSubPath = Dir(sPath & "*", vbDirectory)

        While LenB(sSubPath) <> 0

            If (sSubPath <> ".") And (sSubPath <> "..") Then

                If (GetAttr(sPath & sSubPath) And vbDirectory) = vbDirectory Then

                    lSubCount = lSubCount + 1

                    oStackDir.Add NormalizePath(sPath & sSubPath)

                End If

            End If



            sSubPath = Dir()

        Wend



        If lSubCount = 0 Then

            oLeafDir.Add sPath

        End If

    Wend



    Set GetLeafDirectory = oLeafDir

End Function



Public Function NormalizePath(ByVal Path As String) As String

    If Right$(Path, 1) <> "\" Then

        NormalizePath = Path & "\"

    Else

        NormalizePath = Path

    End If

End Function

舉杯邀明月 2015-08-12

打赏
举报

你这个说的有点模糊啊，看样子，是有可能要返回很多个文件夹路径？还有，并列的、但“层次深度”不相同的，算不算需要返回的呢？就拿你在主贴中的“C:\01”的例子来说：

C:\01
C:\01\a
C:\01\a\1
C:\01\a\2
C:\01\a\3
C:\01\b
C:\01\c

这种情况下，是只返回3、4、5这三项，还是3到7这５项？毕竟，从6、7这两条路径来说，它也算各自的“最底层”。另外一种再复杂点的情况：

C:\01
C:\01\a
C:\01\a\1
C:\01\a\2
C:\01\a\3\x\y
C:\01\b
C:\01\c\w

这时返回的是3到7？　还是5和7？　或者只能是5？所以，从你的含糊的问题描述，根本就搞不清楚你要的是什么结果。

急求：如何枚举到某文件夹下的最底层子文件夹（且只要最底层）

相关推荐