请教两个关于文件处理的问题，先谢谢大家！！

[st_2000]

１，getfile('PDF') 　命令，打开后，除默认的pdf外，还有个[全部文件*.*] 的选项，如何把这个【全部文件*.*】的选项也去掉？


2, On Selection Bar 1 Of 　 销售管理 Do sals1.App 这个菜单命令执行后，当我关闭sals1.app文件画面后，如何完全释放sals1.app这个文件？　因为显示它还被占用着而无法更新。　试过用clear　无效。

再次感谢！！

[都市夜猫]

1. vfp 的 getfile 好像无法隐藏所有文件选项，用公用对话框控件（CommonDialog）或 ShellAPI 替代吧 2. 做个的项目中没用过 app 形式，不知你直接运行 app 是否会完整退出，通常应该与 clear events 命令有关吧

[oldbbb]

VFP的 GETFILE() 可以随便编辑文件名，输入“*prg”就列出PRG文件。 VFP的LIstBox可以模拟获取文件名，如当 RowSourceType = 7、RowSource = "*.dbf*"

[都市夜猫]

用公用对话框函数吧，下面的函数你自己再酌情修改，例如加些错误处理，或者改成与 vfp 的 getfile 函数参数兼容，等等

? API_GetFile('pdf')

Function API_GetFile(tcExt)
	Local cFlt, nOfs, pBuf, cOFN, cFile
	
	Declare Long GetOpenFileName in comdlg32 String
	Declare Long CommDlgExtendedError in comdlg32
	Declare Long GlobalAlloc in win32api Long, Long
	Declare Long GlobalFree in win32api Long

	cFlt	= tcExt + ' 文件' + Chr(0) + '*.' + tcExt
	nOfs	= Len(cFlt) + 2
	pBuf	= GlobalAlloc(0x40, nOfs + 256)
	cOFN	= Replicate(Chr(0), 8) + BinToC(pBuf, 'rs') + Replicate(Chr(0), 8) ;
			+ BinToC(1, 'rs') + BinToC(pBuf + nOfs, 'rs') + BinToC(256, 'rs') ;
			+ Replicate(Chr(0), 16) + BinToC(0x181008, 'rs') ;
			+ Replicate(Chr(0), 20)
	cOFN	= BinToC(4+Len(cOFN), 'rs') + cOFN
	Sys(2600, pBuf, Len(cFlt), cFlt)
	If GetOpenFileName(cOFN) > 0
		cFile = Sys(2600, pBuf + nOfs, 256)
		cFile = Left(cFile, At(Chr(0), cFile) - 1)
	Else
		MessageBox('错误码: ' + Transform(CommDlgExtendedError()), 16, '')
		cFile = ''
	EndIf
	GlobalFree(pBuf)
	Return cFile
EndFunc

[文修]

楼主你好， 二楼正解，建议楼主试一下

[st_2000]

感谢各位，问题1，业务场景已经处理完毕 问题2，clear events 无法解决我的问题， 不知道还有什么办法？