sqlserver 判断某一天是几月的第几周

[花落随风]

比如2016-1-1 是12月的第4周，2016-1-4 开始是第一周

也就是一每个月的第一个星期一开始算是第几周

[花落随风]

从每个月的第一个星期一算起，周一到周日就是第一周，一个月的的第几个周一就是第几周的开始日期

[中国风]

SELECT @@DATEFIRST--SET DATEFIRST 指定一周中的第一天。美国英语中默认 7 对应星期日。

--针对以上默认 7 对应星期日
DECLARE @Dt DATE='2016-4-1'
SELECT RTRIM(CASE WHEN DATEPART(dw,DATEADD(dd,-1,@Dt))>=5 THEN MONTH(DATEADD(dd,-7,@dt)) ELSE MONTH(@dt) END)+'月的第'
+RTRIM(CASE WHEN DATEPART(dw,DATEADD(dd,-DAY(@Dt),@Dt))>=5 THEN 0 ELSE 1 END+CASE WHEN DATEPART(dw,DATEADD(dd,-1,@Dt))>=5 THEN CEILING(DAY(DATEADD(dd,-7,@dt))/7.0) ELSE CEILING(DAY(@dt)/7.0) END)
+'周'

[唐诗三百首]

create function dbo.getMonthWeek(@d date)
returns varchar(20)
as
begin
declare @returns varchar(20),
              @monthfirstDay date,
              @firstMondy date

select @monthfirstDay=left(convert(varchar,@d,23),7)+'-01'

if not exists(select 1 
                     from master.dbo.spt_values
                     where type=N'P' and number between 0 and datediff(d,@monthfirstDay,@d)
                     and datepart(dw,dateadd(d,number,@monthfirstDay))=2)
begin
  select @monthfirstDay=dateadd(mm,-1,@monthfirstDay)
end

  ;with t as(select 'days'=dateadd(d,number,@monthfirstDay)
                   from master.dbo.spt_values
                   where type=N'P' and number<=7)
   select @firstMondy=min([days]) 
    from t
    where datepart(dw,[days])=2

select @returns=rtrim(datepart(mm,@monthfirstDay))+'月'
                          +'的第'+rtrim(datediff(d,@firstMondy,@d)/7+1)+'周'

return @returns
end


-- 2016-1-1 是12月的第4周
select dbo.getMonthWeek('2016-1-1') 'result'
/*
result
--------------------
12月的第4周

(1 row(s) affected)
*/


-- 2016-1-4 开始是第一周
select dbo.getMonthWeek('2016-1-4') 'result'
/*
result
--------------------
1月的第1周

(1 row(s) affected)
*/


-- 2016-4-7 开始是第一周
select dbo.getMonthWeek('2016-4-7') 'result'
/*
result
--------------------
4月的第1周

(1 row(s) affected)
*/

[範先森]

declare @date datetime set @date = '2016-04-07' select cast(datepart(mm,@date) as varchar(2)) + '月第' + cast((datepart(wk,@date) - datepart(wk,convert(varchar(7),@date,120) + '-01') + 1) as varchar(2)) + '周'