VB6引用C语言DLL动态库函数，参数类型为CHAR*如何传递数值

[美薇]

* 函数名:ftDetectFaces 本地函数
*参数：chn，表示检测通道，即1路视频，同时可开启5路。
*参数：pbyJpgSrcF，表示图片流，即JPG文件以内存数组方式存储；
*参数：lenF，内存图像流，数组的长度
*参数：outData，表示检测到的人脸ID与位置，每5个INT值表示1个人脸，格式为 id,x,y,w,h,id,x,y,w,h,id.......
*参数：facenum, 表示outData中包括的有效人脸个数
*返回：-1表示失败，可能图片有问题;-10网络或后台EXE服务有问题。
*/
int WINAPI ftDetectFaces(int chn, char* pbyJpgSrcF, int lenF, int *&outData, int &facenum);
* 函数名:ftVerifyImage 远程函数
*参数：pbyJpgSrcF，表示图片流，即JPG文件以内存数组方式存储；
*参数：lenF，内存图像流，数组的长度
*参数：score, 图片比对结果[0,1.0], -1表示比对失败
*-1表示失败，可能图片有问题；-10网络或后台EXE服务有问题。*/
int WINAPI ftVerifyImage(char* pbyJpgSrcF0, int lenF0, char* pbyJpgSrcF1, int lenF1, float &score);



这里有vb.net例程为：
Imports System.Runtime.InteropServices
Imports System.IO
Imports System.Text
Module Module1
<DllImport("FTDetectAPI.dll", CharSet:=CharSet.Ansi, CallingConvention:=CallingConvention.StdCall)> Public Function ftDetectFaces (ByVal chn As Integer, ByVal pbyJpgSrcF1() As Byte, ByVal lenF1 As Integer, ByRef outData As IntPtr, ByRef facenum As Integer) As Integer
End Function
<DllImport("FTDetectAPI.dll", CharSet:=CharSet.Ansi, CallingConvention:=CallingConvention.StdCall)> Public Function ftVerifyImage(ByVal pbyJpgSrcF0() As Byte, ByVal lenF0 As Integer, ByVal pbyJpgSrcF1() As Byte, ByVal lenF1 As Integer, ByRef score As Single) As Integer
End Function

现在使用VB6编程，不知道应该怎么声明这两个函数。
其中两个数组参数报错，函数:ftVerifyImage 声明我写成 这样
Public Declare Function ftVerifyImage Lib "FTDetectAPI.dll" (ByVal pbyJpgSrcF0() As Byte, ByVal lenF0 As Integer, pbyJpgSrcF1() As Byte, ByVal lenF1 As Integer, ByRef score As Single) As Integer
显示：数组参数必须为 ByRef ，改为
Public Declare Function ftVerifyImage Lib "FTDetectAPI.dll" (ByRef pbyJpgSrcF0() As Byte, ByVal lenF0 As Integer, ByRef pbyJpgSrcF1() As Byte, ByVal lenF1 As Integer, ByRef score As Single) As Integer
调用后，运行显示事实错误6，溢出。请大师们指点

[专注VB编程开发20年]

ByRef pbyJpgSrcF1() As Byte,一般用指针，long

[舉杯邀明月]

byval as string 就可以了。

[Tiger_Zhao]

Option Explicit

Public Declare Sub CopyMemory Lib "kernel32.dll" Alias "RtlMoveMemory" ( _
                    ByRef Destination As Any, _
                    ByRef Source As Any, _
                    ByVal Length As Long)

Public Declare Function ftDetectFaces Lib "FTDetectAPI.dll" ( _
                    ByVal chn As Long, _
                    ByRef pbyJpgSrcF As Byte, _
                    ByVal lenF As Long, _
                    ByRef pOutData As Long, _
                    ByRef facenum As Long _
                    ) As Long

'调用代码大概如下'
    Dim chn         As Long
    Dim lenF        As Long
    Dim pOutData    As Long
    Dim facenum     As Long
    Dim aJpgSrcF()  As Byte
    Dim aOutData()  As Long
    Dim lResult     As Long
    
    '准备数据'
    chn = 1234
    aJpgSrcF = ReadJptStream()
    lenF = UBound(aJpgSrcF) + 1
    
    '调用'
    lResult = ftDetectFaces(chn, aJpgSrcF(0), lenF, pOutData, facenum)
    
    '成功后复制结果'
    ReDim aOutData(facenum * 5 - 1) '每人5个INT'
    '注意CopyMemory不同的参数声明方式调用写法不同，这是针对上面的声明'
    CopyMemory aOutData(0), ByVal pOutData, facenum * 5 * 4 '1个INT4字节'

不过你的设计不是很规范，outData 似乎是函数内部分配的内存，谁负责释放？
不遵循谁申请谁释放的原则，很容易导致内存泄漏。

[of123]

用 Byte 数组。调用时，用数组元素 0，如 pbyJpgSrcF(0)。

int WINAPI ftDetectFaces(int chn, char* pbyJpgSrcF, int lenF, int *&outData, int &facenum);

Public Declare Function ftDetectFaces Lib "FTDetectAPI.dll" (ByVal chn As Long, ByRef pbyJpgSrcF() As Byte, ByVal lenF As Long, ByRef outData() As Long, ByRef facenum As Long) As Long

[美薇]

感谢大家的回复